Chinaunix首页 | 论坛 | 博客

信仰年轻

首页　| 　博文目录　| 　关于我

Garfield_Trump

  • 博客访问： 1852732
  • 博文数量： 317
  • 博客积分： 1557
  • 博客等级： 上尉
  • 技术积分： 1208
  • 用 户 组： 普通用户
  • 注册时间： 2008-02-26 23:38
个人简介

如果想出发，就不要等到明天！

文章分类

全部博文（317）

文章存档

2016年（1）

2015年（41）

2014年（152）

2013年（114）

2012年（4）

2011年（1）

2009年（4）

我的朋友
最近访客
推荐博文
相关博文
从零开始uboot—分析uboot1.1.6之start.S(5)

分类： 嵌入式

2014-09-14 00:38:33

原文地址：从零开始uboot—分析uboot1.1.6之start.S(5) 作者：andyhzw

操作系统：ubuntu10.04


前言：
    在上一章节中，详细分析了uboot中的顶级makefile，了解了uboot的编译流程，在本章节中，将要详细分析的是uboot 的执行流程。
而uboot的第一条执行，是在 start.S 的。


一，start.S的详细分析。
点击(此处)折叠或打开
  1. /*
  2.  * armboot - Startup Code for ARM920 CPU-core
  3.  *
  4.  * Copyright (c) 2001    Marius Gr鰃er
  5.  * Copyright (c) 2002    Alex Z黳ke
  6.  * Copyright (c) 2002    Gary Jennejohn
  7.  *
  8.  * See file CREDITS for list of people who contributed to this
  9.  * project.
  10.  *
  11.  * This program is free software; you can redistribute it and/or
  12.  * modify it under the terms of the GNU General Public License as
  13.  * published by the Free Software Foundation; either version 2 of
  14.  * the License, or (at your option) any later version.
  15.  *
  16.  * This program is distributed in the hope that it will be useful,
  17.  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18.  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19.  * GNU General Public License for more details.
  20.  *
  21.  * You should have received a copy of the GNU General Public License
  22.  * along with this program; if not, write to the Free Software
  23.  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24.  * MA 02111-1307 USA
  25.  */


  28. #include <config.h>            /* ./include/config.h    */
  29. #include <version.h>        /* ./include/version.h     */


  32. /*
  33.  *************************************************************************
  34.  *
  35.  * Jump vector table as in table 3.1 in [1]
  36.  *
  37.  *************************************************************************
  38.  */

  40. /*
  41. global声明一个符号可被其他文档引用，相当于声明了一个全局变量，.globl和.global相同。
  42. 详情请看：http://blog.chinaunix.net/uid-28458801-id-3554759.html

  44.  _start就是整个start.S的最开始，即整个uboot的代码的开始。
  45.  _start后面加上一个冎号’:’，表示其是一个标号Label，类似亍C诧言goto后面的标号。
  46. 而同时，_start的值，也就是返个代码的位置了，此处即为代码的最开始，相对的0的位置。

  48. b reset :表示跳转到 reset 执行，并且不返回

  50. ldr: LDR伪指令-----大范围的地址读取
  51. 详情请看：1，http://blog.chinaunix.net/uid-28458801-id-3753775.html
  52.         2，http://blog.chinaunix.net/uid-28458801-id-3753657.html
  53.         
  54. .word .word expr {,expr}… 分配一段字内存单元，幵用expr初始化字内存单元(32bit)
  55. 以_undefined_instruction为例，就是，此处分配了一个word=32bit=4字节
  56. 的地址空间，里面存放的值是undefined_instruction。
  57. 而此处_undefined_instruction也就是该地址空间的地址了。用C诧言来表达就是：
  58. _undefined_instruction = &undefined_instruction。
  59. 在后面的代码，我们可以看到，undefined_instruction也是一个标号，即一个地址值，对应着
  60. 就是在发生“未定义指令”的时候，系统所要去执行的代码。
  61. 所以：
  62. ldr pc, 标号1
  63. 。。。
  64. 标号1：.word 标号2
  65. 标号2：
  66.     。。。（具体要执行的代码）
  67. 的意思就是，将地址为标号1中内容载入到pc，而地址为标号1中的内容，正好装的是标号2。
  68. 用C诧言表达其实很简单：
  69. PC = *（标号1） = 标号2
  70. 对PC赋值，即是实现代码跳转，所以整个返段汇编代码的意思就是：
  71. 跳转到标号2的位置，执行对应的代码。

  73. .balignl 16,0xdeadbeef 意思就是，接下来的代码，都要16字节对齐，不足之处，用0xdeadbeef填充。
  74. */
  75. .globl _start
  76. _start:    b reset
  77.     ldr    pc, _undefined_instruction
  78.     ldr    pc, _software_interrupt
  79.     ldr    pc, _prefetch_abort
  80.     ldr    pc, _data_abort
  81.     ldr    pc, _not_used
  82.     ldr    pc, _irq
  83.     ldr    pc, _fiq

  85. _undefined_instruction:    .word undefined_instruction
  86. _software_interrupt:    .word software_interrupt
  87. _prefetch_abort:    .word prefetch_abort
  88. _data_abort:        .word data_abort
  89. _not_used:        .word not_used
  90. _irq:            .word irq
  91. _fiq:            .word fiq

  93.     .balignl 16,0xdeadbeef


  96. /*
  97.  *************************************************************************
  98.  *
  99.  * Startup Code (reset vector)
  100.  *
  101.  * do important init only if we don't start from memory!
  102.  * relocate armboot to ram
  103.  * setup stack
  104.  * jump to second stage
  105.  *
  106.  *************************************************************************
  107.  */
  108. /*
  109. _TEXT_BASE是一个标号地址，此地址中是一个word类型的变量，变量名是TEXT_BASE,代码的基地址.
  110. TEXT_BASE 定义在 \board\xx\config.mk，假设为 TEXT_BASE = 0x33D00000

  112. *(_armboot_start) = _start
  113. */
  114. _TEXT_BASE:
  115.     .word    TEXT_BASE

  117. .globl _armboot_start
  118. _armboot_start:
  119.     .word _start

  121. /*
  122.  * These are defined in the board-specific linker script.
  123.  */
  124.  /*
  125.  _bss_start和_bss_end都叧是两个标号，对应着此处的地址。
  126. 而两个地址里面分别存放的值是__bss_start和_end,这两个的值，定义在 \board\xx\u-boot.lds 中。
  127. 而关亍_bss_start和_bss_end定义为.glogl即全局变量，是因为uboot的其他源码中要用到这两个变量。

  129. FREE_RAM_END和FREE_RAM_SIZE，PreLoadedONRAM，IRQ_STACK_START，FIQ_STACK_START，之所以也是声明为全局变量，
  130. 是因为uboot的源码中会用到这些变量。
  131.  */
  132. .globl _bss_start
  133. _bss_start:
  134.     .word __bss_start

  136. .globl _bss_end
  137. _bss_end:
  138.     .word _end

  140. .globl FREE_RAM_END
  141. FREE_RAM_END:
  142.     .word    0x0badc0de

  144. .globl FREE_RAM_SIZE
  145. FREE_RAM_SIZE:
  146.     .word    0x0badc0de

  148. .globl PreLoadedONRAM
  149. PreLoadedONRAM:
  150.     .word    0

  152. #ifdef CONFIG_USE_IRQ
  153. /* IRQ stack memory (calculated at run-time) */
  154. .globl IRQ_STACK_START
  155. IRQ_STACK_START:
  156.     .word    0x0badc0de

  158. /* IRQ stack memory (calculated at run-time) */
  159. .globl FIQ_STACK_START
  160. FIQ_STACK_START:
  161.     .word 0x0badc0de
  162. #endif


  165. /*
  166.  * the actual reset code
  167.  */
  168. /*
  169. 对 mrs 和msr 有疑问的请看：http://blog.chinaunix.net/uid-28458801-id-4083956.html
  170. */
  171. reset:
  172.     /*
  173.      * set the cpu to SVC32 mode.设置cpu为 SVC模式。
  174.      * 如果对arm的个模式有疑问的请看：1，http://blog.chinaunix.net/uid-28458801-id-3788554.html
  175.      *     2，http://blog.chinaunix.net/uid-28458801-id-3494646.html
  176.      */

  178.     mrs    r0,cpsr                    /* 传送CPSR的内容到R0 */
  179.     bic    r0,r0,#0x1f                /* 清除r0的bit[4:0]位 */
  180.     orr    r0,r0,#0xd3                /* 把r0的bit[7:6]和bit[4]和bit[2:0]置为1 */
  181.     msr    cpsr,r0                    /* 将r0的值赋给CPSR */

  183. /* turn off the watchdog */
  184. #if defined(CONFIG_S3C2400)
  185. # define pWTCON        0x15300000
  186. # define INTMSK        0x14400008    /* Interupt-Controller base addresses */
  187. # define CLKDIVN    0x14800014    /* clock divisor register */
  188. #elif defined(CONFIG_S3C2410)
  189. # define pWTCON        0x53000000
  190. # define INTMOD 0X4A000004
  191. # define INTMSK        0x4A000008    /* Interupt-Controller base addresses */
  192. # define INTSUBMSK    0x4A00001C
  193. # define CLKDIVN    0x4C000014    /* clock divisor register */
  194. #endif


  197. /*
  198. 以上是看门狗的相关寄存器的地址。

  200. 对 ldr伪指令 有疑惑的请看：http://blog.chinaunix.net/uid-28458801-id-4084264.html

  202. 先是用r0寄存器存pWTCON的值，然后r1=0，再将r1中的0写入到pWTCON寄存器中，其实就是
  203. *((int *)pWTCON) = 0；
  204. */
  205. #if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
  206.     ldr r0, =pWTCON            /* 宏pWTCON的值赋值给r0寄存器 */
  207.     mov r1, #0x0
  208.     str r1, [r0]

  210.     /*
  211.      * mask all IRQs by setting all bits in the INTMR - default
  212.      * 关闭所有中断。
  213.      * INTMSK寄存器设置为0xffffffff
  214.      */
  215.     mov    r1, #0xffffffff
  216.     ldr    r0, =INTMSK
  217.     str    r1, [r0]
  218. /* 将INTSUBMSK寄存器的值设置为0x3ff。*/
  219. # if defined(CONFIG_S3C2410)
  220.     ldr    r1, =0x3ff
  221.     ldr    r0, =INTSUBMSK
  222.     str    r1, [r0]
  223. # endif

  225. #if 0        /* 不编译*/
  226.     /* FCLK:HCLK:PCLK = 1:2:4 */
  227.     /* default FCLK is 120 MHz ! */
  228.     ldr    r0, =CLKDIVN
  229.     mov    r1, #3
  230.     str    r1, [r0]
  231. #endif
  232. #endif    /* CONFIG_S3C2400 || CONFIG_S3C2410 */

  234.     /*
  235.      * we do sys-critical inits only at reboot,
  236.      * not when booting from ram!
  237.      */
  238.      /*
  239.      ADR伪指令--- 小范围的地址读取
  240.      */
  241.     
  242. #ifndef CONFIG_SKIP_LOWLEVEL_INIT
  243.     adr    r0, _start        /* r0 <- current position of code ,将_start的地址赋值给r0 */
  244.     ldr    r1, _TEXT_BASE    /* test if we run from flash or RAM*/
  245.     cmp r0, r1     /* don't reloc during debug , 比较r0和r1是否相等 */
  246.     blne    cpu_init_crit    /* 如果r0和r1不相等，则执行 cpu_init_crit*/
  247. #endif

  249.     /* Set up the stack                        
  250.     CFG_MALLOC_LEN,CFG_GBL_DATA_SIZE 定义在\include\configs\xx.h
  251.     
  252.     #define CFG_MALLOC_LEN (CFG_ENV_SIZE + 128*1024)
  253.     #define CFG_GBL_DATA_SIZE 128 /* size in bytes reserved for initial data */

  255.     #define CFG_ENV_SIZE 0x20000 /* Total Size of Environment Sector */
  256.     
  257.     #define CONFIG_STACKSIZE_IRQ    (4*1024)    /* IRQ stack */
  258.     #define CONFIG_STACKSIZE_FIQ    (4*1024)    /* FIQ stack */
  259.     
  260.     */
  261. stack_setup:
  262.     ldr    r0, _TEXT_BASE        /* upper 128 KiB: relocated uboot ,地址为_TEXT_BASE的内存中的内容给r0 */
  263.     sub    r0, r0, #CFG_MALLOC_LEN    /* malloc area ，256 kb */
  264.     sub    r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo ,128 byte */
  265.     
  266. /* cpu/arm920t/cpu.c 中的 cpu_init 中真正的为 IRQ，FIQ模式划分了栈*/
  267. #ifdef CONFIG_USE_IRQ
  268.     sub    r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)        /* 4kb + 4kb*/
  269. #endif
  270.     sub    sp, r0, #12        /* leave 3 words for abort-stack ,12 byte */

  272. #ifndef CONFIG_SKIP_LOWLEVEL_INIT
  273.     bl clock_init        /* 初始化系统时钟*/
  274. #endif

  276. #ifndef CONFIG_SKIP_RELOCATE_UBOOT
  277. relocate:                /* relocate U-Boot to RAM     */
  278.     adr    r0, _start        /* r0 <- current position of code */
  279.     ldr    r1, _TEXT_BASE        /* test if we run from flash or RAM */
  280.     cmp r0, r1 /* don't reloc during debug */
  281.     beq clear_bss
  282.     
  283.     ldr    r2, _armboot_start    /* _start */
  284.     ldr    r3, _bss_start
  285.     sub    r2, r3, r2        /* r2 <- size of armboot */
  286. #if 1
  287.     bl CopyCode2Ram    /* r0: source, r1: dest, r2: size */
  288. #else
  289.     add    r2, r0, r2        /* r2 <- source end address */

  291. copy_loop:
  292.     ldmia     {r3-r10}        /* copy from source address [r0] */
  293.     stmia     {r3-r10}        /* copy to target address [r1] */
  294.     cmp    r0, r2            /* until source end addreee [r2] */
  295.     ble    copy_loop
  296. #endif
  297. #endif    /* CONFIG_SKIP_RELOCATE_UBOOT */

  299. /* 清除 bss 段*/
  300. clear_bss:
  301.     ldr    r0, _bss_start        /* find start of bss segment */
  302.     ldr    r1, _bss_end        /* stop here */
  303.     mov     r2, #0x00000000        /* clear */

  305. clbss_l:str    r2, [r0]        /* clear loop... */
  306.     add    r0, r0, #4
  307.     cmp    r0, r1
  308.     ble    clbss_l

  310. SetLoadFlag:
  311.     /* Set a global flag, PreLoadedONRAM */
  312.     adr    r0, _start        /* r0 <- current position of code */
  313.     ldr    r1, _TEXT_BASE        /* test if we run from flash or RAM */
  314.     cmp r0, r1 /* don't reloc during debug */
  315.     ldr r2, =PreLoadedONRAM
  316.     mov r3, #1
  317.     streq r3, [r2]

  319. #if 0    /* 不编译*/
  320.     /* try doing this stuff after the relocation */
  321.     ldr r0, =pWTCON
  322.     mov r1, #0x0
  323.     str r1, [r0]

  325.     /*
  326.      * mask all IRQs by setting all bits in the INTMR - default
  327.      */
  328.     mov    r1, #0xffffffff
  329.     ldr    r0, =INTMR
  330.     str    r1, [r0]

  332.     /* FCLK:HCLK:PCLK = 1:2:4 */
  333.     /* default FCLK is 120 MHz ! */
  334.     ldr    r0, =CLKDIVN
  335.     mov    r1, #3
  336.     str    r1, [r0]
  337.     /* END stuff after relocation */
  338. #endif

  340.     ldr    pc, _start_armboot

  342. _start_armboot:    .word start_armboot        /* 进入c函数阶段 ./lib_arm/board.c */


  345. /*
  346.  *************************************************************************
  347.  *
  348.  * CPU_init_critical registers
  349.  *
  350.  * setup important registers
  351.  * setup memory timing
  352.  *
  353.  *************************************************************************
  354.  */


  357. #ifndef CONFIG_SKIP_LOWLEVEL_INIT
  358. cpu_init_crit:
  359.     /*
  360.      * flush v4 I/D caches
  361.      */
  362.     mov    r0, #0
  363.     mcr    p15, 0, r0, c7, c7, 0    /* flush v3/v4 cache */
  364.     mcr    p15, 0, r0, c8, c7, 0    /* flush v4 TLB */

  366.     /*
  367.      * disable MMU stuff and caches
  368.      */
  369.     mrc    p15, 0, r0, c1, c0, 0
  370.     bic    r0, r0, #0x00002300    @ clear bits 13, 9:8 (--V- --RS)
  371.     bic    r0, r0, #0x00000087    @ clear bits 7, 2:0 (B--- -CAM)
  372.     orr    r0, r0, #0x00000002    @ set bit 2 (A) Align
  373.     orr    r0, r0, #0x00001000    @ set bit 12 (I) I-Cache
  374.     mcr    p15, 0, r0, c1, c0, 0

  376.     /*
  377.      * before relocating, we have to setup RAM timing
  378.      * because memory timing is board-dependend, you will
  379.      * find a lowlevel_init.S in your board directory.
  380.      */
  381.     mov    ip, lr
  382.     bl    lowlevel_init        /* 设置存储控制器，使得外接的sdram可用*/
  383.     mov    lr, ip
  384.     mov    pc, lr
  385. #endif /* CONFIG_SKIP_LOWLEVEL_INIT */

  387. /*
  388.  *************************************************************************
  389.  *
  390.  * Interrupt handling
  391.  *
  392.  *************************************************************************
  393.  */

  395. @
  396. @ IRQ stack frame.
  397. @
  398. #define S_FRAME_SIZE    72

  400. #define S_OLD_R0    68
  401. #define S_PSR        64
  402. #define S_PC        60
  403. #define S_LR        56
  404. #define S_SP        52

  406. #define S_IP        48
  407. #define S_FP        44
  408. #define S_R10        40
  409. #define S_R9        36
  410. #define S_R8        32
  411. #define S_R7        28
  412. #define S_R6        24
  413. #define S_R5        20
  414. #define S_R4        16
  415. #define S_R3        12
  416. #define S_R2        8
  417. #define S_R1        4
  418. #define S_R0        0

  420. #define MODE_SVC 0x13
  421. #define I_BIT     0x80

  423. /*
  424.  * use bad_save_user_regs for abort/prefetch/undef/swi ...
  425.  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
  426.  */

  428.     .macro    bad_save_user_regs
  429.     sub    sp, sp, #S_FRAME_SIZE
  430.     stmia    sp, {r0 - r12}            @ Calling r0-r12
  431.     ldr    r2, _armboot_start
  432.     sub    r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
  433.     sub    r2, r2, #(CFG_GBL_DATA_SIZE+8) @ set base 2 words into abort stack
  434.     ldmia    r2, {r2 - r3}            @ get pc, cpsr
  435.     add    r0, sp, #S_FRAME_SIZE        @ restore sp_SVC

  437.     add    r5, sp, #S_SP
  438.     mov    r1, lr
  439.     stmia    r5, {r0 - r3}            @ save sp_SVC, lr_SVC, pc, cpsr
  440.     mov    r0, sp
  441.     .endm

  443.     .macro    irq_save_user_regs
  444.     sub    sp, sp, #S_FRAME_SIZE
  445.     stmia    sp, {r0 - r12}            @ Calling r0-r12
  446.     add r8, sp, #S_PC
  447.     stmdb r8, {sp, lr}^ @ Calling SP, LR
  448.     str lr, [r8, #0] @ Save calling PC
  449.     mrs r6, spsr
  450.     str r6, [r8, #4] @ Save CPSR
  451.     str r0, [r8, #8] @ Save OLD_R0
  452.     mov    r0, sp
  453.     .endm

  455.     .macro    irq_restore_user_regs
  456.     ldmia    sp, {r0 - lr}^            @ Calling r0 - lr
  457.     mov    r0, r0
  458.     ldr    lr, [sp, #S_PC]            @ Get PC
  459.     add    sp, sp, #S_FRAME_SIZE
  460.     subs    pc, lr, #4            @ return & move spsr_svc into cpsr
  461.     .endm

  463.     .macro get_bad_stack
  464.     ldr    r13, _armboot_start        @ setup our mode stack
  465.     sub    r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
  466.     sub    r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack

  468.     str    lr, [r13]            @ save caller lr / spsr
  469.     mrs    lr, spsr
  470.     str lr, [r13, #4]

  472.     mov    r13, #MODE_SVC            @ prepare SVC-Mode
  473.     @ msr    spsr_c, r13
  474.     msr    spsr, r13
  475.     mov    lr, pc
  476.     movs    pc, lr
  477.     .endm

  479.     .macro get_irq_stack            @ setup IRQ stack
  480.     ldr    sp, IRQ_STACK_START
  481.     .endm

  483.     .macro get_fiq_stack            @ setup FIQ stack
  484.     ldr    sp, FIQ_STACK_START
  485.     .endm

  487. /*
  488.  * exception handlers
  489.  */
  490.     .align 5
  491. undefined_instruction:
  492.     get_bad_stack
  493.     bad_save_user_regs
  494.     bl     do_undefined_instruction

  496.     .align    5
  497. software_interrupt:
  498.     get_bad_stack
  499.     bad_save_user_regs
  500.     bl     do_software_interrupt

  502.     .align    5
  503. prefetch_abort:
  504.     get_bad_stack
  505.     bad_save_user_regs
  506.     bl     do_prefetch_abort

  508.     .align    5
  509. data_abort:
  510.     get_bad_stack
  511.     bad_save_user_regs
  512.     bl     do_data_abort

  514.     .align    5
  515. not_used:
  516.     get_bad_stack
  517.     bad_save_user_regs
  518.     bl     do_not_used

  520. @ thisway.diy, 2006.06.24
  521. .globl Launch
  522.     .align    4
  523. Launch:
  524.     mov r7, r0
  525.     @ diable interrupt
  526.     @ disable watch dog timer
  527.     mov    r1, #0x53000000
  528.     mov    r2, #0x0
  529.     str    r2, [r1]

  531.     ldr r1,=INTMSK
  532.     ldr r2,=0xffffffff @ all interrupt disable
  533.     str r2,[r1]

  535.     ldr r1,=INTSUBMSK
  536.     ldr r2,=0x7ff @ all sub interrupt disable
  537.     str r2,[r1]

  539.     ldr r1, = INTMOD
  540.     mov r2, #0x0 @ set all interrupt as IRQ (not FIQ)
  541.     str r2, [r1]

  543.     @
  544.     mov    ip, #0
  545.     mcr    p15, 0, ip, c13, c0, 0 @    /* zero PID */
  546.     mcr    p15, 0, ip, c7, c7, 0 @    /* invalidate I,D caches */
  547.     mcr    p15, 0, ip, c7, c10, 4 @    /* drain write buffer */
  548.     mcr    p15, 0, ip, c8, c7, 0 @    /* invalidate I,D TLBs */
  549.     mrc    p15, 0, ip, c1, c0, 0 @    /* get control register */
  550.     bic    ip, ip, #0x0001 @    /* disable MMU */
  551.     mcr    p15, 0, ip, c1, c0, 0 @    /* write control register */

  553.     @ MMU_EnableICache
  554.     @mrc p15,0,r1,c1,c0,0
  555.     @orr r1,r1,#(1<<12)
  556.     @mcr p15,0,r1,c1,c0,0

  558.     @ clear SDRAM: the end of free mem(has wince on it now) to the end of SDRAM
  559.     ldr r3, FREE_RAM_END
  560.     ldr r4, =PHYS_SDRAM_1+PHYS_SDRAM_1_SIZE @ must clear all the memory unused to zero
  561.     mov r5, #0

  563.     ldr r1, _armboot_start
  564.     ldr r2, =On_Steppingstone
  565.     sub r2, r2, r1
  566.     mov pc, r2
  567. On_Steppingstone:
  568. 2: stmia {r5}
  569.     cmp r3, r4
  570.     bne 2b

  572.     @ set sp = 0 on sys mode
  573.     mov sp, #0

  575.     @ add by thisway.diy 2006.06.26, switch to SVC mode
  576.     msr    cpsr_c,    #0xdf    @ set the I-bit = 1, diable the IRQ interrupt
  577.     msr    cpsr_c,    #0xd3    @ set the I-bit = 1, diable the IRQ interrupt
  578.     ldr sp, =0x31ff5800    
  579.     
  580.     nop
  581.     nop
  582.     nop
  583.     nop

  585.     mov pc, r7 @ Jump to PhysicalAddress
  586.     nop
  587.     mov pc, lr

  589. #ifdef CONFIG_USE_IRQ

  591.     .align    5
  592. irq:
  593. /* add by to use IRQ for USB and DMA */
  594.     sub    lr, lr, #4             @ the return address
  595.     ldr    sp, IRQ_STACK_START     @ the stack for irq
  596.     stmdb         { r0-r12,lr }    @ save registers
  597.     
  598.     ldr    lr,    =int_return         @ set the return addr
  599.     ldr    pc, =IRQ_Handle         @ call the isr
  600. int_return:
  601.     ldmia         { r0-r12,pc }^    @ return from interrupt

  603.     .align    5
  604. fiq:
  605.     get_fiq_stack
  606.     /* someone ought to write a more effiction fiq_save_user_regs */
  607.     irq_save_user_regs
  608.     bl     do_fiq
  609.     irq_restore_user_regs

  611. #else

  613.     .align    5
  614. irq:
  615.     get_bad_stack
  616.     bad_save_user_regs
  617.     bl     do_irq

  619.     .align    5
  620. fiq:
  621.     get_bad_stack
  622.     bad_save_user_regs
  623.     bl     do_fiq

  625. #endif
最后得到的内存分别如下：





二，my_uboot的实现思路
    根据以上分析，总结了my_uboot的实现思路：
（1）设置 CPU 模式
（2）关闭看门狗
（3）关闭中断
（4）设置堆栈 sp 指针
（5）清除 bss 段
（6）异常中断处理
（7）跳转到 start_armboot 函数中执行。

（1）设置 CPU 模式
总的来说，就是将 CPU 设置为 SVC 模式。

（2）关闭看门狗
就是去设置对应的寄存器，将看门狗关闭。

（3）关闭中断
关闭中断，也是去设置对应的寄存器，即可。

（4）设置堆栈 sp 指针
设置堆栈以便 C 程序执行。

（5）清除 bss 段
此处很简单，就是将对应 bss 段，都设置为,0，即清零。
其对应的地址空间，就是那些未初始化的全局变量的地址。

（6）异常中断处理
异常中断处理，就是实现对应的常见的那些处理中断的部分内容。
说白了就是实现一个个中断凼数。 uboot在初始化的时候，主要目的叧是为了初始化系统，及引
导系统，所以，此处的中断处理部分的代码，往往相对比较简单，丌是很复杂

（7）跳转到 start_armboot 函数中执行
前面的6个操作都是汇编语言实现的，开发难度高，移植性低，因此在实现uboot的真正的引导linux内核的实现，还是由C语言来实现。
在此，初步的思路是：1，初始化。2，串口，以便调试。3，实现linux内核的引导。




三，疑问
在这实现中，有个很重要的疑问：通过什么方式来烧写uboot，linux内核，文件系统程序。
初步设想：通过 SEGGER的 J-Flash ARM 程序，把编译好的需要的3个文件烧写到Flash中对于的位置。
如果这个设想不通过，则需要在my_uboot中添加uboot的一下命令的实现。




阅读(667) | 评论(0) | 转发(0) |
0

上一篇：从零开始uboot—分析uboot1.1.6(4)

下一篇：从零开始uboot—实现(6)

给主人留下些什么吧！~~
关于我们 | 关于IT168 | 联系方式 | 广告合作 | 法律声明 | 免费注册

Copyright 2001-2010 ChinaUnix.net All Rights Reserved 北京皓辰网域网络信息技术有限公司. 版权所有

感谢所有关心和支持过ChinaUnix的朋友们

16024965号-6