EM78P153程序框架

EMC系列单片机有多种型号，每个IC由于设计方面的原因，各有不同，例如 EM78P153 的中断向量位置 跟 EM78P259 ，EM78P447等都不相同，如果只用一种IC开发的话，那倒问题不大，如果工作用用到各种IC的话，来回切换，给写程序带来了不便。于是我们想建立一个模板，结合宏的强大功能，方便的初始化IC，迅速建立运行环境，其实这里做的，有点类似 C 里面的 runtime 初始化部分，也类似bootloader，总之，目的就是快速建立环境，我们只需要从 main 函数开始写，而不需要花精力在芯片初始化部分。嘿嘿，理论上来这样算是比较方便的，但不是究极的方便，看过UBOOT就会有感触，为啥人家能支持那么多CPU，说到尾还是利用了宏定义的强大功能。当然，我在构思是否能利用一下shell的强大功能实现一个特殊的软件，恩，思考一下……

 

宏方面的使用原理，其实不难，本质上跟C是一样的，可以参看我之前的笔记：

http://blog.chinaunix.net/u1/52089/showart.php?id=419252

 

道理上来说，这东西不难，关键是比较烦，得有人去学写繁琐的宏定义，好吧，我吃螃蟹了，搞了一大堆东西出来，非常的方便。本文章所有东西原创。

 

主程序：EM78P153.DT

/*--------------------------------------------------------------------------
        1. 项目 : EM78P153程序框架
        2. 作者 : Etual / [e-mail]
        3. 日期 : 2008 - 12 - 10
        4. 编译平台 : WicePlus2.6081015
---------------------------------------------------------------------------*/
     /*
      * 包含下面用到的宏定义符号
      */
     include "head153.h"

;---------------------------------------------------------------------------------
     /*
      * 寄存器定义
      */
ABUFF EQU 0x10
PSWBUFF EQU 0x11
IntrCnt EQU 0x12

/*-------------------------------------------------------------------------------*/
               /*
                * 中断向量
                */
               ORG 0X00
               jmp start
               ORG 0X08
               jmp int_tcc
               
               ORG 0x20
               /*
                * TCC 中断服务函数
                */
INT_TCC:
               mov abuff,a
               swap abuff
               swapa psw
               mov pswbuff,a
              /*
               * 产生几个基准时间
               */
               inc IntrCnt
;---------------------------------------------------------------------
              /*
               * 在这里添加需要的中断函数
               */
               
               nop
;---------------------------------------------------------------------
int_end:
               bc 0x0f,0 ; Clear TCC interrupt flag
               swapa pswbuff
               mov psw,a
               swapa abuff
reti



               
;---------------------------MAIN PROGRAM------------------------------
start:
               call SysInit
loop:
              /*
               * 主循环，添加实际项目的功能模块
               */
              
               com 0x06
              ;-----------------------------
HaltProc:
               eni
               wdtc
               /*
                * 大循环周期 0.128ms * 128 = 16.3ms
                */
               mov a,@128
               sub a,Intrcnt
               jbs psw,c
               jmp HaltProc
               clr Intrcnt
               jmp loop





/*---------------------------------------------------------------------------------
               功能 : 系统初始化。
---------------------------------------------------------------------------------*/
SysInit:
               disi
           ; jbs psw,4 ; 程序看门狗复位纠错处理
           ; jmp error_proc

InitSRAM:
               /*------------------------------------------------
                               上电清空所有的RAM
               调用格式    ：
                       CLEAR_ALL_RAM FROM,TO
               宏参数定义    ：
                       FROM: 开始地址
                       TO    : 结束地址
               -------------------------------------------------*/
               nop
               CLEAR_ALL_RAM

InitCont:
               /*-------------------------------------------------
                               TCC定时器设置
               调用格式    :
                       CONT_SETUP MACRO arg1
               宏参数定义    :
                       TCC_1_1 ~ TCC_1_256 预分频
                    TCC_SRC_INT / TCC_SRC_EXT TCC源选择 INT:内部时钟，EXT 外部计数
                    TCC_EDGE_RISE / TCC_EDGE_FALL 触发弦选择 RISE 上升弦，FALL 下降弦
                    TCC_PRESCAL / WDT_PRESCAL 预分频分给TCC还是WDT
               -------------------------------------------------*/
               nop
               CONT_SETUP TCC_PRESCAL | TCC_1_1 | TCC_SRC_INT
InitIO:
               /*-----------------------------------------------
                            IO 口方向以及上下拉设置
               IOW MACRO ARG1,ARG2
                               IOR REG1,REG2 IOR REG2 -> REG1
                               IOW REG1,REG2 IOW REG2 -> REG1
               ------------------------------------------------*/
               nop
               mov a,@0X00
               iow 0x05 ; port5 I/O
               mov a,@0x00
               iow 0X06 ; port6 I/O
               mov a,@0XFF
               iow 0x0b ; PULL DOWN 0:ENABLE, 1:DISABLE
               mov a,@0X00
               iow 0x0c ; OPEN DRAIN 0:DISABLE, 1:ENABLE
               mov a,@0xff
               iow 0X0D ; PULL HIGH 0:ENABLE, 1:DISABLE
InitWatchdog:
               /*------------------------------------------------
                                 看门狗设置
               WDT_SETUP MACRO arg1
               宏参数定义：
                       WDT_ENABLE / WDT_DISABLE 允许看门狗
                    ROC_ENABLE / ROC_DISABLE R OPTION
                    EIS_IO / EIS_INT P60 作为IO还是外部中断
               -------------------------------------------------*/
               nop
               WDT_SETUP WDT_ENABLE | ROC_DISABLE | EIS_IO
InitInterrupt:
               /*------------------------------------------------
                                中断设置
               IMR1_SETUP MACRO arg1
                    argument : IMR_TCC /IMR_EXT
               ------------------------------------------------*/
               nop
               IMR1_SETUP IMR_TCC
ret


宏定义 head153.h

 

/*--------------------------------------------------------------------------
        1. 项目 : EM78P153 宏定义
        2. 作者 : Etual / [e-mail]
        3. 日期 : 2008 - 12 - 10
---------------------------------------------------------------------------*/


/*****************************************************
                   寄存器名字定义
*****************************************************/
R0 == 0X00
TCC == 0X01
PC == 0X02
PSW == 0X03
C == 0
DC == 1
Z == 2
POWERDOWN == 3
TIMEOUT == 4
R4 == 0X04
P5 == 0X05
P6 == 0X06
P7 == 0X07
R8 == 0X08
R9 == 0X09
RA == 0X0A
RB == 0X0B
RC == 0X0C
RD == 0X0D
RE == 0X0E
RF == 0X0F
;-----------------------------------------------------
IOC5 == 0X05
IOC6 == 0X06
IOC7 == 0X07
IOC8 == 0X08
IOC9 == 0X09
IOCA == 0X0A
IOCB == 0X0B
IOCC == 0X0C
IOCD == 0X0D
IOCE == 0X0E
IOCF == 0X0F
;-----------------------------------------------------

/*****************************************************
* 端口变化唤醒 *
*****************************************************/
IO_CHANGE_WAKEUP MACRO
          mov a,@0b00001110 ; 设置WDT预分频
          contw
          wdtc ; 清看门狗
          ior 0x0e
          and a,@0x7f ; 关闭看门狗
          iow 0x0e
          mov a,@0xff
          mov 0x06,0x06 ; 保存端口数据
          ior 0x0f
          or a,@0x02 ; 置能端口变化中断
          iow 0x0f
          disi ; 关闭全局中断
          nop
          slep ; 睡眠
          nop
          wdtc
ENDM

/*****************************************************
* CONT REGISTER *
*****************************************************/
TCC_1_1 == 0X08 /* TCC PRESCALE 1:1 (DEFAULT) */
TCC_1_2 == 0X00 /* TCC PRESCALE 1:2 */
TCC_1_4 == 0X01 /* TCC PRESCALE 1:4 */
TCC_1_8 == 0X02 /* TCC PRESCALE 1:8 */
TCC_1_16 == 0X03 /* TCC PRESCALE 1:16 */
TCC_1_32 == 0X04 /* TCC PRESCALE 1:32 */
TCC_1_64 == 0X05 /* TCC PRESCALE 1:64 */
TCC_1_128 == 0X06 /* TCC PRESCALE 1:128 */
TCC_1_256 == 0X07 /* TCC PRESCALE 1:256 */
                                                              /* 1/FOSC*PRESCAL*256 */
WDT_1_1 == 0X00
WDT_1_2 == 0X01
WDT_1_4 == 0X02
WDT_1_8 == 0X03
WDT_1_16 == 0X04
WDT_1_32 == 0X05
WDT_1_64 == 0X06
WDT_1_128 == 0X07
/****************************************************/
TCC_SRC_INT == 0X00 /* INTERNAL INSTRUCTION CLOCK */
TCC_SRC_ERX == 0X20 /* EXTERNAL CLOCK(TCC/P54 PIN)(DEF) */
TCC_EDGE_RISE == 0X00
TCC_EDGE_FALL == 0X10
TCC_PRESCAL == 0X00
WDT_PRESCAL == 0X08
/****************************************************/
CONT_SETUP MACRO ARG1
          mov a,@ARG1
          contw
ENDM

/*****************************************************
* WDT ENABLE *
*****************************************************/
WDT_ENABLE == 0x80
WDT_DISABLE == 0x00
ROC_ENABLE == 0X01
ROC_DISABLE == 0X00
EIS_IO == 0X00
EIS_INT == 0X40
/****************************************************/
WDT_SETUP MACRO ARG1
         mov a,@ARG1
         iow 0x0e
ENDM



/*****************************************************
* INTERRUPT MASK REGISTER *
*****************************************************/
IMR1 == 0X0F
IMR_TCC == 0X01
IMR_ICI == 0X02
IMR_EXT == 0X04
IMR1_ALL_DISABLE == 0X00
IMR1_ALL_ENABLE == 0XFF
/****************************************************/
IMR1_SETUP MACRO ARG1
          mov a,@ARG1
          iow 0x0f
ENDM

/*****************************************************
* CLEAR ALL RAM *
*****************************************************/

CLEAR_ALL_RAM macro
          mov a,@0x10
          mov 0x04,a
clr_ram:
          clr 0x00
          inc 0x04
          mov a,@0x2f
          and a,0x04
          jbs 0x03,2
          jmp clr_ram
ENDM