25 #if (PHYS_OFFSET & 0x001fffff)
26 #error "PHYS_OFFSET must be at an even 2MiB boundary!"
27 #endif
28 KERNEL_RAM_VADDR定义了经过映射后的内核镜像的virtual地址（link地址），PAGE_OFFSET=3G边界
KERNEL_RAM_PADDR定义了内核镜像的物理地址。
问题：内核镜像为什么一定要映射到高3G的地址上呢？不映射不行吗？
答案：多进程要求多个虚拟地址空间并存，而物理上内存空间只有一个，因此必须将各个进程的虚空间进行动态映射到同一个物理空间上；另一个方面，不同机器环境下，物理内存大小不尽相同（可能太大也可能太小了），必须通过映射屏蔽这些差异以便让进程看不到差异的使用4G（32bit环境）的地址空间！内核属于一个特殊的“进程”（并不是一个进程那么简单），也必须工作于虚地址空间之下（CPU处于实模式下只能寻址有限的物理地址空间），因此需要将物理地址映射到3G（这个3G并不是一定的，可以通过内核编译选项更改，但是通常都是3G）边界的虚地址之上运行，这样基地址+偏移量的寻址思想便可以无缝的使用了！此处答案为本人个人根据现有知识的理解，可能存在错误！
29 #define KERNEL_RAM_VADDR (PAGE_OFFSET + TEXT_OFFSET)
30 #define KERNEL_RAM_PADDR (PHYS_OFFSET + TEXT_OFFSET)
经过映射后的内核镜像的地址必须是1M对齐的！
40 #if (KERNEL_RAM_VADDR & 0xffff) != 0x8000 //The virtual addr of the kernel need to be 1M align
41 #error KERNEL_RAM_VADDR must start at 0xXXXX8000
42 #endif
定义了临时page table的存放地址（虚地址）0xC000000 - 0x4000
43 swapper_pg_dir
44 .globl swapper_pg_dir
45 .equ swapper_pg_dir, KERNEL_RAM_VADDR - 0x4000 @The temp page table base addr is here(0xC000000 - 0x4000)
46 该macro用于获取临时page table的物理地址
47 .macro pgtbl, rd
48 ldr \rd, =(KERNEL_RAM_PADDR - 0x4000)
49 .endm
50 XIP是片内执行的意思；针对某些存在NOR flash扩展的系统内核镜像是直接存放在XOR flash上运行的，因此镜像的地址应该是NOR flash的地址而不是RAM的地址。
51 #ifdef CONFIG_XIP_KERNEL
52 #define KERNEL_START XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
53 #define KERNEL_END _edata_loc
54 #else
55 #define KERNEL_START KERNEL_RAM_VADDR
56 #define KERNEL_END _end
57 #endif
第一阶段：
这一段是bootloader进入kernel的一个入口。在进入该函数之前，整个硬件系统至少需要初始化以下的状态：
1）MMU必须关闭（page table还没有建立，不能进行虚地址转实地址，CPU工作与相对寻址状态，CP指向的是物理地址）
2)D-cache是CPU的数据cache必须处于关闭状态；I-cache是命令cache可以开也可以关闭！
3）R0由bootloader必须清零；R1由bootloader设置为machine的number（这个是什么，可以查看内核的ARM boot文档arch/arm/tools/mach-types）；R2放置atag指针，bootloader在初始化过程中会将kernel必需的参数搜集并放入该atag list中并将这个地址传递给kernel以便在进入kernel后使用
77 .section ".text.head", "ax" 78 .type stext, %function
这里定义了由bootloader进入内核的入口stext！关键的部分来了，哈哈哈
79 ENTRY(stext)
由于要做一些底层的初始化，因此先将CPU切入SVC模式并关闭中断（由于中断向量表以及异常向量表并未建立，CPU无法响应中断请求！）
80 msr cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE @ ensure svc mode
81 @ and irqs disabled
通过协处理器获取处理器ID
82 mrc p15, 0, r9, c0, c0 @ get processor id
此处需要确定CPU的类型才能进行相应的初始化操作
83 bl __lookup_processor_type @ r5=procinfo r9=cpuid
84 movs r10, r5 @ invalid processor (r5=0)?
85 beq __error_p @ yes, error 'p'
根据内核中预置的信息，判断当前的board是哪个来确定存储器扩展以及扩展的外设有哪些
86 bl __lookup_machine_type @ r5=machinfo
87 movs r8, r5 @ invalid machine (r5=0)?
88 beq __error_a @ yes, error 'a'
此处会去校验atag的内容
89 bl __vet_atags
这里非常重要！由于CPU要开启MMU进入虚地址执行模式，因此必须先建立一个临时的page table（临时的意思是将来会这个table将会被抛弃，重新建立）
90 bl __create_page_tables
这一句十分重要也值得去细细推敲，看似没有什么用途，但是在后边开启MMU后进入虚地址空间（link地址）的部分至关重要！因为，该伪指令会将__switch_data对应的虚地址加载给r13寄存器，后面会通过将r13加载进pc（指令计数器）达到进入虚地址模式的目的！也就是说此前的所有代码工作于PIC（position independent code），并没有使用link地址，理解这一点很重要！
99 ldr r13, __switch_data @ address to jump to __mmap_switched(This is not PIC addr that means:it is a absolute addr in the kernel image, another words virtual addr) after the MMU switched on and return here which start execute code in the virtual space!!!!!!!!!!!!!!!!!!!!!!!!!!
100 @ mmu has been enabled
page table已经建立准备开启MMU
101 adr lr, __enable_mmu @ return (PIC) address
执行清除CPU cache以及TLB（table lookup buffer是MMU的高速缓冲区，提供高速虚实地址转换，原理是将以前的转换结果放在这个buffer当中，如果请求的地址在这里则不做全局搜索）的工作
102 add pc, r10, #PROCINFO_INITFUNC @Call the __cpu_flush to clear I-cache-D-cache TLB related registered as PROCINFO_INITFUNC
103 @After __enable_mmu start to exwcute __switch_data by mov pc, r13 in __enable_mmu
104
多CPU的系统暂时不分析！呵呵
105 #if defined(CONFIG_SMP)
106 .type secondary_startup, #function
107 ENTRY(secondary_startup)
108 /*
109 * Common entry point for secondary CPUs.
110 *
111 * Ensure that we're in SVC mode, and IRQs are disabled. Lookup
112 * the processor type - there is no need to check the machine type
113 * as it has already been validated by the primary processor.
114 */
115 msr cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE
116 mrc p15, 0, r9, c0, c0 @ get processor id
117 bl __lookup_processor_type
118 movs r10, r5 @ invalid processor?
119 moveq r0, #'p' @ yes, error 'p'
120 beq __error
121
122 /*
123 * Use the page tables supplied from __cpu_up.
124 */
125 adr r4, __secondary_data
126 ldmia r4, {r5, r7, r13} @ address to jump to after
127 sub r4, r4, r5 @ mmu has been enabled
128 ldr r4, [r7, r4] @ get secondary_data.pgdir
129 adr lr, __enable_mmu @ return address
130 add pc, r10, #PROCINFO_INITFUNC @ initialise processor
131 @ (return control reg)
132
133 /*
134 * r6 = &secondary_data
135 */
136 ENTRY(__secondary_switched)
137 ldr sp, [r7, #4] @ get secondary_data.stack
138 mov fp, #0
139 b secondary_start_kernel
140
141 .type __secondary_data, %object
142 __secondary_data:
143 .long .
144 .long secondary_data
145 .long __secondary_switched
146 #endif /* defined(CONFIG_SMP) */
147
开启MMU的函数
155 .type __enable_mmu, %function
156 __enable_mmu:
157 #ifdef CONFIG_ALIGNMENT_TRAP
158 orr r0, r0, #CR_A
159 #else
160 bic r0, r0, #CR_A
161 #endif
162 #ifdef CONFIG_CPU_DCACHE_DISABLE
163 bic r0, r0, #CR_C
164 #endif
165 #ifdef CONFIG_CPU_BPREDICT_DISABLE
166 bic r0, r0, #CR_Z
167 #endif
168 #ifdef CONFIG_CPU_ICACHE_DISABLE
169 bic r0, r0, #CR_I
170 #endif
此处MMU相关的设置，本人没有细究，有情趣的可以研究研究
171 mov r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
172 domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
173 domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
174 domain_val(DOMAIN_IO, DOMAIN_CLIENT))
175 mcr p15, 0, r5, c3, c0, 0 @ load domain access register
176 mcr p15, 0, r4, c2, c0, 0 @ load page table pointer
177 b __turn_mmu_on
这里真正的开启了MMU并从PIC进入virual地址空间运行！！
190 .align 5
191 .type __turn_mmu_on, %function
192 __turn_mmu_on:
执行延时操作（原因在于协处理器相关操作不能立即生效，需要几个ARM的指令周期后才能工作！）
193 mov r0, r0 @delay for the reason of the ARM execute flow!
194 mcr p15, 0, r0, c1, c0, 0 @ write control reg
195 mrc p15, 0, r3, c0, c0, 0 @ read id reg
196 mov r3, r3 @delay!!!!!for the reason of ARM execute flow!
197 mov r3, r3 @delay!!!!!
该行代码之前pc方的是物理地址，此后pc存放的将是虚地址，也就是phys+0xc000000
198 mov pc, r13 @jump to the __switch_data; r3 contains the virtual addr of __switch_data, because the MMU is on, so this virtual addr can be translated into the physical addr automatically!
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
以后的代码在虚地址空间运行！！！！！！！！！！！！！！！！！！！
该函数在PHYS_OFFSET+0x08000-0x4000处创建临时page table
215 .type __create_page_tables, %function
216 __create_page_tables:
217 pgtbl r4 @ Get page table base address r4=0x4000 16K addr
清零内存
222 mov r0, r4 @Back up base page table addr
223 mov r3, #0
224 add r6, r0, #0x4000 @ r6 contains the end of page table addr
225 /***Clear the 16K page table memory to 0*/
226 1: str r3, [r0], #4
227 str r3, [r0], #4
228 str r3, [r0], #4
229 str r3, [r0], #4
230 teq r0, r6
231 bne 1b
232 /**End*/
将内核镜像中的MMU flag数值取出，准备设置page table
233 ldr r7, [r10, #PROCINFO_MM_MMUFLAGS] @ get the mm_mmuflags
此处，为当前物理地址起的1M空间建立映射（1M源于ARM的MMU支持2级page，第一级支持1M的page或者指向2级的entry；由于内核镜像的特殊性，它的segments被放在一级page table的1M page内而不是存放在后面将要讲述的4kpage内）
该语句比较重要，pc此处指向物理地址，右移20次则得到当前物理地址的1M计数（再左移20位就是segment的地址！，相当于清零低20bit）
241 mov r6, pc, lsr #20 @ start of kernel section r6=pc>>20 contains section addr and the virt addr == phys addr
根据上句得出的段计数左移20位算出段地址，并将将低20bit设置成MMU的flag，得到一个map entry！
242 orr r3, r7, r6, lsl #20 @ flags + kernel base
将map entry数值写回page table相应的位置，以便MMU查表转换的时候使用！这里有一点值得注意：这里，映射前后的地址空间实际上上一样的，因为pc的虚地址跟物理地址重合！r6（可以理解r6的数值为page table的index）之所以左移2bit是由于每个page table的entry占4个字节，然后page entry addr=r4（基地址）+index*4
243 str r3, [r4, r6, lsl #2] @ identity mapping;Reason see r6=pc>>20
244 @ r6 contains the index offset in the page table so multiple 4 get the address of the L1 entry
245 /**Here we need an id to decide which page entry to write the r3, so we apply multi 4 to get the id*/
这里为内核镜像建立映射（映射的本质是设置page table entry，让MMU知道如何将虚地址转换成物理地址）；非XIP的时候KERNEL_RAM_VADDR=KERNEL_START
251 add r0, r4, #(KERNEL_START & 0xff000000) >> 18 //Should firstly right shift 20bits and for the reason of page entry is 4 bytes size so left s hift 2 then is 18;What is 0xff000000?while not 0xfff00000? Answer is in the next code 0x0f00000+0xff000000=0xfff0000!
252 str r3, [r0, #(KERNEL_START & 0x00f00000) >> 18]! //Attention!r3's content remains as the kernel section map, so
253 //The two virtual addr corresponds to the same phys addr!
254 ldr r6, =(KERNEL_END - 1)
255 add r0, r0, #4 //Point to the next L1 entry!
256 add r6, r4, r6, lsr #18 //Caculate the end of L1 entry
257 1: cmp r0, r6 //Reaching the end of entry?
258 add r3, r3, #1 << 20 //add the segment addr for 1
259 strls r3, [r0], #4
260 bls 1b
261
262 #ifdef CONFIG_XIP_KERNEL
263 /*
264 * Map some ram to cover our .data and .bss areas.
265 */
266 orr r3, r7, #(KERNEL_RAM_PADDR & 0xff000000)
267 .if (KERNEL_RAM_PADDR & 0x00f00000)
268 orr r3, r3, #(KERNEL_RAM_PADDR & 0x00f00000)
269 .endif
270 add r0, r4, #(KERNEL_RAM_VADDR & 0xff000000) >> 18
271 str r3, [r0, #(KERNEL_RAM_VADDR & 0x00f00000) >> 18]!
272 ldr r6, =(_end - 1)
273 add r0, r0, #4
274 add r6, r4, r6, lsr #18
275 1: cmp r0, r6
276 add r3, r3, #1 << 20
277 strls r3, [r0], #4
278 bls 1b
279 #endif
由于最低1M存放了bootloader传递给kernel的一些参数，因此需要为它建立map这样开启MMU后就可以访问这些参数了。
284 add r0, r4, #PAGE_OFFSET >> 18 @The base virtual addr!
285 orr r6, r7, #(PHYS_OFFSET & 0xff000000)
286 .if (PHYS_OFFSET & 0x00f00000)
287 orr r6, r6, #(PHYS_OFFSET & 0x00f00000)
288 .endif
289 str r6, [r0]
建好页表返回
332 mov pc, lr
333 .ltorg
334
335 #include "head-common.S"
