Chinaunix首页 | 论坛 | 博客

wangcong02345wangcong02345.blog.chinaunix.net

首页　| 　博文目录　| 　关于我

wangcong02345

  • 博客访问： 2159628
  • 博文数量： 438
  • 博客积分： 3871
  • 博客等级： 中校
  • 技术积分： 6075
  • 用 户 组： 普通用户
  • 注册时间： 2011-09-10 00:11
个人简介

邮箱: wangcong02345@163.com

文章分类

全部博文（438）

文章存档

2017年（15）

2016年（119）

2015年（91）

2014年（62）

2013年（56）

2012年（79）

2011年（16）

我的朋友
最近访客
推荐博文
相关博文
写操作系统----4.开启分页

分类： LINUX

2016-08-19 18:52:21

1. 实现分页机制的代码
  1. org 0x9000
  2. jmp begin
  3. ;segment discript
  4. TYPE_8 equ 0x8 ;code -->exec
  5. TYPE_2 equ 0x2 ;data -->r/w

  7. S_0 equ (0x0<<4) ;s=0-->gate
  8. S_1 equ (0x1<<4) ;s=1-->data/code

  10. DPL_0 equ (0x0<<5) ;privilege level
  11. DPL_3 equ (0x3<<5)

  13. P_0 equ (0x00<<7) ;not in memory
  14. P_1 equ (0x01<<7) ;in memory

  16. AVL_0 equ (0x00<<8)

  18. DB_0 equ (0x00<<10) ;16bit data&code
  19. DB_1 equ (0x01<<10) ;32bit data&code

  21. G_0 equ (0x00<<11) ;g=0,byte
  22. G_1 equ (0x01<<11) ;g=1,4K

  24. TI_0 equ (0x0<<2) ;TI=0,gdt
  25. TI_1 equ (0x1<<2) ;TI=1,ldt

  27. RPL_0 equ (0x0)

  29. ;PAGE
  30. PAGE_POS equ 0xF0000       ;0xF0000-->0xFFFFF-->64K
  31. PG_P_0 equ (0x0)           ;not in memory
  32. PG_P_1 equ (0x1)           ;in memory

  34. PG_RW_0 equ (0x0<<1) ;read,not write
  35. PG_RW_1 equ (0x1<<1) ;read,write

  37. PG_US_0 equ (0x0<<2) ;supervisor
  38. PG_US_1 equ (0x1<<2) ;user

  40. PG_PWT_0 equ (0x0<<3) ;memory
  41. PG_PWT_1 equ (0x1<<3) ;memory and cache

  43. PG_PCD_0 equ (0x0<<4) ;disable page level cache
  44. PG_PCD_1 equ (0x1<<4) ;enable page level cache

  46. PG_A_0 equ (0x0<<5) ;not accessed
  47. PG_A_1 equ (0x1<<5) ;accessed

  49. PG_D_0 equ (0x0<<6) ;not dirty
  50. PG_D_1 equ (0x1<<6) ;dirty

  52. PG_PAT_0 equ (0x0<<7) ;page attribute tabel
  53. PG_PAT_1 equ (0x1<<7) ;

  55. PG_G_0 equ (0x0<<8) ;global-->TLB
  56. PG_G_1 equ (0x1<<8) ;

  58. PG_AVL_0 equ (0x0<<9) ;available
  59. PG_AVL_1 equ (0x1<<9) ;
  60. %macro DESC 3
  61.     dw %1 & 0xFFFF ;limit[0-15]
  62.     dw %2 & 0xFFFF ;base[0-15]
  63.     db (%2>>16)&0xFF ;base[16-23]
  64.     db (%3&0xFF) ;prop[0-7]
  65.     db (((%1>>16)&0xF) | (%3>>4)&0xF0) ;limit[16-19]prop[8-11]
  66.     db (%2>>24) & 0xFF
  67. %endmacro
  68. gdt_base: DESC 0, 0, 0
  69. gdt_code: DESC 0xFFFF, 0x0, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_8)
  70. gdt_video: DESC 0xFFFF, 0xB8000, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_2)

  72. gdt_ptr:
  73.     dw 24 ;gdt_limit: 8*3=16, only 3 gdt item
  74.     dd gdt_base ;gdt_base

  76. select_code equ (0x01<<3)|TI_0|RPL_0
  77. select_video equ (0x02<<3)|TI_0|RPL_0
  78. begin:
  79.     mov ah, 0x88
  80.     int 0x15
  81.     mov cx, ax
  82.     ;----------------- 打开A20 ----------------
  83.     in al,0x92
  84.     or al,0000_0010B
  85.     out 0x92,al

  87.     ;----------------- 加载GDT ----------------
  88.     lgdt [gdt_ptr]

  90.     ;----------------- cr0第0位置1 ----------------
  91.     mov eax, cr0
  92.     or eax, 0x00000001
  93.     mov cr0, eax

  95.     ;----------------- 跳到保护模式 ----------------
  96.     jmp select_code:protect_mode
  97. [bits 32]
  98. protect_mode:
  99.     mov ax,select_video
  100.     mov gs,ax
  101.     mov byte [gs:160], 'P'
  102.     mov byte [gs:161], 0xA4

  104.     call setup_page_table    

  106.     sgdt [gdt_ptr]
  107.     
  108.     or dword [gdt_ptr+2], 0xC0000000 ; gdt_ptr
  109.     or byte [gdt_base+7], 0xC0 ;change gdt base addr
  110.     or byte [gdt_base+16+7], 0xC0 ;select_video: byte8

  112.     or esp, 0xC0000000

  114.     mov eax, PAGE_POS
  115.     mov cr3, eax
  116.         
  117.     ;打开cr0的pg位
  118.     mov eax, cr0
  119.     or eax, 0x80000000
  120.     mov cr0, eax

  122.     lgdt [gdt_ptr]

  124.     mov byte [gs:162], 'G'
  125.     mov byte [gs:163], 0xA4
  126.     jmp $

  128. setup_page_table:
  129.     mov ecx, 0x1000 ;1PTE:4K=0x1000      -->清空4k个字节每次清4个字节，这儿应为0x1000/4=0x400
  130.     xor esi, esi
  131.     mov eax, (PG_US_1|PG_RW_1|PG_P_1)    -->如果一开始就把PTE设为可用的话,bochs里面info tab会打印出上万条映射
  132. _init_page_table:
  133.     mov [PAGE_POS+esi], eax
  134.     add esi,0x04
  135.     loop _init_page_table

  137.     ;PDE0, PDE768 use the same PTE0
  138.     or eax,(0x01<<12)
  139.     mov [PAGE_POS+0x0], eax
  140.     mov [PAGE_POS+0xc00], eax

  142.     ;PTE for PDE0 and PDE768
  143.     mov ecx,256
  144.     xor esi,esi
  145.     mov eax, (PG_US_1|PG_RW_1|PG_P_1)
  146. _create_pte:
  147.     mov [PAGE_POS+0x1000+esi],eax
  148.     add esi,0x04
  149.     add eax,0x1000
  150.     loop _create_pte

  152.     ;create other PDE for kernel

  154.     ret

1.1 由于loader.bin没有超过512,所以不需要改mbr.S
  1. cong@msi:/work/os/code/4page$ ls -l loader.bin
  2. -rw-rw-r-- 1 cong cong 263 Aug 19 18:18 loader.bin
1.2.a 关于段界限的修改
在没有修改阶界限之前是不能访问1M以上字节的，因为刚开始code段的范围是0-0xFFFF
  1. <bochs:1> b 0x904e
  2. <bochs:2> c
  3. (0) Breakpoint 1, 0x0000904e in ?? ()
  4. Next at t=156817618
  5. (0) [0x00000000904e] 0008:0000904e (unk. ctxt): mov byte ptr gs:0x000000a1, 0xa4 ; 65c605a1000000a4
  6. <bochs:3> s
  7. Next at t=156817619
  8. (0) [0x000000009056] 0008:00009056 (unk. ctxt): call .+81 (0x000090ac) ; e851000000
  9. <bochs:4>
  10. Next at t=156817620
  11. (0) [0x0000000090ac] 0008:000090ac (unk. ctxt): mov ecx, 0x00001000 ; b900100000
  12. <bochs:5>
  13. Next at t=156817621
  14. (0) [0x0000000090b1] 0008:000090b1 (unk. ctxt): xor esi, esi ; 31f6
  15. <bochs:6>
  16. Next at t=156817622
  17. (0) [0x0000000090b3] 0008:000090b3 (unk. ctxt): mov eax, 0x00000007 ; b807000000
  18. <bochs:7>
  19. Next at t=156817623
  20. (0) [0x0000000090b8] 0008:000090b8 (unk. ctxt): mov dword ptr ds:[esi+983040], eax ; 898600000f00
  21. <bochs:8>
  22. (0).[156817623] [0x0000000090b8] 0008:000090b8 (unk. ctxt): mov dword ptr ds:[esi+983040], eax ; 898600000f00
  23. Next at t=156817624
  24. (0) [0x0000fffffff0] f000:fff0 (unk. ctxt): jmpf 0xf000:e05b ; ea5be000f0   -->重启了
983040=0xF0000,info gdt后发现没有一个段可以到地址0xF0000
  1. <bochs:3> info gdt
  2. Global Descriptor Table (base=0x00009002, limit=24):
  3. GDT[0x00]=??? descriptor hi=0x00000000, lo=0x00000000
  4. GDT[0x01]=Code segment, base=0x00000000, limit=0x0000ffff, Execute-Only, Non-Conforming, Accessed, 32-bit   -->code段的范轩是0-0xffff
  5. GDT[0x02]=Data segment, base=0x000b8000, limit=0x0000ffff, Read/Write, Accessed                             -->视频段的范围是0xb8000-(0xb8000+0xffff)
  6. You can list individual entries with 'info gdt [NUM]' or groups with 'info gdt [NUM] [NUM]'
这儿需要添加一个数据段，放分页的数据
1.2.b
添加数据段之后忘改段界限了，info gdt 后还是只有3个段
    1.  73 gdt_ptr:
    2.  74 dw 24 ;gdt_limit: 3*8=32, only 3 gdt item
    3.  75 dd gdt_base ;gdt_base
  2. <bochs:14> info gdt
  3. Global Descriptor Table (base=0x00009002, limit=24):
  4. GDT[0x00]=??? descriptor hi=0x00000000, lo=0x00000000
  5. GDT[0x01]=Code segment, base=0x00000000, limit=0x000fffff, Execute-Only, Non-Conforming, Accessed, 32-bit
  6. GDT[0x02]=Data segment, base=0x00000000, limit=0x0000ffff, Read/Write
  7. You can list individual entries with 'info gdt [NUM]' or groups with 'info gdt [NUM] [NUM]'

1.2.c
有了数据段之后，就重新设置一个各个段寄存器
  1.  96 protect_mode:
  2.  97 mov ax, select_code   --->这儿需要修改
  3.  98 mov ds, ax
  4.  99 mov es, ax

  6. <bochs:13>
  7. Next at t=156817514
  8. (0) [0x000000009040] 0008:00009040 (unk. ctxt): mov ds, ax ; 8ed8
  9. <bochs:14>
  10. (0).[156817514] [0x000000009040] 0008:00009040 (unk. ctxt): mov ds, ax ; 8ed8
  11. Next at t=156817515
  12. (0) [0x0000fffffff0] f000:fff0 (unk. ctxt): jmpf 0xf000:e05b ; ea5be000f0

1.2.d 
出现下面这个情况说明页表没有正确的设置好,PDE没有设置正确
  1. Next at t=1252900596
  2. (0) [0x0000000090a1] 0008:000090a1 (unk. ctxt): mov cr0, eax ; 0f22c0
  3. <bochs:38>
  4. Next at t=1252900597
  5. (0).[1252900597] ??? (physical address not available)


  8. <bochs:34> xp /31 0x1F0000
  9. [bochs]:
  10. 0x001f0000 <bogus+ 0>: 0x00001007 0x00000007 0x00000007 0x00000007
  11. 0x001f0010 <bogus+ 16>: 0x00000007 0x00000007 0x00000007 0x00000007
  12. 0x001f0020 <bogus+ 32>: 0x00000007 0x00000007 0x00000007 0x00000007
  13. 0x001f0030 <bogus+ 48>: 0x00000007 0x00000007 0x00000007 0x00000007
  14. 0x001f0040 <bogus+ 64>: 0x00000007 0x00000007 0x00000007 0x00000007
  15. 0x001f0050 <bogus+ 80>: 0x00000007 0x00000007 0x00000007 0x00000007
  16. 0x001f0060 <bogus+ 96>: 0x00000007 0x00000007 0x00000007 0x00000007
  17. 0x001f0070 <bogus+ 112>: 0x00000007 0x00000007 0x00000007
1.2.e
info gdt 出现上万个，说明PDE的属性都设置成可用了，想少打印只需把用得着的属性设为可用即可
  1. cr3: 0x000000100000
  2. 0x00000000-0x000fffff -> 0x000000000000-0x0000000fffff
  3. 0x00400000-0x00400fff -> 0x0000f000f000-0x0000f000ffff
  4. ...
  5. 0xffffe000-0xffffefff -> 0x000000000000-0x000000000fff
    0xfffff000-0xffffffff -> 0x000000100000-0x000000100fff  106190个
改完之后
  1. <bochs:37> info tab
  2. cr3: 0x000000100000
  3. 0x00000000-0x000fffff -> 0x000000000000-0x0000000fffff
  4. 0xc0000000-0xc00fffff -> 0x000000000000-0x0000000fffff
  5. 0xffc00000-0xffc00fff -> 0x000000101000-0x000000101fff
  6. 0xfff00000-0xfff00fff -> 0x000000101000-0x000000101fff
  7. 0xfffff000-0xffffffff -> 0x000000100000-0x000000100fff
1.3 正确代码分析
  1. org 0x9000
  2. jmp begin
  3. ;segment discript
  4. TYPE_8 equ 0x8 ;code -->exec
  5. TYPE_2 equ 0x2 ;data -->r/w

  7. S_0 equ (0x0<<4) ;s=0-->gate
  8. S_1 equ (0x1<<4) ;s=1-->data/code

  10. DPL_0 equ (0x0<<5) ;privilege level
  11. DPL_3 equ (0x3<<5)

  13. P_0 equ (0x00<<7) ;not in memory
  14. P_1 equ (0x01<<7) ;in memory

  16. AVL_0 equ (0x00<<8)

  18. DB_0 equ (0x00<<10) ;16bit data&code
  19. DB_1 equ (0x01<<10) ;32bit data&code

  21. G_0 equ (0x00<<11) ;g=0,byte
  22. G_1 equ (0x01<<11) ;g=1,4K

  24. TI_0 equ (0x0<<2) ;TI=0,gdt
  25. TI_1 equ (0x1<<2) ;TI=1,ldt

  27. RPL_0 equ (0x0)

  29. ;PAGE
  30. PAGE_POS equ 0x1F0000    ;0xF0000-->0xFFFFF-->64K
  31. ;PAGE_POS equ 0x1F0100   ;这儿测试PTE是否可以在 4K不对齐的地址上，答案是不可以，必须4K对齐
  32. PG_P_0 equ (0x0) ;not in memory
  33. PG_P_1 equ (0x1) ;in memory

  35. PG_RW_0 equ (0x0<<1) ;read,not write
  36. PG_RW_1 equ (0x1<<1) ;read,write

  38. PG_US_0 equ (0x0<<2) ;supervisor
  39. PG_US_1 equ (0x1<<2) ;user

  41. PG_PWT_0 equ (0x0<<3) ;memory
  42. PG_PWT_1 equ (0x1<<3) ;memory and cache

  44. PG_PCD_0 equ (0x0<<4) ;disable page level cache
  45. PG_PCD_1 equ (0x1<<4) ;enable page level cache

  47. PG_A_0 equ (0x0<<5) ;not accessed
  48. PG_A_1 equ (0x1<<5) ;accessed

  50. PG_D_0 equ (0x0<<6) ;not dirty
  51. PG_D_1 equ (0x1<<6) ;dirty

  53. PG_PAT_0 equ (0x0<<7) ;page attribute tabel
  54. PG_PAT_1 equ (0x1<<7) ;

  56. PG_G_0 equ (0x0<<8) ;global-->TLB
  57. PG_G_1 equ (0x1<<8) ;

  59. PG_AVL_0 equ (0x0<<9) ;available
  60. PG_AVL_1 equ (0x1<<9) ;
  61. %macro DESC 3
  62.     dw %1 & 0xFFFF ;limit[0-15]
  63.     dw %2 & 0xFFFF ;base[0-15]
  64.     db (%2>>16)&0xFF ;base[16-23]
  65.     db (%3&0xFF) ;prop[0-7]
  66.     db (((%1>>16)&0xF) | (%3>>4)&0xF0) ;limit[16-19]prop[8-11]
  67.     db (%2>>24) & 0xFF
  68. %endmacro
  69. gdt_base: DESC 0, 0, 0 ;desc_dummy
  70. gdt_code: DESC 0xFFFFFF, 0x0, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_8)
  71. gdt_data: DESC 0xFFFFF, 0x0, (G_1|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_2)          ;这儿加了一个data段且段界限是0xFFFFF×4K=4G
  72. gdt_video: DESC 0xFFFF, 0xB8000, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_2)

  74. gdt_ptr:
  75.     dw 32       ;gdt_limit: 4*8=32, only 4 gdt item         ;加gdt_data后这儿还是24,死活调不出来
  76.     dd gdt_base ;gdt_base

  78. select_code equ (0x01<<3)|TI_0|RPL_0
  79. select_data equ (0x02<<3)|TI_0|RPL_0
  80. select_video equ (0x03<<3)|TI_0|RPL_0
  81. begin:
  82.     mov cx, ax
  83.     ;----------------- 打开A20 ----------------
  84.     in al,0x92
  85.     or al,0000_0010B
  86.     out 0x92,al

  88.     ;----------------- 加载GDT ----------------
  89.     lgdt [gdt_ptr]

  91.     ;----------------- cr0第0位置1 ----------------
  92.     mov eax, cr0
  93.     or eax, 0x00000001
  94.     mov cr0, eax

  96.     ;----------------- 跳到保护模式 ----------------
  97.     jmp select_code:protect_mode
  98. [bits 32]
  99. protect_mode:
  100.     mov ax, select_data
  101.     mov ds, ax
  102.     mov es, ax
  103.     mov ax, select_video
  104.     mov gs, ax
  105.     mov byte [gs:160], 'P'
  106.     mov byte [gs:161], 0xA4

  108.     call setup_page_table    

  110.     sgdt [gdt_ptr]
  111.     
  112.     or dword [gdt_ptr+2], 0xC0000000     ; gdt_ptr
  113.     or byte [gdt_base+7], 0xC0           ;change gdt base addr
  114.     or byte [gdt_base+8+7], 0xC0         ;change gdt base addr
  115.     or byte [gdt_base+16+7], 0xC0        ;select_video: byte8

  117.     or esp, 0xC0000000

  119.     mov eax, PAGE_POS
  120.     mov cr3, eax
  121.         
  122.     ;打开cr0的pg位
  123.     mov eax, cr0
  124.     or eax, 0x80000000
  125.     mov cr0, eax

  127.     lgdt [gdt_ptr]

  129.     mov byte [gs:162], 'G'
  130.     mov byte [gs:163], 0xA4
  131.     jmp $

  133. setup_page_table:
  134.     mov ecx, 0x400 ;1PTE:4K=0x1000
  135.     xor esi, esi
  136.     xor eax, eax
  137. _init_page_table:
  138.     mov [PAGE_POS+esi], eax
  139.     add esi,0x04
  140.     loop _init_page_table

  142.     ;PDE0, PDE768 use the same PTE0
  143.     mov eax, (PG_US_1|PG_RW_1|PG_P_1)
  144.     or eax, ((PAGE_POS+0x1000)&0xFFF000)     
  145.     mov [PAGE_POS+0x0], eax
  146.     mov [PAGE_POS+0xc00], eax
  147.     sub eax, 0x1000
  148.     mov [PAGE_POS+0xFFC], eax

  150.     ;PTE for PDE0 and PDE768
  151.     mov ecx,256
  152.     xor esi,esi
  153.     mov eax, (PG_US_1|PG_RW_1|PG_P_1)
  154. _create_pte:
  155.     mov [PAGE_POS+0x1000+esi],eax
  156.     add esi,0x04
  157.     add eax,0x1000
  158.     loop _create_pte

  160.     ;create other PDE for kernel

  162.     ret
1.4 代码打包
4page.rar  (下载后改名为4page.tar.gz)

1.5 注意
a. PDE[12-31]位存的是 PTE的[12-31]位，而PDE与PTE中存的是物理地址，但是后12位是不存的。
换句话话PDE与PTE只存物理地址的[12-31]位，低12位用来放属性，cpu在查找时直接把PDE与PTE的低12位设为0。
PDE的基地址是4K对齐的，PTE的基地址也是4K对齐的。
b. 这也就是为什么PAGE_POS不能在4K不对齐的地址上的原因
PAGE_POS equ 0x1F0000    ;0xF0000-->0xFFFFF-->64K
;PAGE_POS equ 0x1F0100   ;这儿测试PTE是否可以在 4K不对齐的地址上，答案是不可以，必须4K对齐
阅读(1104) | 评论(0) | 转发(0) |
0

上一篇：写操作系统----3.进入保护模式

下一篇：linux驱动16---用户空间获得变量的物理地址

给主人留下些什么吧！~~
关于我们 | 关于IT168 | 联系方式 | 广告合作 | 法律声明 | 免费注册

Copyright 2001-2010 ChinaUnix.net All Rights Reserved 北京皓辰网域网络信息技术有限公司. 版权所有

感谢所有关心和支持过ChinaUnix的朋友们

16024965号-6