Chinaunix首页 | 论坛 | 博客

wangcong02345wangcong02345.blog.chinaunix.net

首页　| 　博文目录　| 　关于我

wangcong02345

  • 博客访问： 2112744
  • 博文数量： 438
  • 博客积分： 3871
  • 博客等级： 中校
  • 技术积分： 6075
  • 用 户 组： 普通用户
  • 注册时间： 2011-09-10 00:11
个人简介

邮箱: wangcong02345@163.com

文章分类

全部博文（438）

文章存档

2017年（15）

2016年（119）

2015年（91）

2014年（62）

2013年（56）

2012年（79）

2011年（16）

我的朋友
最近访客
推荐博文
相关博文
写操作系统----3.进入保护模式

分类： LINUX

2016-08-17 15:57:56

《操作系统真相还原》 与 《Orange'S：一个操作系统的实现》都参考了
在上一篇文章中mbr读取了硬盘上的一个sector到0x9000,然后跳到了0x9000运行
1. 第一次写的loader.S
  1. org 0x9000
  2. jmp begin

  4. TYPE_0 equ 0x0

  6. S_0 equ (0x0<<4) ;s=0-->gate
  7. S_1 equ (0x1<<4) ;s=1-->data/code

  9. DPL_0 equ (0x0<<5) ;privilege level
  10. DPL_3 equ (0x3<<5)

  12. P_0 equ (0x00<<7) ;not in memory
  13. P_1 equ (0x01<<7) ;in memory

  15. AVL_0 equ (0x00<<8)

  17. DB_0 equ (0x00<<10) ;16bit data&code
  18. DB_1 equ (0x01<<10) ;32bit data&code

  20. G_0 equ (0x00<<11) ;g=0,byte
  21. G_1 equ (0x01<<11) ;g=1,4K

  23. TI_0 equ (0x0<<2) ;TI=0,gdt
  24. TI_1 equ (0x1<<2) ;TI=1,ldt

  26. RPL_0 equ (0x0)

  28. %macro DESC 3
  29.     dw %1 & 0xFFFF ;limit[0-15]
  30.     dw %2 & 0xFFFF ;base[0-15]
  31.     db (%2>>16)&0xFF ;base[16-23]
  32.     db (%3&0xFF) ;prop[0-7]
  33.     db (((%1>>8)&0xF) | (%3>>4)&0xF0) ;limit[16-19]prop[8-11]
  34.     db (%2>>24) & 0xFF
  35. %endmacro
  36. gdt_base: DESC 0, 0, 0
  37. gdt_code: DESC 0xFFFF, 0x0, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1)
  38. gdt_video: DESC 0xFFFF, 0xB8000, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1)

  40. gdt_ptr:
  41.     dw 24 ;gdt_limit: 8*3=16, only 3 gdt item
  42.     dd gdt_base ;gdt_base

  44. select_code equ (0x01<<3)|TI_0|RPL_0
  45. select_video equ (0x02<<3)|TI_0|RPL_0
  46. begin:
  47.     ;----------------- 打开A20 ----------------
  48.     in al,0x92
  49.     or al,0000_0010B
  50.     out 0x92,al

  52.     ;----------------- 加载GDT ----------------
  53.     lgdt [gdt_ptr]

  55.     ;----------------- cr0第0位置1 ----------------
  56.     mov eax, cr0
  57.     or eax, 0x00000001
  58.     mov cr0, eax

  60.     ;----------------- 跳到保护模式 ----------------
  61.     jmp select_code:protect_mode
  62. protect_mode:
  63.     mov ax,select_video
  64.     mov gs,ax
  65.     mov byte [gs:160], 'P'
  66.     jmp $
1.2 看需不需要改mbr
  1. cong@msi:/work/os/code/3pm$ ls -l loader.bin
  2. -rw-rw-r-- 1 cong cong 86 Aug 17 14:24 loader.bin
才86个字节，mbr是读了512个字节，这儿不到512字节，所以不需要修改mbr.S
下面开始分析问题
2. 
2.1.a 第一次调试
  1. (0) [0x0000fffffff0] f000:fff0 (unk. ctxt): jmpf 0xf000:e05b          ; ea5be000f0
  2. <bochs:1> b 0x9000                      -->因为把代码加载到了0x9000，所以这儿直接到0x9000执行
  3. <bochs:2> c
  4. (0) Breakpoint 1, 0x00009000 in ?? ()
  5. Next at t=156817505
  6. .....
  7. <bochs:11>
  8. Next at t=156817513
  9. (0) [0x000000009035] 0000:00009035 (unk. ctxt): jmpf 0x0008:903a ; ea3a900800    -->向保护模式跳转
  10. <bochs:12>
  11. (0).[156817513] [0x000000009035] 0000:00009035 (unk. ctxt): jmpf 0x0008:903a ; ea3a900800  
  12. Next at t=156817514
  13. (0) [0x0000fffffff0] f000:fff0 (unk. ctxt): jmpf 0xf000:e05b ; ea5be000f0 -->这儿发现不对了,这儿是复位了
2.1.b 第一次修改
  1. cong@msi:/work/os/code/3pm$ diff ./loader.S loader.S_bad
  2. 4,5c4
  3. < TYPE_8 equ 0x8 ;code -->exec
  4. < TYPE_2 equ 0x2 ;data -->r/w
  5. ---
  6. > TYPE_0 equ 0x0
  7. 38,39c37,38
  8. < gdt_code: DESC 0xFFFF, 0x0, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_8)   -->code段加上可执行权限
  9. < gdt_video: DESC 0xFFFF, 0xB8000, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_2)   
  10. ---
  11. > gdt_code: DESC 0xFFFF, 0x0, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1)          -->原先code段没有可执行权限
  12. > gdt_video: DESC 0xFFFF, 0xB8000, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1)
2.2.a 第二次调试
  1. (0) [0x000000009039] 0000:00009039 (unk. ctxt): jmpf 0x0008:903e ; ea3e900800
  2. <bochs:15>
  3. Next at t=313385561
  4. (0) [0x00000000903e] 0008:0000903e (unk. ctxt): mov eax, 0xe88e0010 ; b810008ee8    -->这儿的确是跳到903e上面来了，但是还是乱的
  5. <bochs:16>
  6. Next at t=313385562
  7. (0) [0x000000009043] 0008:00009043 (unk. ctxt): mov byte ptr gs:[esi], 0xa0 ; 65c606a0
  8. <bochs:17>
  9. Next at t=313385563
  10. (0) [0x000000009047] 0008:00009047 (unk. ctxt): add byte ptr ds:[eax+101], dl ; 005065
  11. <bochs:18>
  12. (0).[313385563] [0x000000009047] 0008:00009047 (unk. ctxt): add byte ptr ds:[eax+101], dl ; 005065
  13. Next at t=313385564
  14. (0) [0x0000fffffff0] f000:fff0 (unk. ctxt): jmpf 0xf000:e05b ; ea5be000f0
  15. <bochs:19>
  16. Next at t=313385565
  17. (0) [0x0000000fe05b] f000:e05b (unk. ctxt): xor ax, ax ; 31c0
2.2.b第二次修改
  1. 63 [bits 32]               -->加入这个标签，使得这儿编出来的是32位的代码
  2. 64 protect_mode:
2.2.c 对比一下两次生成的二进制代码
xxd ./loader.bin
  1. 0000000: eb1e 0000 0000 0000 0000 ffff 0000 0098 ................
  2. 0000010: 4f00 ffff 0080 0b92 4f00 1800 0290 0000 O.......O.......
  3. 0000020: e492 0c02 e692 0f01 161a 900f 20c0 6683 ............ .f.    -->没有加[bits 32]标签
  4. 0000030: c801 0f22 c0ea 3a90 0800 b810 008e e865 ..."..:........e
  5. 0000040: c606 a000 50eb fe ....P..


  8. 0000000: eb1e 0000 0000 0000 0000 ffff 0000 0098 ................
  9. 0000010: 4f00 ffff 0080 0b92 4f00 1800 0290 0000 O.......O.......
  10. 0000020: e492 0c02 e692 0f01 161a 900f 20c0 6683 ............ .f.    -->加了[bits 32]标签
  11. 0000030: c801 0f22 c0ea 3a90 0800 66b8 1000 8ee8 ..."..:...f.....
  12. 0000040: 65c6 05a0 0000 0050 ebfe e......P..
2.3 运行结果就对了


2.4 虽然结果上是对了，但还有点小问题
  1. cong@msi:/work/os/code/3pm$ diff ./loader.S loader.S_ok
  2. 34c34
  3. < db (((%1>>8)&0xF) | (%3>>4)&0xF0) ;limit[16-19]prop[8-11]    -->arg1的前16位己填序，现在要填16-19位
  4. ---
  5. > db (((%1>>16)&0xF) | (%3>>4)&0xF0) ;limit[16-19]prop[8-11]   -->所以要右称16位
2.5 代码打包
3pm.rar (下载后改名为3pm.tar.gz)
2.6 下面分析一下代码
  1. cong@msi:/work/os/code/3pm$ cat loader.S
  2. org 0x9000                            --> org是条伪指令不会生成二进制的代码
  3. jmp begin                             --> jmp下面是数据，cpu区分不了数据与代码，防止cpu把数据当成代码就加上jmp,人为的控制cpu去执行代码段中的代码
 -->下面定义了一堆段属性
  1. TYPE_8 equ 0x8 ;code -->exec
  2. TYPE_2 equ 0x2 ;data -->r/w

  4. S_0 equ (0x0<<4) ;s=0-->gate
  5. S_1 equ (0x1<<4) ;s=1-->data/code

  7. DPL_0 equ (0x0<<5) ;privilege level
  8. DPL_3 equ (0x3<<5)

  10. P_0 equ (0x00<<7) ;not in memory
  11. P_1 equ (0x01<<7) ;in memory

  13. AVL_0 equ (0x00<<8)

  15. DB_0 equ (0x00<<10) ;16bit data&code
  16. DB_1 equ (0x01<<10) ;32bit data&code

  18. G_0 equ (0x00<<11) ;g=0,byte
  19. G_1 equ (0x01<<11) ;g=1,4K

  21. TI_0 equ (0x0<<2) ;TI=0,gdt
  22. TI_1 equ (0x1<<2) ;TI=1,ldt

  24. RPL_0 equ (0x0)
  25. -->宏中arg1=段界限，arg2=段基址, arg3=段属性
  26. %macro DESC 3                           -->这儿采用了《Orange'S：一个操作系统的实现》中的宏，用宏之后就比较直观
  27.     dw %1 & 0xFFFF ;limit[0-15]
  28.     dw %2 & 0xFFFF ;base[0-15]
  29.     db (%2>>16)&0xFF ;base[16-23]
  30.     db (%3&0xFF) ;prop[0-7]
  31.     db (((%1>>16)&0xF) | (%3>>4)&0xF0) ;limit[16-19]prop[8-11]
  32.     db (%2>>24) & 0xFF
  33. %endmacro
  34. gdt_base:  DESC 0, 0, 0                    -->第一个描述符为空
  35. gdt_code:  DESC 0xFFFF, 0x0, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_8)             -->代码段描述符
  36. gdt_video: DESC 0xFFFF, 0xB8000, (G_0|DB_1|AVL_0|P_1|DPL_0|S_1|TYPE_2)         -->显示段描述符

  38. gdt_ptr:
  39.     dw 24                ;gdt_limit: 8*3=24, 只预留了3个gdt描述符的段界限
  40.     dd gdt_base          ;gdt_base gdt的基地址就是gdt_base这个标签的地址

  42. select_code equ (0x01<<3)|TI_0|RPL_0
  43. select_video equ (0x02<<3)|TI_0|RPL_0

  45. begin:
  46.     ;----------------- 打开A20 ----------------
  47.     in al,0x92
  48.     or al,0000_0010B
  49.     out 0x92,al

  51.     ;----------------- 加载GDT ----------------
  52.     lgdt [gdt_ptr]

  54.     ;----------------- cr0第0位置1 ----------------
  55.     mov eax, cr0
  56.     or eax, 0x00000001
  57.     mov cr0, eax

  59.     ;----------------- 跳到保护模式 ----------------
  60.     jmp select_code:protect_mode
  61. [bits 32]
  62. protect_mode:
  63.     mov ax,select_video
  64.     mov gs,ax
  65.     mov byte [gs:160], 'P'
  66.     mov byte [gs:161], 0xA4
  67.     jmp $


阅读(1893) | 评论(0) | 转发(0) |
0

上一篇：写操作系统----2.从mbr进入loader

下一篇：写操作系统----4.开启分页

给主人留下些什么吧！~~
关于我们 | 关于IT168 | 联系方式 | 广告合作 | 法律声明 | 免费注册

Copyright 2001-2010 ChinaUnix.net All Rights Reserved 北京皓辰网域网络信息技术有限公司. 版权所有

感谢所有关心和支持过ChinaUnix的朋友们

16024965号-6