SAP 内表的ALV输出

本题题目参照：SAP 内表数据查询

*&---------------------------------------------------------------------*
*& Report  ZY20130903_ITAB
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  ZY20130903_ITAB.
"TYPE-POOLS slis.                   "ALV类型池
TABLES: vbak,marc.
TYPES: BEGIN OF ty_mara,
         matnr TYPE mara-matnr, "物料编号
         meins TYPE mara-meins,    "单位
       END OF ty_mara,
       BEGIN OF ty_makt,
         matnr TYPE makt-matnr, "物料编号
         maktx TYPE makt-maktx,    "物料描述
       END OF ty_makt,
       BEGIN OF ty_vbap,
         matnr TYPE vbap-matnr, "物料编号
         kwmeng TYPE vbap-kwmeng,  "销售数量
         meins TYPE vbap-meins, "单位
       END OF ty_vbap,
       BEGIN OF ty_mard,
         werks TYPE mard-werks,    "工厂
         matnr TYPE mard-matnr, "物料编号
         labst TYPE mard-labst,    "非限制使用库存
       END OF ty_mard,
       BEGIN OF ty_out,
         werks TYPE mard-werks, "工厂
         matnr   TYPE mard-matnr,  "物料编号
         maktx TYPE makt-maktx, "物料描述
         kwmeng  TYPE vbap-kwmeng, "销售数量
         meins_m TYPE mara-meins, "单位
         labst   TYPE mard-labst,  "非限制使用库存
         meins_v TYPE vbap-meins, "单位
       END OF ty_out.
"定义相应的工作区
DATA : wa_mara TYPE ty_mara,
        wa_makt TYPE ty_makt,
        wa_vbap TYPE ty_vbap,
        wa_mard TYPE ty_mard,
        wa_out TYPE ty_out,
"定义相应的内表
        it_mara TYPE STANDARD TABLE OF ty_mara,
        it_makt TYPE STANDARD TABLE OF ty_makt,
        it_vbap TYPE STANDARD TABLE OF ty_vbap,
        it_mard TYPE STANDARD TABLE OF ty_mard,
        it_out  TYPE STANDARD TABLE OF ty_out.
"定义alv相关
DATA: it_field TYPE slis_t_fieldcat_alv,
      wa_field TYPE slis_fieldcat_alv,
      wa_layout TYPE slis_layout_alv,
      it_sort TYPE slis_t_sortinfo_alv,
      wa_sort TYPE slis_sortinfo_alv.
*选择屏幕
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
SELECT-OPTIONS: s_erdat FOR vbak-erdat,
                s_matnr FOR wa_mara-matnr,
                s_werks FOR marc-werks NO INTERVALS NO-EXTENSION OBLIGATORY.
SELECTION-SCREEN END OF BLOCK b1.
*INITIALIZATION.
INITIALIZATION.
  PERFORM init_screen. "初始化
*AT SELECTION-SCREEN.
AT SELECTION-SCREEN.
  PERFORM check_werks.    "检查工厂有效性
*START-OF-SELECTION.
START-OF-SELECTION.
  PERFORM get_meins. "获得单位
  PERFORM get_maktx.       "获得物料描述
  PERFORM get_kwmeng. "获得销量
  PERFORM get_labst.       "获得库存
  PERFORM edit_data. "编辑数据


PERFORM edit_fieldcat USING: 'WERKS'  '工厂'     ''  '1' '',
                             'MATNR'  '物料编号' ''  '2' '',
                             'MAKTX'  '物料描述' ''  '3' '',
                             'KWMENG' '销售数量' ''  '4' '',
                             'MEINS_M'  '销售单位' ''  '5' '',
                             'LABST'  '库存数量' ''  '6' 'X',
                             'MEINS_V'  '基本单位' ''  '7' ''.
PERFORM output_alv.      "alv方式展示数据
**& Form  INIT_SCREEN     INIT_SCREEN  ：
FORM init_screen .
  s_werks-sign = 'I'.
  s_werks-option = 'EQ'.
  s_werks-low = '1000'.
  APPEND s_werks.
  s_erdat-sign = 'I'.
  s_erdat-option = 'BT'.
  s_erdat-low = '20110201'.
  s_erdat-high = '20110228'.
  APPEND s_erdat.
  s_matnr-sign = 'I'.
  s_matnr-option = 'EQ'.
  s_matnr-low = 'P-102'.
  s_matnr-high = 'p-104'.
  APPEND s_matnr.
ENDFORM. " INIT_SCREEN
*&      Form  CHECK_WERKS
FORM check_werks .
  DATA: l_werks TYPE werks_d.
  SELECT SINGLE werks
    FROM t001w    "工厂检查表
      INTO l_werks
    WHERE werks IN s_werks.
  IF sy-subrc <> 0.
    MESSAGE 'The plant is not exist' TYPE 'E'.
  ENDIF.
ENDFORM. " CHECK_WERKS
*&      Form  GET_MEINS
FORM get_meins .
  SELECT matnr       "物料号
         meins "单位
    FROM mara
    INTO CORRESPONDING FIELDS OF TABLE it_mara
    WHERE matnr IN s_matnr.
* 排序
  SORT it_mara BY matnr ASCENDING.
ENDFORM.                    " GET_MEINS
* GET_MAKTX
FORM get_maktx .
  CHECK it_mara IS NOT INITIAL. "检查内表是否为空
  SELECT makt~matnr
         spras
         maktx
    FROM makt
      INTO CORRESPONDING FIELDS OF TABLE it_makt
        FOR ALL ENTRIES IN it_mara
    WHERE matnr = it_mara-matnr
      AND spras = 'EN'.
* 排序
  SORT it_makt BY matnr ASCENDING.
ENDFORM.                    " GET_MAKTX
*& Form  GET_KWMENG
FORM get_kwmeng .
  SELECT vbap~matnr
         vbap~kwmeng "销量
         vbap~meins      "
    INTO CORRESPONDING FIELDS OF TABLE it_vbap
       FROM vbap
         INNER JOIN vbak ON vbak~vbeln = vbap~vbeln
    WHERE vbak~auart = 'TA' "类型
      AND vbak~erdat IN s_erdat.  "日期
* 排序
  SORT it_vbap BY matnr ASCENDING.
ENDFORM. " GET_KWMENG
*&      Form  GET_LABST
FORM get_labst .
  CHECK it_vbap IS NOT INITIAL.     "检查内表是否为空
  SELECT werks "工厂
         matnr     "物料编号
         labst "非限制使用库存
    FROM mard
      INTO CORRESPONDING FIELDS OF TABLE it_mard
     WHERE werks IN s_werks  "工厂
    AND matnr IN s_matnr.
* 排序
  SORT it_mard BY matnr ASCENDING.
ENDFORM. " GET_LABST
*&      Form  EDIT_DATA
FORM edit_data .
  CHECK it_mard IS NOT INITIAL.     "检查内表是否为空
  LOOP AT it_mard INTO wa_mard. "循环内表
    wa_out-werks = wa_mard-werks.
    wa_out-matnr = wa_mard-matnr.
    wa_out-labst = wa_mard-labst.
    READ TABLE it_mara INTO wa_mara WITH KEY matnr = wa_mard-matnr BINARY SEARCH.
    IF sy-subrc = 0.
      wa_out-meins_m = wa_mara-meins.
    ENDIF.
    READ TABLE it_makt INTO wa_makt WITH KEY matnr = wa_mard-matnr BINARY SEARCH.
    IF sy-subrc = 0.
      wa_out-maktx = wa_makt-maktx.
    ENDIF.
    LOOP AT it_vbap INTO wa_vbap WHERE matnr = wa_mard-matnr.
      AT END OF matnr.
        SUM.         "求合
        wa_out-kwmeng = wa_vbap-kwmeng.
      ENDAT.
      wa_out-meins_v = wa_vbap-meins.
    ENDLOOP.
    APPEND wa_out TO it_out. "添加到内表
     write: / wa_out-werks,
          wa_out-matnr,
          wa_out-maktx,
          wa_out-kwmeng,
          wa_out-meins_m,
          wa_out-labst,
          wa_out-meins_v.

  ENDLOOP.
ENDFORM.                    " EDIT_DATA
*& Form  EDIT_FIELDCAT

FORM edit_fieldcat USING    $i_filedname
                            $i_seltext
                            $i_key
                            $i_col
                            $i_sum.
  CLEAR wa_field.
  wa_field-fieldname = $i_filedname.
  wa_field-seltext_l = $i_seltext. "长文本
  wa_field-key       = $i_key.
  wa_field-col_pos   = $i_col.        "列的位置
  wa_field-do_sum = $i_sum. "求和
  APPEND wa_field TO it_field.
ENDFORM.                    " EDIT_FIELDCAT

"&      Form  OUTPUT_ALV
FORM output_alv .
  DATA: w_repid TYPE sy-repid.
  wa_layout-zebra               = 'X'. "使ALV界面呈现颜色交替
  wa_layout-colwidth_optimize = 'X'. "自动优化列宽
  wa_sort-spos        = 1.        "排序顺序
  wa_sort-fieldname = 'WERKS'. "排序字段
  wa_sort-up          = 'X'.      "升序
  wa_sort-subtot = 'X'. "小计
  APPEND wa_sort TO it_sort.
  CLEAR wa_sort .
  wa_sort-spos        = 2.        "排序顺序
  wa_sort-fieldname = 'MATNR'. "排序字段
  wa_sort-up          = 'X'.      "升序
  wa_sort-subtot = 'X'. "小计
  APPEND wa_sort TO it_sort.
  CLEAR wa_sort .
  w_repid = sy-repid. "当前程序的名称
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      i_grid_title = 'ALV TITLE'
      is_layout = wa_layout
      it_fieldcat = it_field
      it_sort = it_sort
    TABLES
      t_outtab = it_out
    EXCEPTIONS
      program_error = 1
      OTHERS = 2.
ENDFORM.