arm-linux（kernel-2.6.13）的启动过程（1/2）

arm-linux（kernel-2.6.13）的启动过程（1/2）

因为总是看别人的移植笔录很不爽。所以自己分析下启动过程。

要解决的问题：
1。汇编部分__create_page_tables创建的也表是什么样的？
2。 __mmap_switched都作了什么？


前面的文章简单的分析了下这个函数，但我并不是很清晰。这次做个了当。

.type    __create_page_tables, %function
__create_page_tables:
    ldr    r5, [r8, #MACHINFO_PHYSRAM]    @取machine_desc结构phys_ram成员，r5 = 0x30000000
    pgtbl    r4, r5                @ page table address r4=0x30004000

我的不是XIP，所以如下定义
    .globl    swapper_pg_dir
    .equ    swapper_pg_dir, TEXTADDR - 0x4000 这里的swapper_pg_dir：0xc0004000
    .macro    pgtbl, rd, phys
    adr    \rd, stext
    sub    \rd, \rd, #0x4000
    .endm
虽然    
    . = TEXTADDR;
    .init : {            /* Init code and data        */
        _stext = .;
。。。
c0008000 :
但是这个宏跟这个地址无关，他取得stext符号位置的实际运行地址（0x30008000），然后返回rd=0x30008000-0x4000
也就是返回0x30004000。
这里的r4就是页表的基地址了，以后要把它载入到cp15的寄存器 c2（ttb base 寄存器），才能访问到页表。


  /*
     * Clear the 16K level 1 swapper page table
     */
    mov    r0, r4
    mov    r3, #0
    add    r6, r0, #0x4000
1:    str    r3, [r0], #4
    str    r3, [r0], #4
    str    r3, [r0], #4
    str    r3, [r0], #4
    teq    r0, r6
    bne    1b

注：0x4000＝16k，把0x30004000-0x30008000这段区间清零，页表就在这个区间。


    ldr    r7, [r10, #PROCINFO_MMUFLAGS]   
 
把 mmuflags放到r7
看看这个mmuflags是什么内容，涉及到页表的操作，总是很罗嗦。
在proc-arm920.S中，这个标志是这样定义的。

.long   PMD_TYPE_SECT | \
        PMD_SECT_BUFFERABLE | \
        PMD_SECT_CACHEABLE | \
        PMD_BIT4 | \
        PMD_SECT_AP_WRITE | \
        PMD_SECT_AP_READ
在pgtable.h中，有这些宏定义
/*
 * Hardware page table definitions.
 *
 * + Level 1 descriptor (PMD) 这里已经说明了，用的是一级描述符。
 *   - common
 */
#define PMD_TYPE_SECT        (2 << 0) 表示使用段（section），每个描述符描述1M大小的区间。
#define PMD_BIT4        (1 << 4) 没什么意义，只是要求为1
#define PMD_SECT_BUFFERABLE    (1 << 2) 使用写缓冲
#define PMD_SECT_CACHEABLE    (1 << 3) 使用读缓冲
#define PMD_SECT_AP_WRITE    (1 << 10)
#define PMD_SECT_AP_READ    (1 << 11) 这两个联合起来，表示可 R/W（在任何模式下）

《嵌入式开发详解》p109 中有具体的描述

    /*
     * Create identity mapping for first MB of kernel to
     * cater for the MMU enable.  This identity mapping
     * will be removed by paging_init().  We use our current program
     * counter to determine corresponding section base address.
     */
    mov    r6, pc, lsr #20            @ start of kernel section ，r6 = 30008xxx>>20 = 0x300
    orr    r3, r7, r6, lsl #20        @ flags + kernel base，r3= r7&0x30000000
    str    r3, [r4, r6, lsl #2]        @ identity mapping [0x30004000+0x300<<2] = r3

r6取得物理地址的高12bit，这12bit在寻址一级描述符时，作为0x30004000-0x30008000之间的引索，然后取得一级描述符。
在一级描述符中，他还表征了每个1M内存块的起始地址。
r3中是生成的一级描述符，然后将这个一级描述符放到页目录中。
此时的映射为
虚拟地址    0x30000000－0x30100000    (1M)
            |            |
            |            |
物理地址    0x30000000－0x30100000
但是还没有生效。

    /*
     * Now setup the pagetables for our kernel direct
     * mapped region.  We round TEXTADDR down to the
     * nearest megabyte boundary.  It is assumed that
     * the kernel fits within 4 contigous 1MB sections.
     */

    add    r0, r4,  #(TEXTADDR & 0xff000000) >> 18    @ start of kernel
    str    r3, [r0, #(TEXTADDR & 0x00f00000) >> 18]!
    add    r3, r3, #1 << 20
    str    r3, [r0, #4]!            @ KERNEL + 1MB
    add    r3, r3, #1 << 20
    str    r3, [r0, #4]!            @ KERNEL + 2MB
    add    r3, r3, #1 << 20
    str    r3, [r0, #4]            @ KERNEL + 3MB

经过上面的处理后，映射成了这样子。

 虚拟地址        物理地址

0xc0000000（1M）          0x30000000
0xc0100000（1M）          0x30100000
0xc0200000（1M）          0x30200000
0xc0300000（1M）          0x30300000
可以发现，如果我们的内核代码超过了4M的话，访问会出现问题，所以 This identity mapping will be removed by paging_init().
也就是说这个映射是暂时的。
    /*
     * Then map first 1MB of ram in case it contains our boot params.
     */
    add    r0, r4, #VIRT_OFFSET >> 18
    orr    r6, r5, r7
    str    r6, [r0]

    mov    pc, lr
    .ltorg

#define VIRT_OFFSET -1073741824 /* PAGE_OFFSET */（1G）
 虚拟地址        物理地址

0xc0000000（1M）          0x30000000
这里保证了：不管你把虚拟地址改到哪里（0xa0008000）

虚拟地址    0xc0000000－0xc0100000    (1M)
            |            |
            |            |
物理地址    0x30000000－0x30100000
从虚拟地址0xc0000000开始的1M里总能访问到启动参数。这要求我们一定要把启动参数放到ram的头1M里。


struct proc_info_list {
    unsigned int        cpu_val;
    unsigned int        cpu_mask;
    unsigned long        __cpu_mmu_flags;    /* used by head.S */
    unsigned long        __cpu_flush;        /* used by head.S */

...

上面的代码在ram里建立了页表，只是简单前4m。0x30000000 ~ 0x30400000。此时还没有启动mmu。
head.S将按照下面的路径完成启动mmu的任务。

1。调用__cpu_flush ： 对应这b    __arm920_setup这段代码
2。调用__enable_mmu ： 注册了r4,就是页表基址到cp15的c2。
3。__turn_mmu_on ： 到这里mmu已经启动了，代码运行在虚拟地址了
4。__mmap_switched：
5。start_kernel：




2。 __mmap_switched都作了什么？


/*
 * The following fragment of code is executed with the MMU on, and uses
 * absolute addresses; this is not position independent.
 *
 *  r0  = cp#15 control register
 *  r1  = machine ID
 *  r9  = processor ID
 */
    .type    __mmap_switched, %function
__mmap_switched:
    adr    r3, __switch_data + 4

    ldmia    r3!, {r4, r5, r6, r7}
    cmp    r4, r5                @ Copy data segment if needed
1:    cmpne    r5, r6
    ldrne    fp, [r4], #4
    strne    fp, [r5], #4
    bne    1b

    mov    fp, #0                @ Clear BSS (and zero fp)
1:    cmp    r6, r7
    strcc    fp, [r6],#4
    bcc    1b

    ldmia    r3, {r4, r5, r6, sp}
    str    r9, [r4]            @ Save processor ID
    str    r1, [r5]            @ Save machine type
    bic    r4, r0, #CR_A            @ Clear 'A' bit
    stmia    r6, {r0, r4}            @ Save control register values
    b    start_kernel

    .type    __switch_data, %object
__switch_data:
    .long    __mmap_switched
    .long    __data_loc            @ r4
    .long    __data_start            @ r5
    .long    __bss_start            @ r6
    .long    _end                @ r7
    .long    processor_id            @ r4
    .long    __machine_arch_type        @ r5
    .long    cr_alignment            @ r6
    .long    init_thread_union + THREAD_START_SP @ sp
他根据需要，拷贝data段，清零bss段，保存r0  = cp#15 control register，r1  = machine ID，r9  = processor ID
到变量中(在setup.c中)
unsigned int processor_id;
unsigned int __machine_arch_type;