由图像的灰度化看基本图像处理[转载]

[基础篇]

首先看一段实现24位色图像转换的代码

procedure Grayscale(const Bitmap:TBitmap);
var
  X: Integer;
  Y: Integer;
  R,G,B,Gray: Byte;
  Color: TColor;
begin
  for Y := 0 to (Bitmap.Height - 1) do
  begin
    for X := 0 to (Bitmap.Width - 1) do
    begin
      Color := Bitmap.Canvas.Pixels[X,Y];
      R := Color and $FF;
      G := (Color and $FF00) shr 8;
      B := (Color and $FF0000) shr 16;
      Gray := Trunc(0.3 * R + 0.59 * G + 0.11 * B);
      Bitmap.Canvas.Pixels[X,Y] := Gray shl 16 or Gray shl 8 or Gray;
    end
  end
end;

{这段代码效率是非常低的，但可以方便我们理解同时一些问题}

Delphi的帮助中对TColor已经有了详细的描述，这可以方便我们理解上面的代码！

　　首先看：

　　R := Color and $FF;
　　G := (Color and $FF00) shr 8;
　　B := (Color and $FF0000) shr 16;

　　这是段常见的从TColor中提取三原色的代码，但它是什么意思呢？
首先应该 知道and是与(.)运算，0.1=0，0.0=0，1.1=1，以取绿色为例：$FF00实际上就是$00FF00,它与一个TColor类型数按位进 行与运算后，表示红色和绿色的位都变为了$00,而表示绿色的部分不变(0，1和1进行与运算值都不变)，再右移8位，自然就获得了绿色值的8位表示！

　　再获得三原色的值后，就是计算灰度值，0.3 * Red + 0.59 * Green + 0.11 * Blue 这是求加权平均值的公式。(因为人眼对颜色的敏感度不同，所以权值不同，就像在pf16bit中用了6位表示绿色，其它两种颜色只用了5位，这问题以后另 写文章说明)

　　然后就是像素颜色信息的写回，刚才是右移，现在自然就是左移，而或(+)运算就是(0 +1=1，0+0=0，1+1=1),举个简单例子就是：($FF shl 16 = $FF0000) or ($FF shl 8 = $FF00) or $FF = $FFFFFF ,其实这里的或运算当然也可以用 + 代替。

　　虽然上面的代码实现了24位色图像的， 但当图像比较大时，速度非常慢，为什么？查看相关VCL代码可知调用Bitmap.Canvas.Pixels获取，写入像素的颜色信息实际上是利用了 API GetPixel、SetPixel，这种方法是非常低效的！(唯一的好处是在进行一些和颜色无关的操作，如图像的旋转，翻转时不需要因为 PixelFormat的不同而修改代码)所以应该换一种更高效的访问像素点数据的方法，如用API GetDIBits、SetDIBits，但这种方法比较复杂，好在Delphi3以后版本的TBitmap中提供了Scanline。利用 Scanline可以快速对像素进行访问！

还是以24位色(PixelFormats=pf24bit)为例,可改写为：

procedure Grayscale(const Bitmap:TBitmap);
const
  PixelCountMax = 32768;
type
  pRGBTripleArray = ^TRGBTripleArray;
  TRGBTripleArray = ARRAY[0..PixelCountMax-1] OF TRGBTriple;
var
  Row: pRGBTripleArray;
  X: Integer;
  Y: Integer;
  Gray: Byte;
begin
  for Y := 0 to (Bitmap.Height - 1) do
  begin
    Row := Bitmap.ScanLine[Y];
    for X := 0 to (Bitmap.Width - 1) do
    begin
      Gray := Trunc(0.3 * Row^[X].rgbtRed + 0.59 * Row^[X].rgbtGreen + 0.11 * Row^[X].rgbtBlue);
      Row^[X].rgbtRed:=Gray;
      Row^[X].rgbtGreen:=Gray;
      Row^[X].rgbtBlue:=Gray;
    end;
  end;
end;

上面的例子用了一个TRGBTriple数组

  PRGBTriple = ^TRGBTriple;
  tagRGBTRIPLE = packed record
    rgbtBlue: Byte;
    rgbtGreen: Byte;
    rgbtRed: Byte;
  end;
  TRGBTriple = tagRGBTRIPLE;

这种方法会限制位图的大小，但一般不用理会，直接用TBitmap可处理不了那么大的位图

当然也可用指针的移动实现，实测结果这样更快～～～

procedure Grayscale(const Bitmap:TBitmap);
var
  X: Integer;
  Y: Integer;
  PRGB: pRGBTriple;
  Gray: Byte;
begin
  for Y := 0 to (Bitmap.Height - 1) do
  begin
    PRGB := Bitmap.ScanLine[Y];
    for X := 0 to (Bitmap.Width - 1) do
    begin
      Gray := Trunc(0.3 * PRGB^.rgbtRed + 0.59 * PRGB^.rgbtGreen + 0.11 * PRGB^.rgbtBlue);
      PRGB^.rgbtRed:=Gray;
      PRGB^.rgbtGreen:=Gray;
      PRGB^.rgbtBlue:=Gray;
      Inc(PRGB);
    end;
  end;
end;

在上一篇中提到了，那代码只能适用于24位色(PixelFormats=pf24bit)，为什么？看看记录类型tagRGBTRIPLE，正好24位，所以这样只能处理24位色图！

那怎么处理其他的位图呢？

先对这各种类型的位图做些简单的介绍～～～

pf1bit:

　　每个像素只需要用一位表示，如调色板定义的是黑白两种颜色(0为黑，1为白)，这时只能用位操作访问像素信息！如定义

var P:PByte

  for Y := 0 to (Bitmap.Height - 1) do
  begin
    p := Bitmap.ScanLine[Y];
    for X := 0 to (Bitmap.width - 1) DIV 8 + 1 do
    begin
      p^:=1 or 2 or 4 or 8 or 16 or 32 or 64 or 128;
      Inc(PRGB,3);
    end;
  end;

　p^:=1 or 2 or 4 or 8 or 16 or 32 or 64 or 128;
　这行代码什么意思呢？1=1(二进制),2=10(二进制),4=100(二进制),8=1000(二进制)...

　结合上篇中解释了的或运算，很容易理解就以八个字位为单位，给其赋上颜色信息！

pf4bit:

　　和pf1bit位图一样，操作pf4bit位图也需要用位操作。

pf8bit:

　　可直接利用Byte、TByteArray，但用Scanline取的值表示的只是调色板上颜色的索引。

pf15bit和pf16bit:

　　这两种位图都是16位的，pf15bit是第一位为0，后15位的每5位分别表示红、绿、蓝。而pf16bit中绿色占6位，其它两种颜色占用5位(人眼对绿色比较敏感)！

　pf24bit位图转pf15bit位图代码

　var
　　Row24:pRGBTriple;
　　Row15:PWord;

　for j := 0 TO Bitmap.Height-1 DO
　begin
  　Row15 := Bitmap15.Scanline[j];
  　Row24 := Bitmap24.Scanline[j];
  　for i := 0 TO Bitmap.Width-1 DO
  　begin
    　with Row24^ do
      　Row15^ := (rgbtRed Shr 3) Shl 10 or (rgbtGreen Shr 3) Shl 5 or (rgbtBlue Shr 3);
    　Inc(Row24);
    　Inc(Row15);
  　end
　end;

pf24bit和pf32bit:
 
　pf24bit上面的已多次用到，就不多说了。而pf32bit和pf24bit一样，用24位来记录三原色的颜色信息！
　PRGBQuad = ^TRGBQuad;
　tagRGBQUAD = packed record
　　rgbBlue: Byte;
　　rgbGreen: Byte;
　　rgbRed: Byte;
　　rgbReserved: Byte;
　end;
　TRGBQuad = tagRGBQUAD;

　如果要修改上面的程序，就是简单的PRGBQuad替换PRGBTriple，TRGBQuad替换TRGBTriple的过程～

　测试表明在pf32bit中利用Scanline处理图像要比pf24bit快。

　所以除了单色图(PixelFormats=pf1bit)外(没必要),其它都可转外32位色实现。这也是一种比较可行的方法！