读写客户端Windows注册表

REPORT z_barry_test NO STANDARD PAGE .

DATA: value TYPE i ,
      server TYPE string.
DATA matcher TYPE REF TO cl_abap_matcher.

PARAMETERS: p_host(15) TYPE c ,
            p_port(8) TYPE n .

INITIALIZATION.
  CALL METHOD cl_gui_frontend_services=>registry_get_dword_value
    EXPORTING
      root      = cl_gui_frontend_services=>hkey_current_user
      key       = 'Software\Microsoft\Windows\CurrentVersion\Internet Settings'
      value     = 'ProxyEnable'
    IMPORTING
      reg_value = value
    EXCEPTIONS
      OTHERS    = 1.

  CALL METHOD cl_gui_frontend_services=>registry_get_value
    EXPORTING
      root      = cl_gui_frontend_services=>hkey_current_user
      key       = 'Software\Microsoft\Windows\CurrentVersion\Internet Settings'
      value     = 'ProxyServer'
    IMPORTING
      reg_value = server
    EXCEPTIONS
      OTHERS    = 1.

  CALL METHOD cl_gui_cfw=>flush.
  IF NOT server IS INITIAL.
    SPLIT server AT ':' INTO p_host p_port.
  ENDIF.

AT SELECTION-SCREEN.
  IF sy-ucomm = 'ONLI' AND NOT p_host IS INITIAL.
    matcher = cl_abap_matcher=>create( pattern = '\d+\.\d+\.\d+\.\d+'
                                   ignore_case = 'X'
                                   text = p_host ).
    IF matcher->match( ) IS INITIAL.
      MESSAGE 'Wrong IP Addr Format' TYPE 'E'.
    ENDIF.
  ENDIF.

START-OF-SELECTION.
  IF p_host = ''.
    CALL METHOD cl_gui_frontend_services=>registry_set_dword_value
      EXPORTING
        root        = cl_gui_frontend_services=>hkey_current_user
        key         = 'Software\Microsoft\Windows\CurrentVersion\Internet Settings'
        value       = 'ProxyEnable'
        dword_value = 0
      IMPORTING
        rc          = value
      EXCEPTIONS
        OTHERS      = 4.
  ELSE.
    SHIFT p_port LEFT DELETING LEADING '0' .
    CONCATENATE p_host':' p_port INTO server.

    CALL METHOD cl_gui_frontend_services=>registry_set_dword_value
      EXPORTING
        root        = cl_gui_frontend_services=>hkey_current_user
        key         = 'Software\Microsoft\Windows\CurrentVersion\Internet Settings'
        value       = 'ProxyEnable'
        dword_value = 1
      IMPORTING
        rc          = value
      EXCEPTIONS
        OTHERS      = 4.
    CALL METHOD cl_gui_frontend_services=>registry_set_value
      EXPORTING
        root       = cl_gui_frontend_services=>hkey_current_user
        key        = 'Software\Microsoft\Windows\CurrentVersion\Internet Settings'
        value_name = 'ProxyServer'
        value      = server
      IMPORTING
        rc         = value
      EXCEPTIONS
        OTHERS     = 5.
  ENDIF.
  CALL METHOD cl_gui_cfw=>flush.

  MESSAGE s000(oo) WITH 'OK!'.