Delphi的指针操作

浅谈Object Pascal的指针



大家都认为，C语言之所以强大，以及其自由性，很大部分体现在其灵活的指 针运用上。因此，说指针是C语言的灵魂，一点都不为过。同时，这种说法也让很多人产生误解，似乎只有C语言的指针才能算指针。Basic不支持指针，在此 不论。其实，Pascal语言本身也是支持指针的。从最初的Pascal发展至今的Object Pascal，可以说在指针运用上，丝毫不会逊色于C语言的指针。

以下内容分为八个部分，分别是
一、类型指针的定义
二、无类型指针的定义
三、指针的解除引用
四、取地址（指针赋值）
五、指针运算
六、动态内存分配
七、字符数组的运算
八、函数指针


一、类型指针的定义。对于指向特定类型的指针，在C中是这样定义的：
int *ptr;
char *ptr;
与之等价的Object Pascal是如何定义的呢？
var
ptr : ^Integer;
ptr : ^char;
其实也就是符号的差别而已。

二、无类型指针的定义。C中有void *类型，也就是可以指向任何类型数据的指针。Object Pascal为其定义了一个专门的类型：Pointer。于是，
ptr : Pointer;
就与C中的
void *ptr;
等价了。

三、指针的解除引用。要解除指针引用（即取出指针所指区域的值），C 的语法是 (*ptr)，Object Pascal则是 ptr^。

四、取地址（指针赋值）。取某对象的地址并将其赋值给指针变量，C 的语法是
ptr = &Object;
Object Pascal 则是
ptr := @Object;
也只是符号的差别而已。

五、指针运算。在C中，可以对指针进行移动的运算，如：
char a[20];  
char *ptr=a;  
ptr++;
ptr+=2;
当执行ptr++;时，编译器会产生让ptr前进sizeof(char)步长的代码，之后，ptr将指向a[1]。ptr+=2;这句使得ptr前进两 个sizeof(char)大小的步长。同样，我们来看一下Object Pascal中如何实现：
var
  a : array [1..20] of Char;
  ptr : PChar; //PChar 可以看作 ^Char
begin
  ptr := @a;
  Inc(ptr); // 这句等价于 C 的 ptr++;
  Inc(ptr, 2); //这句等价于 C 的 ptr+=2;
end;

六、动态内存分配。C中，使用malloc()库函数分配内存，free()函数释放内存。如这样的代码：
int *ptr, *ptr2;
int i;
ptr = (int*) malloc(sizeof(int) * 20);
ptr2 = ptr;
for (i=0; i<20; i++){
  *ptr = i;
  ptr++;
}
free(ptr2);
Object Pascal中，动态分配内存的函数是GetMem()，与之对应的释放函数为FreeMem()（传统Pascal中获取内存的函数是New()和 Dispose()，但New()只能获得对象的单个实体的内存大小，无法取得连续的存放多个对象的内存块）。因此，与上面那段C的代码等价的 Object Pascal的代码为：
var ptr, ptr2 : ^integer;
  i : integer;
begin
  GetMem(ptr, sizeof(integer) * 20);
    //这句等价于C的 ptr = (int*) malloc(sizeof(int) * 20);
  ptr2 := ptr; //保留原始指针位置
  for i := 0 to 19 do
  begin
    ptr^ := i;
    Inc(ptr);
  end;
  FreeMem(ptr2);
end;
对 于以上这个例子（无论是C版本的，还是Object Pascal版本的），都要注意一个问题，就是分配内存的单位是字节（BYTE），因此在使用GetMem时，其第二个参数如果想当然的写成 20，那么就会出问题了（内存访问越界）。因为GetMem(ptr, 20);实际只分配了20个字节的内存空间，而一个整形的大小是四个字节，那么访问第五个之后的所有元素都是非法的了（对于malloc()的参数同 样）。

七、字符数组的运算。C语言中，是没有字符串类型的，因此，字符串都是用字符数组来实现，于是也有一套str打头的库函数以进行字符数组的运算，如以下代码：
char str[15];
char *pstr;
strcpy(str, "teststr");
strcat(str, "_testok");
pstr = (char*) malloc(sizeof(char) * 15);
strcpy(pstr, str);
printf(pstr);
free(pstr);
而 在Object Pascal中，有了String类型，因此可以很方便的对字符串进行各种运算。但是，有时我们的Pascal代码需要与C的代码交互（比如：用 Object Pascal的代码调用C写的DLL或者用Object Pascal写的DLL准备允许用C写客户端的代码）的话，就不能使用String类型了，而必须使用两种语言通用的字符数组。其实，Object Pascal提供了完全相似C的一整套字符数组的运算函数，以上那段代码的Object Pascal版本是这样的：
var str : array [1..15] of char;
  pstr : PChar; //Pchar 也就是 ^Char
begin
  StrCopy(@str, 'teststr'); //在C中，数组的名称可以直接作为数组首地址指针来用
          //但Pascal不是这样的，因此 str前要加上取地址的运算符
  StrCat(@str, '_testok');
  GetMem(pstr, sizeof(char) * 15);
  StrCopy(pstr, @str);
  Write(pstr);
  FreeMem(pstr);
end;

八、函数指针。在动态调用DLL中的函数时，就会用到函数指针。假设用C写的一段代码如下：
typedef int (*PVFN)(int); //定义函数指针类型
int main()
{
  HMODULE hModule = LoadLibrary("test.dll");
PVFN pvfn = NULL;
  pvfn = (PVFN) GetProcAddress(hModule, "Function1");
  pvfn(2);
  FreeLibrary(hModule);
}
就我个人感觉来说，C语言中定义函数指针类型的typedef代码的语法有些晦涩，而同样的代码在Object Pascal中却非常易懂：
type PVFN = Function (para : Integer) : Integer;
var
  fn : PVFN;
    //也可以直接在此处定义，如：fn : function (para:Integer):Integer;
  hm : HMODULE;
begin
  hm := LoadLibrary('test.dll');
  fn := GetProcAddress(hm, 'Function1');
  fn(2);
  FreeLibrary(hm);
end;

补充（蓝蓝） 其他指针（类似的指针）

接口是什么  接口就是指针

事件是什么 事件也是指针，
我们可以这样申明
type
  OnMouseOn=procedure of object;//使用object关键字定义一个 过程或者函数的指针，让他来关联事件
  TClass1=class
    public
      OnMouse:procedure of object;
    end;
   如果写成
    class.onmouse:=form1.onmousedown//这里进行了过程指针指向了。form1的一个具体事件的

 

 2006-7-10 10:09:17    指针详细。

指针的表达方法
   
   Const
      const PI: ^Integer = @I;


    ^integer=@I=Pointer=@MyProc
     都是指针
    而
      Data^是指针的具体内容。

请举例如何定义指针常量和常量指针
 
 

参数传递中的指针常量就不必说了吧——和非指针的常量一样的。

  这是一个标准的Const Pointer的例子：

var
  A:Integer=100;
const
  PA:PInteger=@A;
procedure TForm1.Button1Click(Sender: TObject);
begin
  Caption:=IntToHex(Integer(PA),8);
end;

  下面是一个用函数来模拟无法预先决定值的常量指针的例子：

Unit A;
interface
function PointerA:Pointer;
implementation
var
  ObjA:TXXX; //ObjA运行后才能被动态的创建
function PointerA:Pointer;
begin
  Result:=@ObjA;
end;
...

  这样，在UnitA之外的地方，PointerA地返回值就是常量了