MPC8349E-mITX的U-Boot连接脚本u-boot.lds分析

  1 // MPC8349E-mITX ltib U-Boot board/mpc8349itx/u-boot.lds     --- by starby
  2 /*
  3  * Copyright (C) Freescale Semiconductor, Inc. 2006. All rights reserved.
  4  *
  5  * See file CREDITS for list of people who contributed to this
  6  * project.
  7  *
  8  * This program is free software; you can redistribute it and/or
  9  * modify it under the terms of the GNU General Public License as
 10  * published by the Free Software Foundation; either version 2 of
 11  * the License, or (at your option) any later version.
 12  *
 13  * This program is distributed in the hope that it will be useful,
 14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
 15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 16  * GNU General Public License for more details.
 17  *
 18  * You should have received a copy of the GNU General Public License
 19  * along with this program; if not, write to the Free Software
 20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 21  * MA 02111-1307 USA
 22  */
 23
 24 OUTPUT_ARCH(powerpc)        /* ## 指定输出的可执行文件的平台为powerpc */
 25 SECTIONS                    /* 各个段的指定 */
 26 {
 27   /* Read-only sections, merged into text segment: */
 28   . = + SIZEOF_HEADERS;         /* ## 地址加SIZEOF_HEADERS(0x94)  "."表示当前地址 */
 29   .interp : { *(.interp) }      /* 定义 .interp段 : 由所有代码的.interp段共同组成. */
 30   .hash          : { *(.hash)       }   /* .hash段: 由所有代码的.hash段共同组成. */
 31   .dynsym        : { *(.dynsym)     }
 32   .dynstr        : { *(.dynstr)     }
 33   .rel.text      : { *(.rel.text)       }
 34   .rela.text     : { *(.rela.text)  }
 35   .rel.data      : { *(.rel.data)       }
 36   .rela.data     : { *(.rela.data)  }
 37   .rel.rodata    : { *(.rel.rodata)     }
 38   .rela.rodata   : { *(.rela.rodata)    }
 39   .rel.got       : { *(.rel.got)        }
 40   .rela.got      : { *(.rela.got)       }
 41   .rel.ctors     : { *(.rel.ctors)  }
 42   .rela.ctors    : { *(.rela.ctors) }
 43   .rel.dtors     : { *(.rel.dtors)  }
 44   .rela.dtors    : { *(.rela.dtors) }
 45   .rel.bss       : { *(.rel.bss)        }
 46   .rela.bss      : { *(.rela.bss)       }
 47   .rel.plt       : { *(.rel.plt)        }
 48   .rela.plt      : { *(.rela.plt)       }
 49   .init          : { *(.init)   }
 50   .plt : { *(.plt) }
 51   .text      :          /* ## 文本段 */
 52   {
 53     cpu/mpc83xx/start.o (.text)         /* ## 文本段的第一部分start.S，后跟其他做文本段 */
 54     *(.text)
 55     *(.fixup)
 56     *(.got1)
 57     . = ALIGN(16);          /* ## 16字节对齐 */
 58     *(.rodata)
 59     *(.rodata1)
 60     *(.rodata.str1.4)
 61   }
 62   .fini      : { *(.fini)    } =0
 63   .ctors     : { *(.ctors)   }
 64   .dtors     : { *(.dtors)   }
 65
 66   /* Read-write section, merged into data segment: */
 67   . = (. + 0x0FFF) & 0xFFFFF000;    /* 地址对齐(地址低12位为0) */
 68   _erotext = .;
 69   PROVIDE (erotext = .);
 70   .reloc   :        /* .reloc段由以下组成 */
 71   {
 72     *(.got)             /* got段 */
 73     _GOT2_TABLE_ = .;   /* _GOT2_TABLE_值为当前地址: .got段结束地址；.got2段起始地址 */
 74     *(.got2)            /* got2段 */
 75     _FIXUP_TABLE_ = .;  /* _FIXUP_TABLE_值: .got2段结束地址；.fixup段起始地址 */
 76     *(.fixup)
 77   }
 78   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2; /* __got2_entries符号定义，其值为GOT表项个数，每个表项占4字节 */
 79   __fixup_entries = (. - _FIXUP_TABLE_) >> 2; /* __fixup_entries值为.fixup的字个数 */
 80
 81   .data    :        /* ## 数据段 */
 82   {
 83     *(.data)
 84     *(.data1)
 85     *(.sdata)
 86     *(.sdata2)
 87     *(.dynamic)
 88     CONSTRUCTORS
 89   }
 90   _edata  =  .;
 91   PROVIDE (edata = .);
 92
 93   . = .;
 94   __u_boot_cmd_start = .;       /* 定义u-boot命令起始地址，board_init_r中有调用 */
 95   .u_boot_cmd : { *(.u_boot_cmd) }  /* u_boot_cmd段 */
 96   __u_boot_cmd_end = .;         /* 同上 __u_boot_cmd_end 符号定义 */
 97
 98   . = .;
 99   __start___ex_table = .;
100   __ex_table : { *(__ex_table) }
101   __stop___ex_table = .;
102
103   . = ALIGN(4096);      /* 4096字节对齐 */
104   __init_begin = .;
105   .text.init : { *(.text.init) }
106   .data.init : { *(.data.init) }
107   . = ALIGN(4096);
108   __init_end = .;   /* start.S中relocate_code计算u-boot镜像text长度，利用了__init_end，后面不再搬运，直接清零clear_bss */
109
110   __bss_start = .;  /* bss代码段起始地址 */
111   .bss       :
112   {
113    *(.sbss) *(.scommon)
114    *(.dynbss)
115    *(.bss)
116    *(COMMON)
117   }
118   _end = . ;    /* _end 符号定义 bss代码段结束地址，u-boot镜像结束地址 */
119   PROVIDE (end = .);
120 }   /* SECTIONS 对各段定义完毕 */
121 ENTRY(_start)       /* ## 指定可执行文件的入口点为符号_start;  u-boot在链接时带 -Ttext $(TEXT_BASE) 参数，指定了lds文件中ENTRY(_start)所在的地址为TEXT_BASE*/
122
123     
124 /*
125        在 board/mpc8349itx/下的config.mk包含
126 #
127 # MPC8349ITX
128 #
129
130 TEXT_BASE  =   0xFEF00000       ## 这个地址是U-Boot在RAM中的程序入口地址，U-Boot启动以后，在RAM中就运行在这个地址往上的空间。这个地址是U-Boot的指令最开始的地址（对很多PowerPC，比如MPC8349ITX，一般再一个100字节的偏移）。在Flash中启动的话，这个地址就在Flash中。
131 */