Chinaunix首页 | 论坛 | 博客
  • 博客访问: 7499
  • 博文数量: 3
  • 博客积分: 0
  • 博客等级: 民兵
  • 技术积分: 10
  • 用 户 组: 普通用户
  • 注册时间: 2015-01-30 21:18
个人简介

热爱技术

文章分类
文章存档

2015年(3)

我的朋友
最近访客

分类: LINUX

2015-06-03 15:24:23

    在完成了zImage自解压之后,就跳转到了解压后的内核(也就是vmlinux的bin版本Image),具体的入口可以在arch/arm/kernel/vmlinux.lds.S(最终的链接脚本是通过这个文件产生的)中获得:

  1. ......
  2. SECTIONS
  3. {
  4. #ifdef CONFIG_XIP_KERNEL
  5. . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  6. #else
  7. . = PAGE_OFFSET + TEXT_OFFSET;
  8. #endif
  9. .init : { /* Init code and data */
  10. _stext = .;
  11. _sinittext = .;
  12. ......

    这个入口在arch/arm/kernel/head.S中,这个文件就是Linux内核真正启动的地方,是初始化部分的开始,用汇编写成。他必须为后面的C代码做好准备,下面先给出程序的流程图,后面是中文注释的代码。

    这里有一些宏定义必须知道他的含义:

出现的位置

默认值

定义

KERNEL_RAM_ADDR

arch/arm/kernel/head.S

0xC0008000

内核内存中的虚拟地址

PAGE_OFFSET

arch/arm/include/asm/memory.h 

0xC0000000

内核虚拟地址空间的起始地址

TEXT_OFFSET

arch/arm/Makefile

0x00008000

内核起始位置相对于内存起始位置的偏移

PHYS_OFFSET

arch/arm/include/asm/memory.h 

构架相关

物理内存的起始地址


arch/arm/kernel/head.S

  1. /*
  2.  * linux/arch/arm/kernel/head.S
  3.  *
  4.  * Copyright (C) 1994-2002 Russell King
  5.  * Copyright (c) 2003 ARM Limited
  6.  * All Rights Reserved
  7.  *
  8.  * This program is free software; you can redistribute it and/or modify
  9.  * it under the terms of the GNU General Public License version 2 as
  10.  * published by the Free Software Foundation.
  11.  *
  12.  * 所有32-bit CPU的内核启动代码
  13.  */
  14. #include <linux/linkage.h>
  15. #include <linux/init.h>

  16. #include <asm/assembler.h>
  17. #include <asm/domain.h>
  18. #include <asm/ptrace.h>
  19. #include <asm/asm-offsets.h>
  20. #include <asm/memory.h>
  21. #include <asm/thread_info.h>
  22. #include <asm/system.h>

  23. #ifdef CONFIG_DEBUG_LL
  24. #include <mach/debug-macro.S>
  25. #endif

  26. /*
  27.  * swapper_pg_dir 是初始页表的虚拟地址.
  28.  * 我们将页表放在KERNEL_RAM_VADDR以下16K的空间中. 因此我们必须保证
  29.  * KERNEL_RAM_VADDR已经被正常设置. 当前, 我们期望的是
  30.  * 这个地址的最后16 bits为0x8000, 但我们或许可以放宽这项限制到
  31.  * KERNEL_RAM_VADDR >= PAGE_OFFSET + 0x4000.
  32.  */
  33. #define KERNEL_RAM_VADDR    (PAGE_OFFSET + TEXT_OFFSET)
  34. #if (KERNEL_RAM_VADDR & 0xffff) != 0x8000
  35. #error KERNEL_RAM_VADDR must start at 0xXXXX8000
  36. #endif

  37.     .globl    swapper_pg_dir
  38.     .equ    swapper_pg_dir, KERNEL_RAM_VADDR - 0x4000

  39. /*
  40.  * TEXT_OFFSET 是内核代码(解压后)相对于RAM起始的偏移.
  41.  *#TEXT_OFFSET - 0x4000就是页表相对于RAM起始的偏移.
  42.  * 这个宏的作用是将phys(RAM的启示地址)加上页表的偏移,
  43.  * 而得到页表的起始物理地址
  44.  */
  45.     .macro    pgtbl, rd, phys
  46.     add    \rd, \phys, #TEXT_OFFSET - 0x4000
  47.     .endm

  48. #ifdef CONFIG_XIP_KERNEL
  49. #define KERNEL_START    XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
  50. #define KERNEL_END    _edata_loc
  51. #else
  52. #define KERNEL_START    KERNEL_RAM_VADDR
  53. #define KERNEL_END    _end
  54. #endif

  55. /*
  56.  * 内核启动入口点.
  57.  * ---------------------------
  58.  *
  59.  * 这个入口正常情况下是在解压完成后被调用的.
  60.  * 调用条件: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
  61.  * r1 = machine nr, r2 = atags or dtb pointer.
  62.  * 这些条件在解压完成后会被逐一满足,然后才跳转过来。
  63.  *
  64.  * 这些代码大多数是位置无关的, 如果你的内核入口地址在连接时确定为
  65.  * 0xc0008000, 你调用此函数的物理地址就是 __pa(0xc0008000).
  66.  *
  67.  * 完整的machineID列表,请参见 linux/arch/arm/tools/mach-types
  68.  *
  69.  * 我们尽量让代码简洁; 不在此处添加任何设备特定的代码
  70.  * - 这些特定的初始化代码是boot loader的工作(或在极端情况下,
  71.  * 有充分理由的情况下, 可以由zImage完成)
  72.  */
  73.     __HEAD
  74. ENTRY(stext)
  75.     setmode    PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ CPU模式设置宏
  76.                                                     @ (进入svc模式并且关闭中断)
  77.     mrc    p15, 0, r9, c0, c0                       @ 获取处理器id-->r9
  78.     bl    __lookup_processor_type                   @ 返回r5=procinfo r9=cpuid
  79.     movs    r10, r5                                 @ r10=r5,并可以检测r5=0?注意当前r10的值
  80.  THUMB( it    eq )            @ force fixup-able long branch encoding
  81.     beq    __error_p            @ yes, error 'p'如果r5=0,则内核处理器不匹配,出错~死循环

  82.     /*
  83.      * 获取RAM的起始物理地址,并保存于 r8 = phys_offset
  84.      * XIP内核与普通在RAM中运行的内核不同
  85.      * (1)CONFIG_XIP_KERNEL
  86.      *         通过运行时计算????
  87.      * (2)正常RAM中运行的内核
  88.      *         通过编译时确定(PLAT_PHYS_OFFSET 一般在arch/arm/mach-xxx/include/mach/memory.h定义)
  89.      *        
  90.      */
  91. #ifndef CONFIG_XIP_KERNEL
  92.     adr    r3, 2f
  93.     ldmia    r3, {r4, r8}
  94.     sub    r4, r3, r4            @ (PHYS_OFFSET - PAGE_OFFSET)
  95.     add    r8, r8, r4            @ PHYS_OFFSET
  96. #else
  97.     ldr    r8, =PLAT_PHYS_OFFSET
  98. #endif

  99.     /*
  100.      * r1 = machine no, r2 = atags or dtb,
  101.      * r8 = phys_offset, r9 = cpuid, r10 = procinfo
  102.      */
  103.     bl    __vet_atags            @ 判断r2(内核启动参数)指针的有效性
  104. #ifdef CONFIG_SMP_ON_UP
  105.     bl    __fixup_smp            @ ???如果运行SMP内核在单处理器系统中启动,做适当调整
  106. #endif
  107. #ifdef CONFIG_ARM_PATCH_PHYS_VIRT
  108.     bl    __fixup_pv_table    @ ????根据内核在内存中的位置修正物理地址与虚拟地址的转换机制
  109. #endif
  110.     bl    __create_page_tables    @ 初始化页表!

  111.     /*
  112.      * 以下使用位置无关的方法调用的是CPU特定代码。
  113.      * 详情请见arch/arm/mm/proc-*.S
  114.      * r10 = xxx_proc_info 结构体的基地址(在上面__lookup_processor_type函数中选中的)
  115.      * 返回时, CPU 已经为 MMU 的启动做好了准备,
  116.      * 且 r0 保存着CPU控制寄存器的值.
  117.      */
  118.     ldr    r13, =__mmap_switched                @ 在MMU启动之后跳入的第一个虚拟地址
  119.     adr    lr, BSYM(1f)                        @ 设置返回的地址(PIC)
  120.     mov    r8, r4                                @ 将swapper_pg_dir的物理地址放入r8,
  121.                                             @ 以备__enable_mmu中将其放入TTBR1
  122.  ARM(    add    pc, r10, #PROCINFO_INITFUNC    )    @ 跳入构架相关的初始化处理器函数(例如A8的是__v7_setup)
  123.  THUMB(    add    r12, r10, #PROCINFO_INITFUNC    )    @主要目的只配置CP15(包括缓存配置)
  124.  THUMB(    mov    pc, r12                )
  125. 1:    b    __enable_mmu                        @ 启动MMU
  126. ENDPROC(stext)
  127.     .ltorg
  128. #ifndef CONFIG_XIP_KERNEL
  129. 2:    .long    .
  130.     .long    PAGE_OFFSET
  131. #endif

  132. /*
  133.  * 创建初始化页表. 我们只创建最基本的页表,
  134.  * 以满足内核运行的需要,
  135.  * 这通常意味着仅映射内核代码本身.
  136.  *
  137.  * r8 = phys_offset, r9 = cpuid, r10 = procinfo
  138.  *
  139.  * 返回:
  140.  * r0, r3, r5-r7 被篡改
  141.  * r4 = 页表物理地址
  142.  */
  143. __create_page_tables:
  144.     pgtbl    r4, r8                @ 现在r4 = 页表的起始物理地址

  145.     /*
  146.      * 清零16K的一级初始页表区
  147.      * 这些页表在内核自解压时被设置过
  148.      * (此时MMU已关闭)
  149.      */
  150.     mov    r0, r4
  151.     mov    r3, #0
  152.     add    r6, r0, #0x4000
  153. 1:    str    r3, [r0], #4
  154.     str    r3, [r0], #4
  155.     str    r3, [r0], #4
  156.     str    r3, [r0], #4
  157.     teq    r0, r6
  158.     bne    1b

  159.     /*
  160.      * 获取节描述符的默认配置(除节基址外的其他配置)
  161.      * 这个数据依构架而不同,数据是用汇编文件配置的:
  162.      * arch/arm/mm/proc-xxx.S
  163.      * (此时MMU已关闭)
  164.      */
  165.     ldr    r7, [r10, #PROCINFO_MM_MMUFLAGS] @ 获取mm_mmuflags(节描述符默认配置),保存于r7

  166.     /*
  167.      * 创建特定映射,以满足__enable_mmu的需求。
  168.      * 此特定映射将被paging_init()删除。
  169.      *
  170.      * 其实这个特定的映射就是仅映射__enable_mmu功能函数区的页表
  171.      * 以保证在启用mmu时代码的正确执行--1:1映射(物理地址=虚拟地址)
  172.      */
  173.     adr    r0, __enable_mmu_loc
  174.     ldmia    r0, {r3, r5, r6}
  175.     sub    r0, r0, r3            @ 获取编译时确定的虚拟地址到当前物理地址的偏移
  176.     add    r5, r5, r0            @ __enable_mmu的当前物理地址
  177.     add    r6, r6, r0            @ __enable_mmu_end的当前物理地址
  178.     mov    r5, r5, lsr #20        @ __enable_mmu的节基址
  179.     mov    r6, r6, lsr #20        @ __enable_mmu_end的节基址

  180. 1:    orr    r3, r7, r5, lsl #20        @ 生成节描述符:flags + 节基址
  181.     str    r3, [r4, r5, lsl #2]    @ 设置节描述符,1:1映射(物理地址=虚拟地址)
  182.     teq    r5, r6                    @ 完成映射?(理论上一次就够了,这个函数应该不会大于1M吧~)
  183.     addne    r5, r5, #1            @ r5 = 下一节的基址
  184.     bne    1b

  185.     /*
  186.      * 现在创建内核的逻辑映射区页表(节映射)
  187.      * 创建范围:KERNEL_START---KERNEL_END
  188.      * KERNEL_START:内核最终运行的虚拟地址
  189.      * KERNEL_END:内核代码结束的虚拟地址(bss段之后,但XIP不是)
  190.      */
  191.     mov    r3, pc                @ 获取当前物理地址
  192.     mov    r3, r3, lsr #20        @ r3 = 当前物理地址的节基址
  193.     orr    r3, r7, r3, lsl #20    @ r3 为当前物理地址的节描述符
  194.     /*
  195.      * 下面是为了确定页表项的入口地址
  196.      * 其实页表入口项的偏移就反应了对应的虚拟地址的高位
  197.      *
  198.      * 由于ARM指令集的8bit位图问题,只能分两次得到
  199.      * KERNEL_START:内核最终运行的虚拟地址
  200.      *
  201.      */
  202.     add    r0, r4, #(KERNEL_START & 0xff000000) >> 18
  203.     str    r3, [r0, #(KERNEL_START & 0x00f00000) >> 18]!
  204.     ldr    r6, =(KERNEL_END - 1)
  205.     add    r0, r0, #4
  206.     add    r6, r4, r6, lsr #18    @ r6 = 内核逻辑映射结束的节基址
  207. 1:    cmp    r0, r6
  208.     add    r3, r3, #1 << 20    @ 生成节描述符(只需做基址递增)
  209.     strls    r3, [r0], #4    @ 设置节描述符
  210.     bls    1b

  211. #ifdef CONFIG_XIP_KERNEL
  212.     /*
  213.      * 如果是XIP技术的内核,上面的映射只能映射内核代码和只读数据部分
  214.      * 这里我们再映射一些RAM来作为 .data and .bss 空间.
  215.      */
  216.     add    r3, r8, #TEXT_OFFSET
  217.     orr    r3, r3, r7            @ 生成节描述符:flags + 节基址
  218.     add    r0, r4, #(KERNEL_RAM_VADDR & 0xff000000) >> 18
  219.     str    r3, [r0, #(KERNEL_RAM_VADDR & 0x00f00000) >> 18]!
  220.     ldr    r6, =(_end - 1)
  221.     add    r0, r0, #4
  222.     add    r6, r4, r6, lsr #18
  223. 1:    cmp    r0, r6
  224.     add    r3, r3, #1 << 20
  225.     strls    r3, [r0], #4
  226.     bls    1b
  227. #endif

  228.     /*
  229.      * 然后映射启动参数区(现在r2中的atags物理地址)
  230.      * 或者
  231.      * 如果启动参数区的虚拟地址没有确定(或者无效),则会映射RAM的头1MB.
  232.      */
  233.     mov    r0, r2, lsr #20
  234.     movs    r0, r0, lsl #20
  235.     moveq    r0, r8                @ 如果atags指针无效,则r0 = r8(映射RAM的头1MB)
  236.     sub    r3, r0, r8
  237.     add    r3, r3, #PAGE_OFFSET    @ 转换为虚拟地址
  238.     add    r3, r4, r3, lsr #18        @ 确定页表项(节描述符)入口地址
  239.     orr    r6, r7, r0                @ 生成节描述符
  240.     str    r6, [r3]                @ 设置节描述符

  241.     /*
  242.      * 下面是调试信息的输出函数区
  243.      * 这里做了IO内存空间的节映射
  244.      */
  245. #ifdef CONFIG_DEBUG_LL
  246. #ifndef CONFIG_DEBUG_ICEDCC
  247.     /*
  248.      * 为串口调试映射IO内存空间(将串口IO内存之上的所有地址都映射了)
  249.      * 这允许调试信息(在paging_init之前)从串口控制台输出
  250.      *
  251.      */
  252.     addruart r7, r3        @ 宏代码,位于arch/arm/mach-xxx/include/mach/debug-macro.S
  253.                         @ 作用是将串口控制寄存器的基址放入r7(物理地址)和r3(虚拟地址)
  254.     mov    r3, r3, lsr #20
  255.     mov    r3, r3, lsl #2

  256.     add    r0, r4, r3        @ r0为串口IO内存映射页表项的入口地址
  257.     rsb    r3, r3, #0x4000            @ 16K(PTRS_PER_PGD*sizeof(long))-r3
  258.     cmp    r3, #0x0800            @ limit to 512MB,入口地址有效性检查(只能在最后#0x0800内)
  259.     movhi    r3, #0x0800        @ 也就是说虚拟地址被限制在3.5G以上
  260.     add    r6, r0, r3            @ r6为页表结束地址
  261.     mov    r3, r7, lsr #20
  262.     ldr    r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
  263.     orr    r3, r7, r3, lsl #20    @ 生成节描述符
  264. 1:    str    r3, [r0], #4
  265.     add    r3, r3, #1 << 20
  266.     teq    r0, r6
  267.     bne    1b

  268. #else /* CONFIG_DEBUG_ICEDCC */
  269.     /* 我们无需任何串口调试映射 for ICEDCC */
  270.     ldr    r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
  271. #endif /* !CONFIG_DEBUG_ICEDCC */

  272. #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
  273.     /*
  274.      * 如果我们在使用 NetWinder 或 CATS,我们也需要为调试信息映射
  275.      * 16550-type 串口
  276.      */
  277.     add    r0, r4, #0xff000000 >> 18
  278.     orr    r3, r7, #0x7c000000
  279.     str    r3, [r0]
  280. #endif
  281. #ifdef CONFIG_ARCH_RPC
  282.     /*
  283.      * Map in screen at 0x02000000 & SCREEN2_BASE
  284.      * Similar reasons here - for debug. This is
  285.      * only for Acorn RiscPC architectures.
  286.      */
  287.     add    r0, r4, #0x02000000 >> 18
  288.     orr    r3, r7, #0x02000000
  289.     str    r3, [r0]
  290.     add    r0, r4, #0xd8000000 >> 18
  291.     str    r3, [r0]
  292. #endif
  293. #endif
  294.     mov    pc, lr        @页表创建结束,返回
  295. ENDPROC(__create_page_tables)
  296.     .ltorg
  297.     .align
  298. __enable_mmu_loc:
  299.     .long    .
  300.     .long    __enable_mmu
  301.     .long    __enable_mmu_end

  302. #if defined(CONFIG_SMP)
  303.     __CPUINIT
  304. ENTRY(secondary_startup)
  305.     /*
  306.      * Common entry point for secondary CPUs.
  307.      *
  308.      * Ensure that we're in SVC mode, and IRQs are disabled. Lookup
  309.      * the processor type - there is no need to check the machine type
  310.      * as it has already been validated by the primary processor.
  311.      */
  312.     setmode    PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9
  313.     mrc    p15, 0, r9, c0, c0        @ get processor id
  314.     bl    __lookup_processor_type
  315.     movs    r10, r5                @ invalid processor?
  316.     moveq    r0, #'p'            @ yes, error 'p'
  317.  THUMB( it    eq )        @ force fixup-able long branch encoding
  318.     beq    __error_p

  319.     /*
  320.      * Use the page tables supplied from __cpu_up.
  321.      */
  322.     adr    r4, __secondary_data
  323.     ldmia    r4, {r5, r7, r12}        @ address to jump to after
  324.     sub    lr, r4, r5            @ mmu has been enabled
  325.     ldr    r4, [r7, lr]            @ get secondary_data.pgdir
  326.     add    r7, r7, #4
  327.     ldr    r8, [r7, lr]            @ get secondary_data.swapper_pg_dir
  328.     adr    lr, BSYM(__enable_mmu)        @ return address
  329.     mov    r13, r12            @ __secondary_switched address
  330.  ARM(    add    pc, r10, #PROCINFO_INITFUNC    ) @ initialise processor
  331.                          @ (return control reg)
  332.  THUMB(    add    r12, r10, #PROCINFO_INITFUNC    )
  333.  THUMB(    mov    pc, r12                )
  334. ENDPROC(secondary_startup)

  335.     /*
  336.      * r6 = &secondary_data
  337.      */
  338. ENTRY(__secondary_switched)
  339.     ldr    sp, [r7, #4]            @ get secondary_data.stack
  340.     mov    fp, #0
  341.     b    secondary_start_kernel
  342. ENDPROC(__secondary_switched)

  343.     .align

  344.     .type    __secondary_data, %object
  345. __secondary_data:
  346.     .long    .
  347.     .long    secondary_data
  348.     .long    __secondary_switched
  349. #endif /* defined(CONFIG_SMP) */



  350. /*
  351.  * 在最后启动MMU前,设置一些常用位 Essentially
  352.  * 其实,这里只是加载了页表指针和域访问控制数据寄存器
  353.  *
  354.  *
  355.  * r0 = cp#15 control register
  356.  * r1 = machine ID
  357.  * r2 = atags or dtb pointer
  358.  * r4 = page table pointer
  359.  * r9 = processor ID
  360.  * r13 = 最后要跳入的虚拟地址
  361.  */
  362. __enable_mmu:
  363. #ifdef CONFIG_ALIGNMENT_TRAP
  364.     orr    r0, r0, #CR_A
  365. #else
  366.     bic    r0, r0, #CR_A
  367. #endif
  368. #ifdef CONFIG_CPU_DCACHE_DISABLE
  369.     bic    r0, r0, #CR_C
  370. #endif
  371. #ifdef CONFIG_CPU_BPREDICT_DISABLE
  372.     bic    r0, r0, #CR_Z
  373. #endif
  374. #ifdef CONFIG_CPU_ICACHE_DISABLE
  375.     bic    r0, r0, #CR_I
  376. #endif
  377.     mov    r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
  378.          domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
  379.          domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
  380.          domain_val(DOMAIN_IO, DOMAIN_CLIENT))    @设置域访问控制数据
  381.     mcr    p15, 0, r5, c3, c0, 0        @ 载入域访问控制数据到DACR
  382.     mcr    p15, 0, r4, c2, c0, 0        @ 载入页表基址到TTBR0
  383.     b    __turn_mmu_on                @ 开启MMU
  384. ENDPROC(__enable_mmu)

  385. /*
  386.  * 使能 MMU. 这完全改变了可见的内存地址空间结构。
  387.  * 您将无法通过这里跟踪执行。
  388.  * 如果你已对此进行探究, **在向邮件列表发送另一个新帖之前,
  389.  * 检查linux-arm-kernel的邮件列表归档
  390.  *
  391.  * r0 = cp#15 control register
  392.  * r1 = machine ID
  393.  * r2 = atags or dtb pointer
  394.  * r9 = processor ID
  395.  * r13 = 最后要跳入的*虚拟*地址
  396.  *
  397.  * 其他寄存器依赖上面的调用函数
  398.  */
  399.     .align    5
  400. __turn_mmu_on:
  401.     mov    r0, r0
  402.     mcr    p15, 0, r0, c1, c0, 0        @ 设置cp#15控制寄存器(启用MMU)
  403.     mrc    p15, 0, r3, c0, c0, 0        @ read id reg
  404.     mov    r3, r3
  405.     mov    r3, r13                        @ r3中装入最后要跳入的*虚拟*地址
  406.     mov    pc, r3                        @ 跳转到__mmap_switched
  407. __enable_mmu_end:
  408. ENDPROC(__turn_mmu_on)


  409. #ifdef CONFIG_SMP_ON_UP
  410.     __INIT
  411. __fixup_smp:
  412.     and    r3, r9, #0x000f0000    @ architecture version
  413.     teq    r3, #0x000f0000        @ CPU ID supported?
  414.     bne    __fixup_smp_on_up    @ no, assume UP

  415.     bic    r3, r9, #0x00ff0000
  416.     bic    r3, r3, #0x0000000f    @ mask 0xff00fff0
  417.     mov    r4, #0x41000000
  418.     orr    r4, r4, #0x0000b000
  419.     orr    r4, r4, #0x00000020    @ val 0x4100b020
  420.     teq    r3, r4            @ ARM 11MPCore?
  421.     moveq    pc, lr            @ yes, assume SMP

  422.     mrc    p15, 0, r0, c0, c0, 5    @ read MPIDR
  423.     and    r0, r0, #0xc0000000    @ multiprocessing extensions and
  424.     teq    r0, #0x80000000        @ not part of a uniprocessor system?
  425.     moveq    pc, lr            @ yes, assume SMP

  426. __fixup_smp_on_up:
  427.     adr    r0, 1f
  428.     ldmia    r0, {r3 - r5}
  429.     sub    r3, r0, r3
  430.     add    r4, r4, r3
  431.     add    r5, r5, r3
  432.     b    __do_fixup_smp_on_up
  433. ENDPROC(__fixup_smp)

  434.     .align
  435. 1:    .word    .
  436.     .word    __smpalt_begin
  437.     .word    __smpalt_end

  438.     .pushsection .data
  439.     .globl    smp_on_up
  440. smp_on_up:
  441.     ALT_SMP(.long    1)
  442.     ALT_UP(.long    0)
  443.     .popsection
  444. #endif

  445.     .text
  446. __do_fixup_smp_on_up:
  447.     cmp    r4, r5
  448.     movhs    pc, lr
  449.     ldmia     {r0, r6}
  450.  ARM(    str    r6, [r0, r3]    )
  451.  THUMB(    add    r0, r0, r3    )
  452. #ifdef __ARMEB__
  453.  THUMB(    mov    r6, r6, ror #16    )    @ Convert word order for big-endian.
  454. #endif
  455.  THUMB(    strh    r6, [r0], #2    )    @ For Thumb-2, store as two halfwords
  456.  THUMB(    mov    r6, r6, lsr #16    )    @ to be robust against misaligned r3.
  457.  THUMB(    strh    r6, [r0]    )
  458.     b    __do_fixup_smp_on_up
  459. ENDPROC(__do_fixup_smp_on_up)

  460. ENTRY(fixup_smp)
  461.     stmfd     {r4 - r6, lr}
  462.     mov    r4, r0
  463.     add    r5, r0, r1
  464.     mov    r3, #0
  465.     bl    __do_fixup_smp_on_up
  466.     ldmfd     {r4 - r6, pc}
  467. ENDPROC(fixup_smp)

  468. #ifdef CONFIG_ARM_PATCH_PHYS_VIRT

  469. /* __fixup_pv_table - patch the stub instructions with the delta between
  470.  * PHYS_OFFSET and PAGE_OFFSET, which is assumed to be 16MiB aligned and
  471.  * can be expressed by an immediate shifter operand. The stub instruction
  472.  * has a form of '(add|sub) rd, rn, #imm'.
  473.  */
  474.     __HEAD
  475. __fixup_pv_table:
  476.     adr    r0, 1f
  477.     ldmia    r0, {r3-r5, r7}
  478.     sub    r3, r0, r3    @ PHYS_OFFSET - PAGE_OFFSET
  479.     add    r4, r4, r3    @ adjust table start address
  480.     add    r5, r5, r3    @ adjust table end address
  481.     add    r7, r7, r3    @ adjust __pv_phys_offset address
  482.     str    r8, [r7]    @ save computed PHYS_OFFSET to __pv_phys_offset
  483. #ifndef CONFIG_ARM_PATCH_PHYS_VIRT_16BIT
  484.     mov    r6, r3, lsr #24    @ constant for add/sub instructions
  485.     teq    r3, r6, lsl #24 @ must be 16MiB aligned
  486. #else
  487.     mov    r6, r3, lsr #16    @ constant for add/sub instructions
  488.     teq    r3, r6, lsl #16    @ must be 64kiB aligned
  489. #endif
  490. THUMB(    it    ne        @ cross section branch )
  491.     bne    __error
  492.     str    r6, [r7, #4]    @ save to __pv_offset
  493.     b    __fixup_a_pv_table
  494. ENDPROC(__fixup_pv_table)

  495.     .align
  496. 1:    .long    .
  497.     .long    __pv_table_begin
  498.     .long    __pv_table_end
  499. 2:    .long    __pv_phys_offset

  500.     .text
  501. __fixup_a_pv_table:
  502. #ifdef CONFIG_THUMB2_KERNEL
  503. #ifdef CONFIG_ARM_PATCH_PHYS_VIRT_16BIT
  504.     lsls    r0, r6, #24
  505.     lsr    r6, #8
  506.     beq    1f
  507.     clz    r7, r0
  508.     lsr    r0, #24
  509.     lsl    r0, r7
  510.     bic    r0, 0x0080
  511.     lsrs    r7, #1
  512.     orrcs r0, #0x0080
  513.     orr    r0, r0, r7, lsl #12
  514. #endif
  515. 1:    lsls    r6, #24
  516.     beq    4f
  517.     clz    r7, r6
  518.     lsr    r6, #24
  519.     lsl    r6, r7
  520.     bic    r6, #0x0080
  521.     lsrs    r7, #1
  522.     orrcs    r6, #0x0080
  523.     orr    r6, r6, r7, lsl #12
  524.     orr    r6, #0x4000
  525.     b    4f
  526. 2:    @ at this point the C flag is always clear
  527.     add r7, r3
  528. #ifdef CONFIG_ARM_PATCH_PHYS_VIRT_16BIT
  529.     ldrh    ip, [r7]
  530.     tst    ip, 0x0400    @ the i bit tells us LS or MS byte
  531.     beq    3f
  532.     cmp    r0, #0        @ set C flag, and ...
  533.     biceq    ip, 0x0400    @ immediate zero value has a special encoding
  534.     streqh    ip, [r7]    @ that requires the i bit cleared
  535. #endif
  536. 3:    ldrh    ip, [r7, #2]
  537.     and    ip, 0x8f00
  538.     orrcc    ip, r6    @ mask in offset bits 31-24
  539.     orrcs    ip, r0    @ mask in offset bits 23-16
  540.     strh    ip, [r7, #2]
  541. 4:    cmp    r4, r5
  542.     ldrcc    r7, [r4], #4    @ use branch for delay slot
  543.     bcc    2b
  544.     bx    lr
  545. #else
  546. #ifdef CONFIG_ARM_PATCH_PHYS_VIRT_16BIT
  547.     and    r0, r6, #255    @ offset bits 23-16
  548.     mov    r6, r6, lsr #8    @ offset bits 31-24
  549. #else
  550.     mov    r0, #0        @ just in case...
  551. #endif
  552.     b    3f
  553. 2:    ldr    ip, [r7, r3]
  554.     bic    ip, ip, #0x000000ff
  555.     tst    ip, #0x400    @ rotate shift tells us LS or MS byte
  556.     orrne    ip, ip, r6    @ mask in offset bits 31-24
  557.     orreq    ip, ip, r0    @ mask in offset bits 23-16
  558.     str    ip, [r7, r3]
  559. 3:    cmp    r4, r5
  560.     ldrcc    r7, [r4], #4    @ use branch for delay slot
  561.     bcc    2b
  562.     mov    pc, lr
  563. #endif
  564. ENDPROC(__fixup_a_pv_table)

  565. ENTRY(fixup_pv_table)
  566.     stmfd     {r4 - r7, lr}
  567.     ldr    r2, 2f            @ get address of __pv_phys_offset
  568.     mov    r3, #0            @ no offset
  569.     mov    r4, r0            @ r0 = table start
  570.     add    r5, r0, r1        @ r1 = table size
  571.     ldr    r6, [r2, #4]        @ get __pv_offset
  572.     bl    __fixup_a_pv_table
  573.     ldmfd     {r4 - r7, pc}
  574. ENDPROC(fixup_pv_table)

  575.     .align
  576. 2:    .long    __pv_phys_offset

  577.     .data
  578.     .globl    __pv_phys_offset
  579.     .type    __pv_phys_offset, %object
  580. __pv_phys_offset:
  581.     .long    0
  582.     .size    __pv_phys_offset, . - __pv_phys_offset
  583. __pv_offset:
  584.     .long    0
  585. #endif

  586. #include "head-common.S"
arch/arm/kernel/head-common.S
  1. /*
  2.  * linux/arch/arm/kernel/head-common.S
  3.  *
  4.  * Copyright (C) 1994-2002 Russell King
  5.  * Copyright (c) 2003 ARM Limited
  6.  * All Rights Reserved
  7.  *
  8.  * This program is free software; you can redistribute it and/or modify
  9.  * it under the terms of the GNU General Public License version 2 as
  10.  * published by the Free Software Foundation.
  11.  *
  12.  */

  13. #define ATAG_CORE 0x54410001
  14. #define ATAG_CORE_SIZE ((2*4 + 3*4) >> 2)
  15. #define ATAG_CORE_SIZE_EMPTY ((2*4) >> 2)

  16. #ifdef CONFIG_CPU_BIG_ENDIAN
  17. #define OF_DT_MAGIC 0xd00dfeed
  18. #else
  19. #define OF_DT_MAGIC 0xedfe0dd0 /* 0xd00dfeed in big-endian */
  20. #endif

  21. /*
  22.  * 异常处理. 一些我们无法处理的错误.
  23.  * 我们应当告诉用户(这些错误信息),但因为我们甚至无法保证是在正确的架构上运行,
  24.  * 所以我们什么都不做(死循环)。
  25.  *
  26.  * 如果 CONFIG_DEBUG_LL 被设置,我们试图打印出错误信息,
  27.  * 并希望这可以对我们有帮助 (例如这对bootloader没有提供适当的处理器ID
  28.  * 是有帮助的).
  29.  */
  30.     __HEAD

  31. /* 确定r2(内核启动参数)指针的有效性。 The heuristic 要求
  32.  * 是4Byte对齐的、在物理内存的头16K中,且以ATAG_CORE标记开头。
  33.  * 如果选择了CONFIG_OF_FLATTREE,dtb指针也是可以接受的.
  34.  *
  35.  * 在这个函数的未来版本中 可能会对物理地址的要求更为宽松,
  36.  * 且如果有必要的话,可能可以移动ATAGS数据块.
  37.  *
  38.  * 返回:
  39.  * r2 可能是有效的 atags 指针, 有效的 dtb 指针,或者0
  40.  * r5, r6 被篡改
  41.  */
  42. __vet_atags:
  43.     tst    r2, #0x3            @ 是否4Byte对齐?
  44.     bne    1f                    @ 不是则认为指针无效,返回

  45.     ldr    r5, [r2, #0]        @获取r2指向的前4Byte,用于下面测试
  46. #ifdef CONFIG_OF_FLATTREE
  47.     ldr    r6, =OF_DT_MAGIC        @ is it a DTB?
  48.     cmp    r5, r6
  49.     beq    2f
  50. #endif

  51.     /* 内核启动参数块的规范是:
  52.      * (wait for updata)
  53.      */
  54.     cmp    r5, #ATAG_CORE_SIZE        @ 第一个tag是ATAG_CORE吗?测试的是tag_header中的size
  55.                                 @ 如果为ATAG_CORE,那么必为ATAG_CORE_SIZE
  56.     cmpne    r5, #ATAG_CORE_SIZE_EMPTY    @ 如果第一个tag的tag_header中的size为ATAG_CORE_SIZE_EMPTY
  57.                                         @ 说明此处也有atags
  58.     bne    1f
  59.     ldr    r5, [r2, #4]            @ 第一个tag_header的tag(魔数)
  60.     ldr    r6, =ATAG_CORE            @ 获取ATAG_CORE的魔数
  61.     cmp    r5, r6                    @ 判断第一个tag是否为ATAG_CORE
  62.     bne    1f                        @ 不是则认为指针无效,返回

  63. 2:    mov    pc, lr                @ atag/dtb 指针有效

  64. 1:    mov    r2, #0
  65.     mov    pc, lr
  66. ENDPROC(__vet_atags)

  67. /*
  68.  * 以下的代码段是在MMU开启的状态下执行的,
  69.  * 而且使用的是绝对地址; 这不是位置无关代码.
  70.  *
  71.  * r0 = cp#15 控制寄存器值
  72.  * r1 = machine ID
  73.  * r2 = atags/dtb pointer
  74.  * r9 = processor ID
  75.  */
  76.     __INIT
  77. __mmap_switched:
  78.     adr    r3, __mmap_switched_data

  79.     ldmia     {r4, r5, r6, r7}
  80.     cmp    r4, r5                @ 如果有必要,拷贝数据段。
  81.                             @ 对比__data_loc和_sdata
  82.                             @ __data_loc是数据段在内核代码映像中的存储位置
  83.                             @ _sdata是数据段的链接位置(在内存中的位置)
  84.                             @ 如果是XIP技术的内核,这两个数据肯定不同
  85. 1:    cmpne    r5, r6            @ 检测数据是否拷贝完成
  86.     ldrne    fp, [r4], #4
  87.     strne    fp, [r5], #4
  88.     bne    1b

  89.     mov    fp, #0                @ 清零 BSS 段(and zero fp)
  90. 1:    cmp    r6, r7                @ 检测是否完成
  91.     strcc    fp, [r6],#4
  92.     bcc    1b

  93.     /* 这里将需要的数据从寄存器中转移到全局变量中,
  94.      * 因为最后会跳入C代码,寄存器会被使用。
  95.      */
  96.  ARM(    ldmia    r3, {r4, r5, r6, r7, sp})
  97.  THUMB(    ldmia    r3, {r4, r5, r6, r7}    )
  98.  THUMB(    ldr    sp, [r3, #16]        )
  99.     str    r9, [r4]            @ 保存 processor ID到全局变量processor_id
  100.     str    r1, [r5]            @ 保存 machine type到全局变量__machine_arch_type
  101.     str    r2, [r6]            @ 保存 atags指针到全局变量__atags_pointer
  102.     bic    r4, r0, #CR_A            @ 清除cp15 控制寄存器值的 'A' bit(禁用对齐错误检查)
  103.     stmia    r7, {r0, r4}            @ 保存控制寄存器值到全局变量cr_alignment(在arch/arm/kernel/entry-armv.S)
  104.     b    start_kernel        @ 跳入C代码(init/main.c)
  105. ENDPROC(__mmap_switched)

  106.     .align    2
  107.     .type    __mmap_switched_data, %object
  108. __mmap_switched_data:
  109.     .long    __data_loc            @ r4
  110.     .long    _sdata                @ r5
  111.     .long    __bss_start            @ r6
  112.     .long    _end                @ r7
  113.     .long    processor_id            @ r4
  114.     .long    __machine_arch_type        @ r5
  115.     .long    __atags_pointer            @ r6
  116.     .long    cr_alignment            @ r7
  117.     .long    init_thread_union + THREAD_START_SP @ sp
  118.     .size    __mmap_switched_data, . - __mmap_switched_data

  119. /*
  120.  * 这里提供一个 C-API 版本的 __lookup_processor_type
  121.  */
  122. ENTRY(lookup_processor_type)
  123.     stmfd     {r4 - r6, r9, lr}
  124.     mov    r9, r0
  125.     bl    __lookup_processor_type
  126.     mov    r0, r5
  127.     ldmfd     {r4 - r6, r9, pc}
  128. ENDPROC(lookup_processor_type)

  129. /*
  130.  * 读取处理器ID寄存器 (CP#15, CR0), 并且查找编译时确定的处理器
  131.  * 支持列表. 注意:我们不能对__proc_info使用绝对地址,
  132.  * 因为我们还没有重新初始化页表(MMU已关闭,之前是解压时使用的1:1映射)。
  133.  * (我们不在正确的地址空间:内核是按虚拟地址(0xc00008000)编译的,
  134.  * 而现在我们运行在MMU关闭的情况下)
  135.  * 我们必须计算偏移量。
  136.  *
  137.  *    r9 = cpuid
  138.  * Returns:
  139.  *    r3, r4, r6 被篡改
  140.  *    r5 = proc_info 指针(物理地址空间)
  141.  *    r9 = cpuid (保留)
  142.  */
  143.     __CPUINIT
  144. __lookup_processor_type:
  145.     adr    r3, __lookup_processor_type_data        @获取运行时的地址数据
  146.     ldmia    r3, {r4 - r6}    @获取编译时确定的地址数据(虚拟地址)
  147.     sub    r3, r3, r4            @ 获取地址偏移 virt&phys(r3)
  148.     add    r5, r5, r3            @ 将虚拟地址空间转换为物理地址空间
  149.     add    r6, r6, r3            @ r5=__proc_info_begin r6=__proc_info_end
  150. 1:    ldmia    r5, {r3, r4}    @ 获取proc_info_list结构体中的value, mask
  151.     and    r4, r4, r9            @ 利用掩码处理从CP15获取的处理器ID
  152.     teq    r3, r4                @ 对比编译时确定的处理器ID
  153.     beq    2f                    @ 若处理器ID匹配,返回
  154.     add    r5, r5, #PROC_INFO_SZ        @ 利用sizeof(proc_info_list)跳入下一个处理器ID的匹配
  155.     cmp    r5, r6                @ 是否已经处理完proc_info_list数据
  156.     blo    1b                    @ 如果还有proc_info_list数据,再次检查匹配
  157.     mov    r5, #0                @ 否则,编译的内核与此处理器不匹配,r5 = #0
  158. 2:    mov    pc, lr
  159. ENDPROC(__lookup_processor_type)

  160. /*
  161.  * 参见 <asm/procinfo.h> 中关于 __proc_info 结构体的信息.
  162.  */
  163.     .align    2
  164.     .type    __lookup_processor_type_data, %object
  165. __lookup_processor_type_data:
  166.     .long    .
  167.     .long    __proc_info_begin
  168.     .long    __proc_info_end
  169.     .size    __lookup_processor_type_data, . - __lookup_processor_type_data

  170. /*
  171.  * 处理器ID不匹配时的入口
  172.  * 如果启用了调试信息,会从consol打印提示信息
  173.  * 之后会进入__error的死循环
  174.  */
  175. __error_p:
  176. #ifdef CONFIG_DEBUG_LL
  177.     adr    r0, str_p1
  178.     bl    printascii
  179.     mov    r0, r9
  180.     bl    printhex8
  181.     adr    r0, str_p2
  182.     bl    printascii
  183.     b    __error
  184. str_p1:    .asciz    "\nError: unrecognized/unsupported processor variant (0x"
  185. str_p2:    .asciz    ").\n"
  186.     .align
  187. #endif
  188. ENDPROC(__error_p)

  189. /*
  190.  * 出错时的死循环入口
  191.  */
  192. __error:
  193. #ifdef CONFIG_ARCH_RPC
  194. /*
  195.  * 出错时屏幕变红 - RiscPC only.
  196.  */
  197.     mov    r0, #0x02000000
  198.     mov    r3, #0x11
  199.     orr    r3, r3, r3, lsl #8
  200.     orr    r3, r3, r3, lsl #16
  201.     str    r3, [r0], #4
  202.     str    r3, [r0], #4
  203.     str    r3, [r0], #4
  204.     str    r3, [r0], #4
  205. #endif
  206. 1:    mov    r0, r0
  207.     b    1b
  208. ENDPROC(__error)

阅读(616) | 评论(0) | 转发(0) |
给主人留下些什么吧!~~
评论热议
请登录后评论。

登录 注册