编写ok6410的bootloader

买了一个ok6410的板子，准备开始学习嵌入式linux，同时也想把自己的学习历程记录下来，方便以后看看。有什么问题请各位朋友指教。
bootloader的作用主要就是：先将内核拷贝到RAM，再传递bootargs地址并启动内核。
我主要用的C语音，只有直接操作CPU寄存器才用了一点汇编。

1. arm11的cpu在访问I/O内存之前要先映射一下总线地址：
        mov r0, #0x70000000
        orr r0, r0, #0x13
        mcr p15, 0, r0, c15, c2, 4

2. 关闭看门狗，不然系统会不断重启的：
        ldr r0, =0x7e004000
        mov r1, #0
        str r1, [r0]

3. 其实还要关闭MMU，禁止cache等等，但上电默认如此，就省略了。

4. S3C6410的中断不再是单片机式的跳转指令，而是像X86的使用中断控制器，但首先要设置CPU使用VIC控制器，而不是发生跳转：
        mrc p15, 0, r0, c1, c0, 0
        orr r0, r0, #(1 << 24)
        mcr p15, 0, r0, c1, c0, 0

5. 在调用C程序之前设置好堆栈指针,由于这里使用了ARM的两种模式,管理模式和中断模式，所以两个堆栈指针都要设置：
        （我对ARM架构的多种模式有点不懂，也不知道为什么要用这么多种模式，希望明白的更我讲一下，谢谢）
        （ 改：我后来弄懂了，是为了用户能够系统调用内核，可以见我写的： ARM硬件基础之一  : ) ）
        @切换模式来设置中断模式的sp
        mrs r0, cpsr
        bic r0, r0, #0x1f
        orr r0, r0, #0x12
        msr cpsr, r0
        @现在是中断模式
        mov sp, #0x52000000

        @再把模式切换到SVC模式
        mrs r0, cpsr
        bic r0, r0, #0x1f
        orr r0, r0, #0x13
        msr cpsr, r0
        @堆栈8KB
        mov sp, #0x2000

6. 再初始化时钟，初始化Nand Flash，初始化Uart，Led，初始化SDRAM：
        bl    system_clock_init
        bl    uart_asm_init
        bl    nand_asm_init
        bl    led_init        
        bl    ddr_init

        （后面粘上三个主要函数的代码）其实对这些寄存器的访问都可以用C语言就实现的  : (

.global system_clock_init
system_clock_init:
    ldr    r0, =0x7e00f000

    ldr    r1, [r0, #OTHERS_OFFSET]
    mov    r2, #0x40
    orr    r1, r1, r2
    str    r1, [r0, #OTHERS_OFFSET]

    nop
    nop
    nop
    nop
    nop

    ldr    r2, =0x80
    orr    r1, r1, r2
    str    r1, [r0, #OTHERS_OFFSET]

check_syncack:
    ldr    r1, [r0, #OTHERS_OFFSET]
    ldr    r2, =0xf00
    and    r1, r1, r2
    cmp    r1, #0xf00
    bne    check_syncack

    mov    r1, #0xff00
    orr    r1, r1, #0xff
    str    r1, [r0, #APLL_LOCK_OFFSET]
    str    r1, [r0, #MPLL_LOCK_OFFSET]
    str    r1, [r0, #EPLL_LOCK_OFFSET]
/* CLKUART(=66.5Mhz) = CLKUART_input(532/2=266Mhz) / (UART_RATIO(3)+1) */
/* CLKUART(=50Mhz) = CLKUART_input(400/2=200Mhz) / (UART_RATIO(3)+1) */
/* Now, When you use UART CLK SRC by EXT_UCLK1, We support 532MHz & 400MHz value */

    ldr       r1, [r0, #CLK_DIV2_OFFSET]
    bic    r1, r1, #0x70000
    orr    r1, r1, #0x30000
    str    r1, [r0, #CLK_DIV2_OFFSET]

    ldr       r1, [r0, #CLK_DIV0_OFFSET]    /*Set Clock Divider*/
    bic    r1, r1, #0x30000
    bic    r1, r1, #0xff00
    bic    r1, r1, #0xff
    ldr    r2, =CLK_DIV_VAL
    orr    r1, r1, r2
    str    r1, [r0, #CLK_DIV0_OFFSET]

    ldr    r1, =APLL_VAL
    str    r1, [r0, #APLL_CON_OFFSET]
    ldr    r1, =MPLL_VAL
    str    r1, [r0, #MPLL_CON_OFFSET]

    ldr    r1, =0x80420302            /* FOUT of EPLL is 96MHz *///    66MHz
    str    r1, [r0, #EPLL_CON0_OFFSET]
    ldr    r1, =0x0
    str    r1, [r0, #EPLL_CON1_OFFSET]

    ldr    r1, [r0, #CLK_SRC_OFFSET]    /* APLL, MPLL, EPLL select to Fout */

    ldr    r2, =0x2007

    orr    r1, r1, r2

    str    r1, [r0, #CLK_SRC_OFFSET]

    /* wait at least 200us to stablize all clock */
    mov    r1, #0x10000
1:    subs    r1, r1, #1
    bne    1b

    /* Synchronization for VIC port */
    ldr    r1, [r0, #OTHERS_OFFSET]
    orr    r1, r1, #0x20
    str    r1, [r0, #OTHERS_OFFSET]

    mov    pc, lr

.global    nand_asm_init
nand_asm_init:
    ldr    r0, =ELFIN_NAND_BASE
    ldr    r1, [r0, #NFCONF_OFFSET]
    orr    r1, r1, #0x70
    orr    r1, r1, #0x7700
    str r1, [r0, #NFCONF_OFFSET]

    ldr    r1, [r0, #NFCONT_OFFSET]
    orr    r1, r1, #0x03
    str r1, [r0, #NFCONT_OFFSET]

    mov    pc, lr

#define DDR_READY while((P1MEMSTAT & 3) != 1)

void ddr_time(void);
void ddr_cmd(void);

void ddr_init(void)
{
    //port
    MEM_SYS_CFG &= ~(1 << 7);
    P1MEMCCMD = 0x4;//config mod
    //attribute
    P1MEMCFG = (2 << 15) | (3 << 3) | (2);        //2 SDRAM
    P1MEMCFG2 = (1 << 11) | (3 << 8) | (1 << 6) | (3);
    P1_chip_0_cfg = (1<<16)|(0x50<<8)|(0xf8<<0);
    //time
    ddr_time();
    //cmd
    ddr_cmd();

    P1MEMCCMD = 0x0;//go mod
    DDR_READY;
}

unsigned int ns_to_clk(unsigned int ns)
{
    return (ns / (1000000000 / 133000000)+1);
}

void ddr_time(void)
{
    P1REFRESH = ns_to_clk(7800);
    P1CASLAT = 3 << 1;
    P1T_DQSS = 1;
    P1T_MRD = 2;
    P1T_RAS = ns_to_clk(50);
    P1T_RC = ns_to_clk(70);
    P1T_RCD = ns_to_clk(25) | ((ns_to_clk(25) - 3) << 3);
    P1T_RFC = ns_to_clk(80) | ((ns_to_clk(80) - 3) << 5);
    P1T_RP = ns_to_clk(25) | ((ns_to_clk(25) - 3) << 3);
    P1T_RRD = ns_to_clk(20);
    P1T_WR = ns_to_clk(20);
    P1T_WTR = 1;
    P1T_XP = 2;
    P1T_XSR = ns_to_clk(120);
    P1T_ESR = ns_to_clk(120);
}

void ddr_cmd(void)
{
    P1DIRECTCMD = 2 << 18;
    P1DIRECTCMD = 0 << 18;
    P1DIRECTCMD = 3 << 18;
    P1DIRECTCMD = 3 << 18;

    P1DIRECTCMD = (2 << 18) | (2 << 16);
    P1DIRECTCMD = (2 << 18) | (0 << 16) | (3 << 4) | 2;
}

    

7. 上面都是在8k的stepping stone里执行的，现在准备工作完成，将代码拷贝到sdram接着上面执行，最好重新设置一下堆栈指针到SDRAM：
        （不过最初代码在nand flash里，启动是stepping stone，但是代码是如何从nand到stepping stone的呢？ 不解 :(  ）
        （这几天看数据手册，它说有个stepping stone的控制器，可以将代码复制到内部的RAM中执行）
        bl    copy_uboot_to_ram
        ldr    sp,=0x58000000
        @终于进入C程序了
        ldr    pc,=main

8. 到main里就什么都好搞了，首先要开中断，再亮个灯，串口输出hello world，再用LCD显示个logo，玩玩rtc校准时钟：
        enable_irq();
        led_on(0);  
        uart_test();
        lcd_test();
        rtc_timedisp();

9. 接着最重要，将linux内核zImage从nand flash拷贝到SDRAM的0x50008000 ：
        copy_kernel_to_ram();

10. 再将bootargs放到0x50000100，这是内核默认了的参数位置，并跳到0x50008000运行启动内核，用一个函数即可完成：
        bootm(0x50008000,"root=/dev/nfs nfsroot=115.156.138.17:/home/nfs ip=115.156.138.18:115.156.138.17:115.156.138.110:255.255.255.0 console=ttySAC0,115200");

11. 内核启动后bootloader任务就完成了，内核会通过NFS挂载根文件系统。