王爽汇编---字符串输入分析

assume cs:code
code segment
start:
push ax
getstrs:
mov ah,0
int 16h;调用16号中断0号子程序，读取键盘输入

cmp al,20h;判断键盘输入的是否为字符
jb nochar;不是就跳转
mov ah,0;如果是字符，设置ah=0(表示要入栈）
call charstack;调用栈操作
mov ah,2
call charstack
jmp getstrs
nochar:
cmp ah,0eh;是否为“Backspace”键
je backspace;是就跳转
cmp ah,1ch
je enterkey
jmp getstrs
backspace:
mov ah,1;设置ah=1,表示出栈
call charstack
mov ah,2;设置ah=2,表示显示栈内容
call charstack
jmp getstrs

enterkey:
mov al,0;如果是“Enter”键，设置al=0
mov ah,0
call charstack;调用0号功能且获取字符为“0”
mov ah,2
call charstack
pop ax
ret

charstack:jmp short charstart
table dw charpush,charpop,charshow
top dw 0
charstart:
push bx
push dx
push di
push es

cmp ah,2
ja sret
mov bl,ah
mov bh,0
add bx,bx
jmp word ptr table[bx];根据跳转到指定的标号地址处
charpush:
mov bx,top;保存栈顶SP至bx
mov [si][bx],al;将键盘输入移动至栈内
inc top;移动栈顶SP
jmp sret
charpop:
cmp top,0
je sret
dec top
mov bx,top
mov al,[si][bx];将sp栈顶元素弹出到al中
jmp sret
charshow:
mov bx,0b800h
mov es,bx;es段为显示缓冲区
mov al,160
mov ah,0
mul dh
mov di,ax
add dl,dl
mov dh,0
add di,dx
mov bx,0;设置光标及字符属性
charshows:
cmp bx,top;判断栈是否为空
jne noempty
mov byte ptr es:[di],' '
jmp sret
noempty:
mov al,[si][bx];将栈顶元素复制到al
mov es:[di],al;将元素输出到显示缓冲区
mov byte ptr es:[di+2],' ';字符属性设置
inc bx;栈中下一个字符
add di,2;缓冲区一个字符占2字节
jmp charshows;循环显示栈栈中内容
sret:
pop es
pop di
pop dx
pop bx
ret
code ends
end start