脱离操作系统的bootloader—44binit.s的注释

脱离操作系统的代码文件大概有下面几个，一个很重要的初始化开发板的汇编代码就是44binit.s，另一个是44BLIB_A.S，它是汇编函数的库文件，包括改变存储控制寄存器函数，打开和关闭中断函数，最后一个就是用户的应用程序（可以有多个c源文件）。当44binit.s执行到BL Main，就跳转到该用户文件（它是个c源码文件）的main函数中去了。这三个文件是ADS使用的经典工程文件，还有一个文件夹名字叫INC，里面放的是工程所用到的库文件，包括两个汇编头文件和c头文件，MEMCFG.S就包含了内存初始化的参数，类似u-boot里的memsetup.s，定义了各个bank和刷新寄存器的参数；还有option.s对PLLCLK      不同值的参数设置。C头文件用得较多的是44B.H，定义cpu内特殊功能寄存器的地址。这些文件通过ADS软件make可生成二进制bin文件和可供AXD调试的axf文件。

    GET ..\inc\option.s   //相当于c语言中的#include "option.s"

    GET ..\inc\memcfg.s

;Interrupt Control   //中断控制器的特殊功能寄存器对应的地址

INTPND     EQU       0x01e00004

INTMOD           EQU       0x01e00008

INTMSK     EQU       0x01e0000c

I_ISPR        EQU       0x01e00020

I_CMST     EQU       0x01e0001c

;Watchdog timer   //看门狗定时器

WTCON     EQU       0x01d30000

;Clock Controller     //时钟控制器

PLLCON     EQU       0x01d80000

CLKCON           EQU       0x01d80004

LOCKTIME    EQU    0x01d8000c

      

;Memory Controller   //内存控制器

REFRESH          EQU 0x01c80024    ;Dram/sdram刷新控制寄存器

;Pre-defined constants    //预定义的常量

;下面是对arm处理器模式寄存器对应值的常数定义，arm处理器中有一个CPSR程序状态寄存器 它的后五位决定目前的处理器模式

;0b10000用户模式

;0b10001FIQ模式 等

USERMODE    EQU   0x10

FIQMODE         EQU       0x11

IRQMODE         EQU       0x12

SVCMODE         EQU       0x13

ABORTMODE   EQU 0x17

UNDEFMODE   EQU 0x1b

MODEMASK    EQU 0x1f

NOINT       EQU       0xc0

;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令 2.Thumb:16位 这种工作状态执行半字对准的Thumb指令

;因为处理器分为16位 32位两种工作状态 程序的编译器也是分16位和32两种编译方式 所以下面的程序用于根据处理器工作状态确定编译器编译方式

;code16伪指令指示汇编编译器后面的指令为16位的thumb指令

;code32伪指令指示汇编编译器后面的指令为32位的arm指令

;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译）

;check if tasm.exe is used.

    GBLL    THUMBCODE   ;设置一个全局逻辑变量

    [ {CONFIG} = 16      

THUMBCODE SETL     {TRUE}

    CODE32

    |  

THUMBCODE SETL     {FALSE}

    ]

;if config==16 这里表示你的目前处于领先地16位编译方式，设置THUMBCODE 为 true，否则就转入32位编译模式，设置THUMBCODE 为 false

    [ THUMBCODE

    CODE32   ;for start-up code for Thumb mode

    ]

注意下面这段程序是个宏定义

;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。

;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字空间都有一个标号，以Handle***命名。

;在向量中断模式下使用“加载程序”来执行中断服务程序。

;这里就必须讲一下向量中断模式和非向量中断模式的概念

;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址

;函数中 节省了中断处理时间提高了中断处理速度 例如 ADC中断的向量地址为0xC0,则在0xC0处放如下代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会

;自动跳转到HandlerADC函数中

;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt pending寄存器中对应标志位置位 然后跳转到位于0x18处的统一中断

;函数中 该函数通过读取interrupt pending寄存器中对应标志位 来判断中断源 并根据优先级关系再跳到对应中断源的处理代码中

    MACRO

$HandlerLabel HANDLER $HandleLabel

$HandlerLabel

    sub     sp,sp,#4     ;decrement sp(to store jump address)堆栈的增长方向为递减

    stmfd   sp!,{r0}       ;PUSH the work register to stack(lr does't push because it return to original address);将要使用的r0寄存器入栈

    ;用FD后缀代表满递减堆栈，stmfd 为入栈

    ldr       r0,=$HandleLabel;load the address of HandleXXX to r0

    ldr       r0,[r0]         ;load the contents(service routine start address) of HandleXXX

    str       r0,[sp,#4]           ;store the contents(ISR) of HandleXXX to stack

    ;将对应的中断函数首地址入栈

    ldmfd   sp!,{r0,pc}         ;POP the work register and pc(jump to ISR);将中断函数首地址出栈 放入程序指针中 系统将跳转到对应中断处理函数

    MEND

;一个arm由RO,RW,ZI三个断组成 （对于GNU工具 对应的概念是TEXT ,DATA,BSS）

;bootloader要将RW段复制到ro中并将ZI段清零 编译器使用下列段来记录各段的起始和结束地址

; |Image$$RO$$Base| ; RO段起始地址

; |Image$$RO$$Limit| ; RO段结束地址加1

; |Image$$RW$$Base| ; RW段起始地址

; |Image$$RW$$Limit| ; RW段结束地址加1

; |Image$$ZI$$Base| ; ZI段起始地址

; |Image$$ZI$$Limit| ; ZI段结束地址加1

;这些标号的值是通过编译器的设定来确定的 如编译软件ADS中对ro-base和rw-base的设定

    IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)

    IMPORT |Image$$RW$$Base|   ; Base of RAM to initialise

    IMPORT |Image$$ZI$$Base|   ; Base and limit of area

    IMPORT |Image$$ZI$$Limit| ; to zero initialise

   IMPORT Main   ; The main entry of mon program

AREA    Init,CODE,READONLY

;异常中断矢量表（每个表项占4个字节） 下面是中断向量表 一旦系统运行时有中断发生 即使移植了操作系统

;如linux 处理器已经把控制权交给了操作系统 一旦发生中断 处理器还是会跳转到从0x0开始

;中断向量表中某个中断表项（依据中断类型）开始执行

    ENTRY ;扳子上电和复位后 程序开始从位于0x0处开始执行硬件刚刚上电复位后 程序从这里开始执行跳转到标号为ResetHandler处执行

    b ResetHandler ;for debug

    b HandlerUndef ;handlerUndef

    b HandlerSWI    ;SWI interrupt handler

。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。

    b .

    b .

;0xe0=EnterPWDN

    ldr pc,=EnterPWDN

LTORG  

;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理函数

HandlerFIQ     HANDLER HandleFIQ

HandlerIRQ    HANDLER HandleIRQ

HandlerUndef HANDLER HandleUndef

HandlerSWI    HANDLER HandleSWI

HandlerDabort HANDLER HandleDabort

HandlerPabort HANDLER HandlePabort

;One of the following two routines can be used for non-vectored interrupt.

;下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务

;中断就将pc置为中断服务函数首地址

IsrIRQ    ;using I_ISPR register.

    sub     sp,sp,#4       ;reserved for PC

    stmfd   sp!,{r8-r9}  

       ;IMPORTANT CAUTION

       ;if I_ISPC isn't used properly, I_ISPR can be 0 in this routine.

    ldr       r9,=I_ISPR

    ldr       r9,[r9]

    mov     r8,#0x0

0

    movs    r9,r9,lsr #1

    bcs     %F1

    add     r8,r8,#4

    b         %B0

1

    ldr       r9,=HandleADC

    add     r9,r9,r8

    ldr       r9,[r9]

    str       r9,[sp,#8]

    ldmfd   sp!,{r8-r9,pc}

;****************************************************

;*    START                                    *

;****************************************************

ResetHandler

;扳子上电和复位后 程序开始从位于0x0执行b ResetHandler 程序从跳转到这里执行

;板子上电复位后 执行几个步骤这里通过标号在注释中加1，2，3....标示 标号表示执行顺序

;1.禁止看门狗 屏蔽所有中断

    ldr       r0,=WTCON     ;watch dog disable

    ldr       r1,=0x0        

    str       r1,[r0]                //WTCON=0000 0000 0000 0000b 第五位为0禁用看门狗定时器

    ldr       r0,=INTMSK

    ldr       r1,=0x07ffffff ;all interrupt disable

    str       r1,[r0]

    ;****************************************************

    ;*    Set clock control registers                   *

    ;****************************************************

;2.根据工作频率设置pll

;这里介绍一下计算公式

;Fpllo=(m*Fin)/(p*2^s)

;m=MDIV+8,p=PDIV+2,s=SDIV

;Fpllo必须大于20Mhz小于66Mhz

;Fpllo*2^s必须小于170Mhz

;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.s中

;#elif (MCLK==40000000)

;#define PLL_M (0x48)

;#define PLL_P (0x3)

;#define PLL_S (0x2)

;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2

;硬件使用晶振为10Mhz,即Fin=10Mhz

;Fpllo=80*10/5*2^2=40Mhz

    ldr   r0,=LOCKTIME   //锁时计数寄存器

    ldr   r1,=800       ; count = t_lock * Fin (t_lock=200us, Fin=4MHz) = 800

    str   r1,[r0]

    [ PLLONSTART

       ldr   r0,=PLLCON                ;temporary setting of PLL

       ldr   r1,=((M_DIV<<12)+(P_DIV<<4)+S_DIV) ;Fin=10MHz,Fout=40MHz

       str   r1,[r0]

    ]

    ldr       r0,=CLKCON //时钟控制寄存器各模块的钟控都打开  

    ldr       r1,=0x7ff8          ;All unit block CLK enable    

    str       r1,[r0]

    ;****************************************************

    ;*    Set memory control registers               *    

    ;****************************************************

;3.置存储相关寄存器的程序

;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序

;SMRDATA map在下面的程序中定义

;SMRDATA中涉及的值请参考memcfg.s程序

    ldr       r0,=SMRDATA   //设置源数据地址

    ldmia   r0,{r1-r13}   //进行批量加载13个字的数据

    ldr       r0,=0x01c80000 ;BWSCON Address   BWSCON 寄存器主要用来设置外接存储器的总线宽度和等待状态。

    stmia   r0,{r1-r13}

    ;****************************************************

    ;*    Initialize stacks                            *

    ;****************************************************

    ldr       sp, =SVCStack      ;管理模式的堆栈地址，当系统复位和软件中断响应时进入此模式

    bl         InitStacks

;5.设置缺省中断处理函数

    ;****************************************************

    ;*    Setup IRQ handler                       *

    ;****************************************************

    ldr       r0,=HandleIRQ              ;This routine is needed

    ldr       r1,=IsrIRQ                   ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c

    str       r1,[r0]

;6.将数据段拷贝到ram中 将零初始化数据段清零 跳入C语言的main函数执行 到这步结束bootloader初步引导结束

    ;********************************************************

    ;*    Copy and paste RW data/zero initialized data     *

    ;********************************************************

    LDR           r0, =|Image$$RO$$Limit|      ; Get pointer to ROM data

    LDR           r1, =|Image$$RW$$Base|      ; and RAM copy

    LDR           r3, =|Image$$ZI$$Base|

       ;Zero init base => top of initialised data

                    

    CMP           r0, r1          ; Check that they are different

    BEQ     %F1

0           

    CMP           r1, r3          ; Copy init data

    LDRCC   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4          

    STRCC   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4

    BCC     %B0

1           

    LDR           r1, =|Image$$ZI$$Limit| ; Top of zero init segment

    MOV          r2, #0

2           

    CMP           r3, r1          ; Zero init

    STRCC   r2, [r3], #4

    BCC     %B2

;程序实现了RW数据的拷贝和ZI区域的清零功能。其中引用到的4个符号是由链接器第一输出的。

    [ :LNOT:THUMBCODE

       BL   Main           ;Don't use main() because ......

       B     .                                        

    ]

    [ THUMBCODE                ;for start-up code for Thumb mode

       orr     lr,pc,#1

       bx      lr

       CODE16

       bl      Main     ;Don't use main() because ......

       b       .

       CODE32

    ]

;****************************************************

;*    The function for initializing stack 初始化各模式下的栈指针

    *

;****************************************************

InitStacks

       ;Don't use DRAM,such as stmfd,ldmfd......

       ;SVCstack is initialized before

       ;Under toolkit ver 2.50, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

    mrs     r0,cpsr   //读状态寄存器指令

    bic       r0,r0,#MODEMASK //将r0的后五位清零

    orr       r1,r0,#UNDEFMODE|NIONT     //r1=11011011b

    msr     cpsr_cxsf,r1          ;UndefMode     =msr cpsr,r1

    ldr       sp,=UndefStack

      

    orr       r1,r0,#ABORTMODE|NOINT

    msr     cpsr_cxsf,r1            ;AbortMode

    ldr       sp,=AbortStack

    orr       r1,r0,#IRQMODE|NOINT

    msr     cpsr_cxsf,r1            ;IRQMode

    ldr       sp,=IRQStack

      

    orr       r1,r0,#FIQMODE|NOINT

    msr     cpsr_cxsf,r1            ;FIQMode

    ldr       sp,=FIQStack

    bic       r0,r0,#MODEMASK|NOINT

    orr       r1,r0,#SVCMODE

    msr     cpsr_cxsf,r1            ;SVCMode

    ldr       sp,=SVCStack

       ;USER mode is not initialized.

    mov     pc,lr ;The LR register may be not valid for the mode changes.

;****************************************************

;*    The function for entering power down mode pwdn模式 *

;****************************************************

;void EnterPWDN(int CLKCON);

EnterPWDN

    mov     r2,r0               ;r0=CLKCON

    ldr       r0,=REFRESH             

    ldr       r3,[r0]

    mov     r1, r3

    orr       r1, r1, #0x400000   ;self-refresh enable 22位为1 打开自动刷新

    str       r1, [r0]

    nop     ;Wait until self-refresh is issued. May not be needed.

    nop     ;If the other bus master holds the bus, ...

    nop     ; mov r0, r0

    nop

    nop

    nop

    nop

;enter POWERDN mode

    ldr       r0,=CLKCON

    str       r2,[r0]

;wait until enter SL_IDLE,STOP mode and until wake-up

    mov     r0,#0xff

0   subs    r0,r0,#1    //所有的ARM数据处理指令可加s为后缀

    bne     %B0

;exit from DRAM/SDRAM self refresh mode.

    ldr       r0,=REFRESH

    str       r3,[r0]

    mov     pc,lr

    LTORG

;这是上面提到的对存储寄存器初始化的数据map

SMRDATA DATA

;*****************************************************************

;* Memory configuration has to be optimized for best performance *

;* The following parameter is not optimized.                     *

;*****************************************************************

;*** memory access cycle parameter strategy ***

; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock

; 2) The memory settings,here, are made the safe parameters even at 66Mhz.

; 3) FP-DRAM Parameters:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.

; 4) DRAM refresh rate is for 40Mhz.

;DCD（或DCDU）伪指令用于分配一片连续的字存储单元并用伪指令中指定的表达式初始化。其中，表达式可以为程序标号或数字表达式。DCD也可用“&”代替。

;用DCD分配的字存储单元是字对齐的，而用DCDU分配的字存储单元并不严格字对齐。

;一个字=4字节    

       DCD 0x11110090   ;Bank0=OM[1:0], Bank1~Bank7=16bit, bank2=8bit;

     DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))       ;GCS0

       DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))       ;GCS1

       DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))       ;GCS2

       DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))       ;GCS3

       DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))       ;GCS4

       DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))       ;GCS5

       DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6

       DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7

       DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)       ;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019

       DCD 0x16                           ;SCLK power mode, BANKSIZE 32M/32M

       DCD 0x20                    ;MRSR6 CL=2clk

       DCD 0x20                    ;MRSR7

       ALIGN

;下面是对ram区域map的定义

;AREA RamData, DATA, READWRITE

;这里定义了处理器工作于各模式的堆栈区在ram中map

       AREA RamData, DATA, READWRITE

       ^      (_ISR_STARTADDRESS-0x500)

;其中“^”就是MAP伪指令， 用于定义一个结构化的内存表的首地址，_ISR_STARTADDRESS这个标号是中断服务程序指针的内在表首地址，

;其后面用于存入所有中断服务程序的地址，因为ARM7地址为32位，所以每个指针都是4个字节，这个地址在其它地方有类似于_ISR_STARTADDRESS   EQU   0xc7fff00

;这样的定义（有可能在其它文件中，找找看，呵呵），其中0xc7fff00是根据你自己的空间而定的。

;(_ISR_STARTADDRESS-0x500)后面的是每种模式下的堆栈空间，因为其空间总和为0x500，所以要减去0x500。这些堆栈空间地址在初始化程序的堆栈设置中用到了。

                           

UserStack       #     256 ;c1(c7)ffa00

SVCStack       #     256 ;c1(c7)ffb00

UndefStack     #     256 ;c1(c7)ffc00   //地址转换

AbortStack     #     256 ;c1(c7)ffd00

IRQStack       #     256 ;c1(c7)ffe00

FIQStack       #     0     ;c1(c7)fff00

              ^      _ISR_STARTADDRESS

;这里将中断异常向量建立在sdram中

             

HandleReset    #     4

HandleUndef   #     4

。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。

HandleEINT1 #     4

HandleEINT0 #     4   ;0xc1(c7)fff84

              END