flash滑动窗口

fla例子: 

/**
 * ...
 * @author ...
 */

class CFSSlidableVector extends MovieClip
{
    var mChildArray:Array;
    var mChildNum:Number = 0;
    var mLastChildPosY:Number = 0;
    var mChildIntervalPercent:Number = 0.5;
    var mChildLastPosYmouse:Number = 0;
    var mChildFrameNum:Number = 0;
    var mFlySpeedY:Number = 0;
    var mFlyFrames:Number = 0;
    var mFlyDistance:Number = 0;
    var mIsFlying:Boolean = false;
    var mHeight:Number = 0;
    var mChildSlideDistance:Number = 0;
    var mChildListHeight:Number = 0;
    var mChildListStartPosY:Number = 0;
    var mChildListEndPosY:Number = 0;
    var mChildFlyTargetY:Number = 0;
    var mOnPressFunc = null;
    var mOnReleaseFunc = null;
    var mOnReleaseOutsideFunc = null;
    var mOnPressMoved:Boolean = true;
    var mChildStartPosY:Number = 0;
    var mIsValidPress:Boolean = false;

    public function CFSSlidableVector()
    {
        this.mChildArray = new Array();
        this.mHeight = this._height;
    }

    public function addOneChild(childName)
    {

        this.mChildNum = this.mChildNum + 1;
        var child = this.attachMovie(childName, ("" + this + "_" + childName + "_" + this.mChildNum), this.getNextHighestDepth());
        this.mChildArray.push(child);
        child._x = (this._width - child._width) / 2;
        if (this.mLastChildPosY == 0)
        {
            child._y = this.mChildIntervalPercent * child._height;
            child.mChildStartPosY = child._y;
            this.mLastChildPosY = child._y;
            this.mChildListStartPosY = child._y;
            this.mChildListHeight = child._height;
        }
        else
        {
            child._y = this.mLastChildPosY + (1 + this.mChildIntervalPercent) * child._height;
            child.mChildStartPosY = child._y;
            this.mLastChildPosY = child._y;
            this.mChildListHeight = this.mChildListHeight + child._height * (this.mChildIntervalPercent + 1);
        }
    }


    public function mcFly(distanceY, frames)
    {
        if( (distanceY == 0) || (frames == 0) )
        {
            return;
        }

        this.mFlyDistance = distanceY;
        this.mFlyFrames = frames;
        this.mFlySpeedY = distanceY / frames;
        this.mIsFlying = true;
        this.mChildFlyTargetY = this._y + this.mFlyDistance;

        this.onEnterFrame = function()
        {
            this.mFlyFrames = this.mFlyFrames - 1;
            this._y = this._y + this.mFlySpeedY;
            if (mFlyFrames <= 0)
            {
                this._y = this.mChildFlyTargetY;
                this.mChildFlyTargetY = 0;
                this.mIsFlying = false;
                this.onEnterFrame = null;
            }
        }
    }

    public function childSlide(distanceY, firstFrames, interval)
    {
        if (this.isAnyChildFlying() == true)
        {
            return;
        }

        if(distanceY == 0)
        {
            return;
        }
        this.mChildSlideDistance = this.mChildSlideDistance + distanceY;
        if (distanceY < 0)
        {
            for (var i = 0; i < this.mChildArray.length; i++)
            {
                this.mChildArray[i].mcFly(distanceY, firstFrames + i * interval);
            }
        }
        else
        {
            for (var i = this.mChildArray.length - 1; i >= 0; i--)
            {
                this.mChildArray[i].mcFly(distanceY, firstFrames + (this.mChildArray.length - 1 - i) * interval);
            }
        }
        this.mLastChildPosY = this.mLastChildPosY + distanceY;
    }

    public function childSlideNoCaculateSlideDistance(distanceY, firstFrames, interval)
    {
        if (this.isAnyChildFlying() == true)
        {
            return;
        }

        if(distanceY == 0)
        {
            return;
        }
        if (distanceY < 0)
        {
            for (var i = 0; i < this.mChildArray.length; i++)
            {
                this.mChildArray[i].mcFly(distanceY, firstFrames + i * interval);
            }
        }
        else
        {
            for (var i = this.mChildArray.length - 1; i >= 0; i--)
            {
                this.mChildArray[i].mcFly(distanceY, firstFrames + i * interval);
            }
        }

        this.mLastChildPosY = this.mLastChildPosY + distanceY;
    }

    public function allSlide(distanceY, parent_frames, interval)
    {
        var pre_height = this._height;
        this.mcFly(distanceY, parent_frames);
        this.childMoveNoCaculateSlideDistance(pre_height);
        this.childSlideNoCaculateSlideDistance(-pre_height, parent_frames + interval, interval);
    }

    public function isAnyChildFlying()
    {
        for (var i = 0; i < this.mChildArray.length; i++)
        {
            if (this.mChildArray[i].mIsFlying == true)
            {
                return true;
            }
        }

        return false;
    }

    public function childMoveNoCaculateSlideDistance(distance)
    {
        for (var i = 0; i < this.mChildArray.length; i++)
        {
            var c = this.mChildArray[i];
            c._y = c._y + distance;
        }
    }

    public function childMove(distance)
    {
        this.mChildSlideDistance = this.mChildSlideDistance + distance;
        for (var i = 0; i < this.mChildArray.length; i++)
        {
            var c = this.mChildArray[i];
            c._y = c._y + distance;
        }
    }

    public function fixChildPosY()
    {
        if ((this.mChildListHeight + this.mChildSlideDistance) <= 0)
        {
            this.childMove(this.mChildListStartPosY - (this.mChildListHeight + this.mChildSlideDistance));
        }
        if ((this.mChildListStartPosY + this.mChildSlideDistance) >= (this.mHeight - this.mChildListStartPosY))
        {
            this.childMove(this.mHeight - (this.mChildListStartPosY * 3 + this.mChildSlideDistance) );
        }
    }

    public function registerTouchEvent(name, func)
    {
        if (name == "onPress")
        {
            this.mOnPressFunc = func;
        }
        else if(name == "onRelease")
        {
            this.mOnReleaseFunc = func;
        }
        else if(name == "onReleaseOutside")
        {
            this.mOnReleaseOutsideFunc = func;
        }
    }

    public function setOnPressMoving()
    {
        this.onPress = function()
        {
            this.mIsValidPress = true;
            var d:Number = this.mChildStartPosY + this._ymouse + this._parent.mChildSlideDistance;
            trace("mChildStartPosY: " + this.mChildStartPosY + " _ymouse: " + this._ymouse + " mChildSlideDistance: " + this._parent.mChildSlideDistance);
            if (d < 0 || d > this._parent.mHeight)
            {

                this.mIsValidPress = false;
                return;
            }

            if (this._parent.isAnyChildFlying() == true)
            {
                return;
            }

            this.mChildLastPosYmouse = this._ymouse;
            this.mOnPressMoved = false;

            this.onEnterFrame = function()
            {
                if (this.mChildLastPosYmouse != this._ymouse)
                {
                    this.mOnPressMoved = true;
                }

                this._parent.childMove(this._ymouse - this.mChildLastPosYmouse);
                this._parent.fixChildPosY();

                this.mChildLastPosYmouse = this._ymouse;
            }
            if (this.mOnPressFunc != null)
            {
                this.mOnPressFunc();
            }
        }

        this.onRelease = function()
        {
            if (this.mIsValidPress != true)
            {
                return;
            }
            if (this._parent.isAnyChildFlying() == true)
            {
                return;
            }
            this._parent.fixChildPosY();
            this.onEnterFrame = null;

            if ((this.mOnReleaseFunc != null) && (this.mOnPressMoved == false))
            {
                this.mOnPressMoved = true;
                this.mOnReleaseFunc();
            }
        }

        this.onReleaseOutside = function()
        {
            if (this.mIsValidPress != true)
            {
                return;
            }
            if (this._parent.isAnyChildFlying() == true)
            {
                return;
            }
            this._parent.fixChildPosY();
            this.onEnterFrame = null;


            var distance = (this._ymouse - this.mChildLastPosYmouse) * 3;
            var frames = distance / this._height / 2;
            if (frames < 0)
            {
                frames = -frames;
            }
            frames = frames + 1;
            var interval;
            if (frames > 5)
            {
                interval = 3;
            }
            else
            {
                interval = 1;
            }

            if ((distance + this._parent.mChildListHeight + this._parent.mChildSlideDistance) <= 0)
            {
                distance = (this._parent.mChildListStartPosY - (this._parent.mChildListHeight + this._parent.mChildSlideDistance));
            }

            if ((distance + this._parent.mChildListStartPosY + this._parent.mChildSlideDistance) >= (this._parent.mHeight - this._parent.mChildListStartPosY))
            {
                distance = (this._parent.mHeight - (this._parent.mChildListStartPosY * 3 + this._parent.mChildSlideDistance) );
            }

            this._parent.childSlide(distance, frames, interval);
            if (this.mOnReleaseOutsideFunc != null)
            {
                this.mOnReleaseOutsideFunc();
            }
        }
    }

    public function setChildOnPressMoving()
    {
        var child;
        for (var i = 0; i < this.mChildArray.length; i++)
        {
            child = this.mChildArray[i];
            child.setOnPressMoving();
        }
    }

    /*public function unSetChildOnPressMoving()
    {
        for (var i = 0; i < this.mChildArray.length; i++)
        {
            var child = this.mChildArray[i];
            child.onPress = null;
            child.onRelease = null;
            child.onReleaseOutside = null;
        }
    }*/

}