uboot 1.16 总结，参考了许多网上资源

1、uboot.lds

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
;指定输出的格式，elf小端，32位
OUTPUT_ARCH(arm)
；指定输出文件是arm平台
ENTRY(_start)
；指定启始代码段为_start
;下面写的是链接，表示最终生成的elf格式，如何进行链接
SECTIONS
{
. = 0x00000000;开始地址

. = ALIGN(4);//4字节对齐
.text ://正文段，即指令代码，放在当前位置，即0x00000000位置
{
cpu/arm920t/start.o	(.text)//从目标文件start.o开始，即从汇编程序start.S开始
*(.text)//其他代码部分都放在此处，如board.o cpu.o等等，在他们中有相应的跳转指令，只要指定开始就可以了
//其他放在其后面，自己实现自动跳转。比如再编译c程序的时候,a.o b.o c.o最后生成a.out，只要指定开始就可以了
//就是默认的main开始，其他的自己实现跳转，不用管放在什么位置了。
}

. = ALIGN(4);//继续4字节对齐
.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }只读代码段

. = ALIGN(4);//继续4字节对齐
.data : { *(.data) }//数据段，RW可读写

. = ALIGN(4);//继续4字节对齐
.got : { *(.got) }//自定义got段

. = .;
__u_boot_cmd_start = .;//定义变量__u_boot_cmd_start为当前位置
.u_boot_cmd : { *(.u_boot_cmd) }//放置cmd
__u_boot_cmd_end = .;定义变量__u_boot_cmd_end

. = ALIGN(4);//继续4字节
__bss_start = .;//定义__bss_start变量，为当前位置，定义为当前位置是因为不知道编译出来到有多大放
//放到了那里，那么就等链接的时候自动生成并定义变量
.bss (NOLOAD) : { *(.bss) . = ALIGN(4); }//bss段，即未初始化变量段如数组，参数等
_end = .;//定义变量_end
}

2、start.s

#include <common.h>
#include <config.h>

/*
 *************************************************************************
 *
 * Jump vector table as in table 3.1 in [1]
 *
 *************************************************************************
 */


.globl _start//这里定义了一个符号，_start 其中.globl指示告诉编译器,_start这个符号要被链接器用到，
             //_start就像C语言的main函数一样，告诉链接器程序从这里入口
             //每个汇编都要提供一个_start符号并且用.globl声明，如果使用默认到链接器。
             //如果一个符号没有被.globl声明，就表示这个符号不会被连接器用到。即使int a;声明没有赋值
_start: b    reset  //符号具体含义的定义相当于对符号赋值 即a=....
    ldr    pc, _undefined_instruction
    ldr    pc, _software_interrupt
    ldr    pc, _prefetch_abort
    ldr    pc, _data_abort
    ldr    pc, _not_used
    ldr    pc, _irq
    ldr    pc, _fiq

_undefined_instruction:    .word undefined_instruction//前面的_undefined_instruction也是一个符号，没有
                                                   //globl声明不会被编译器用到。
                                                   //把undefined_instruction值按照16bit赋值给
                                                   //标号_undefined_instruction 即使int a=22;
_software_interrupt:    .word software_interrupt
_prefetch_abort:    .word prefetch_abort
_data_abort:        .word data_abort
_not_used:        .word not_used
_irq:            .word irq
_fiq:            .word fiq

    .balignl 16,0xdeadbeef


/*
 *************************************************************************
 *
 * Startup Code (called from the ARM reset exception vector)
 *
 * do important init only if we don't start from
 * relocate armboot to ram
 * setup stack
 * jump to second stage
 *
 *************************************************************************
 */

_TEXT_BASE:
    .word    TEXT_BASE//定义符号_TEXT_BASE值为TEXT_BASE

    .word _start

/*
 * These are defined in the board-specific linker script.
 */
.globl _bss_start
_bss_start:
    .word __bss_start//在lds中定义的开始赋值为_bss_start

.globl _bss_end//同上//定义_bss_end为lds中的_end
_bss_end:
    .word _end


//下面这里没有define
#ifdef CONFIG_USE_IRQ
/* IRQ stack memory (calculated at run-time) */
.globl IRQ_STACK_START
IRQ_STACK_START:
    .word    0x0badc0de

/* IRQ stack memory (calculated at run-time) */
.globl FIQ_STACK_START
FIQ_STACK_START:
    .word 0x0badc0de
#endif
//没有define


/*
 * the actual start code
 */

start_code:
    /*
     * set the cpu to SVC32 mode
     */
    mrs    r0, cpsr//cpsr到r0
    bic    r0, r0, #0x1f//
    orr    r0, r0, #0xd3//上面把r0的32位赋值成SVC32模式然后下面再赋值给cpsr，改变状态寄存器从而进入svc32
    msr    cpsr,r0

    bl coloured_LED_init//跳转到LED程序，这里可以删除，也可以进行点灯调试
    bl red_LED_on

#if    defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)
    /*
     * relocate exception table
     */
     //重新拷贝异常向量表，从_start开始的16个32位数据拷贝到0地址
    ldr    r0, =_start
    ldr    r1, =0x0
    mov    r2, #16
copyex:
    subs    r2, r2, #1
    ldr    r3, [r0], #4
    str    r3, [r1], #4// 拷贝然后地址+4 每个地址1个字节，4*8=32
    bne    copyex
#endif

#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
    /* turn off the watchdog */

# if defined(CONFIG_S3C2400)//定义寄存器地址
#  define pWTCON        0x15300000
#  define INTMSK        0x14400008    /* Interupt-Controller base addresses */
#  define CLKDIVN    0x14800014    /* clock divisor register */
#else
#  define pWTCON        0x53000000
#  define INTMSK        0x4A000008    /* Interupt-Controller base addresses */
#  define INTSUBMSK    0x4A00001C
#  define CLKDIVN    0x4C000014    /* clock divisor register */
# endif

    ldr     r0, =pWTCON  关闭看门狗
    mov     r1, #0x0
    str     r1, [r0]

    /*
     * mask all IRQs by setting all bits in the INTMR - default
     */
    mov    r1, #0xffffffff//这里关闭中断
    ldr    r0, =INTMSK
    str    r1, [r0]
# if defined(CONFIG_S3C2410)
    ldr    r1, =0x3ff
    ldr    r0, =INTSUBMSK
    str    r1, [r0]
# endif

    /* FCLK:HCLK:PCLK = 1:2:4 */
    /* default FCLK is 120 MHz ! */
    ldr    r0, =CLKDIVN
    mov    r1, #3
    str    r1, [r0]
#endif    /* CONFIG_S3C2400 || CONFIG_S3C2410 */

    /*
     * we do sys-critical inits only at reboot,
     * not when booting from
     */
#ifndef CONFIG_SKIP_LOWLEVEL_INIT//这里没有定义skip，跳转到cpu_init_crit
    bl    cpu_init_crit
#endif


//在lowlevel_init.S执行完后继续执行下面的代码





#ifndef CONFIG_SKIP_RELOCATE_UBOOT   //进行代码搬运
relocate:                /* relocate U-Boot to RAM        */
    adr    r0, _start        /* r0 <- current position of code   */   //adr取变脸地址，取_start地址。
    ldr    r1, _TEXT_BASE        /* test if we run from flash or RAM */
    cmp     r0, r1                  /* don't reloc during debug         */
    beq     stack_setup

    ldr    r2, _armboot_start            //计算代码段大小 从_bss_start - _armboot_start即_start  都在lds中定义
    ldr    r3, _bss_start
    sub    r2, r3, r2        /* r2 <- size of armboot            */  //然后从0地址拷贝这么大小的内容到_TEXT_BASE地址开始的空间中即内存
    add    r2, r0, r2        /* r2 <- source end address         */

copy_loop:
    ldmia     {r3-r10}        /* copy from source address [r0]    */
    stmia     {r3-r10}        /* copy to   target address [r1]    */
    cmp    r0, r2            /* until source end addreee [r2]    */
    ble    copy_loop
#endif    /* CONFIG_SKIP_RELOCATE_UBOOT */

    /* Set up the stack                            */
stack_setup:   //这里初始化堆栈，搬运代码完成后，初始化堆栈
    ldr    r0, _TEXT_BASE        /* upper 128 KiB: relocated uboot   */           //下面两个变量在Includes/config/smdk2410.h中有定义
    sub    r0, r0, #CONFIG_SYS_MALLOC_LEN    /* malloc area                      */   //堆空间定义的大小 malloc可分配空间大小
    sub    r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /* bdinfo                        */  //给内核传递参数的大小空间，初始化
#ifdef CONFIG_USE_IRQ//这里不使用快速中断  下面不用
    sub    r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
    sub    sp, r0, #12        /* leave 3 words for abort-stack    */  //从这里看出初始化堆栈时间上就是给定sp寄存器的值

clear_bss:
    ldr    r0, _bss_start        /* find start of bss segment        */  //清楚_bss_start段为0
    ldr    r1, _bss_end        /* stop here                        */
    mov    r2, #0x00000000        /* clear                            */

clbss_l:str    r2, [r0]        /* clear loop...                    */
    add    r0, r0, #4
    cmp    r0, r1
    ble    clbss_l

    ldr    pc, _start_armboot   //然后跳转到_start_armboot

_start_armboot:    .word start_armboot   //lib_arm中board.c 程序中开始执行start_armboot函数  即传说中的stage2


/*
 *************************************************************************
 *
 * CPU_init_critical registers
 *
 * setup important registers
 * setup memory timing
 *
 *************************************************************************
 */


#ifndef CONFIG_SKIP_LOWLEVEL_INIT  //初始化关键寄存器
cpu_init_crit:
    /*
     * flush v4 I/D caches
     */
    mov    r0, #0
    mcr    p15, 0, r0, c7, c7, 0    /* flush v3/v4 cache */
    mcr    p15, 0, r0, c8, c7, 0    /* flush v4 TLB */     //初始化cache和快表

    /*
     * disable MMU stuff and caches
     */                                           //关闭MMU全部使用物理地址
    mrc    p15, 0, r0, c1, c0, 0
    bic    r0, r0, #0x00002300    @ clear bits 13, 9:8 (--V- --RS)
    bic    r0, r0, #0x00000087    @ clear bits 7, 2:0 (B--- -CAM)
    orr    r0, r0, #0x00000002    @ set bit 2 (A) Align
    orr    r0, r0, #0x00001000    @ set bit 12 (I) I-Cache
    mcr    p15, 0, r0, c1, c0, 0

    /*
     * before relocating, we have to setup RAM timing
     * because memory timing is board-dependend, you will
     * find a lowlevel_init.S in your board directory.
     */
    mov    ip, lr

    bl    lowlevel_init   //跳转到board中的lowlevel_init.S中执行，进行SDARM的配置

    mov    lr, ip
    mov    pc, lr
#endif /* CONFIG_SKIP_LOWLEVEL_INIT */

/*
 *************************************************************************
 *
 * Interrupt handling
 *
 *************************************************************************
 */

@
@ IRQ stack frame.
@
#define S_FRAME_SIZE    72

#define S_OLD_R0    68
#define S_PSR        64
#define S_PC        60
#define S_LR        56
#define S_SP        52

#define S_IP        48
#define S_FP        44
#define S_R10        40
#define S_R9        36
#define S_R8        32
#define S_R7        28
#define S_R6        24
#define S_R5        20
#define S_R4        16
#define S_R3        12
#define S_R2        8
#define S_R1        4
#define S_R0        0

#define MODE_SVC 0x13
#define I_BIT     0x80

/*
 * use bad_save_user_regs for abort/prefetch/undef/swi ...
 * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 */

    .macro    bad_save_user_regs
    sub    sp, sp, #S_FRAME_SIZE
    stmia    sp, {r0 - r12}            @ Calling r0-r12
    ldr    r2, _armboot_start
    sub    r2, r2, #(CONFIG_STACKSIZE)
    sub    r2, r2, #(CONFIG_SYS_MALLOC_LEN)
    sub    r2, r2, #(CONFIG_SYS_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
    ldmia    r2, {r2 - r3}            @ get pc, cpsr
    add    r0, sp, #S_FRAME_SIZE        @ restore sp_SVC

    add    r5, sp, #S_SP
    mov    r1, lr
    stmia    r5, {r0 - r3}            @ save sp_SVC, lr_SVC, pc, cpsr
    mov    r0, sp
    .endm

    .macro    irq_save_user_regs
    sub    sp, sp, #S_FRAME_SIZE
    stmia    sp, {r0 - r12}            @ Calling r0-r12
    add     r7, sp, #S_PC
    stmdb   r7, {sp, lr}^                   @ Calling SP, LR
    str     lr, [r7, #0]                    @ Save calling PC
    mrs     r6, spsr
    str     r6, [r7, #4]                    @ Save CPSR
    str     r0, [r7, #8]                    @ Save OLD_R0
    mov    r0, sp
    .endm

    .macro    irq_restore_user_regs
    ldmia    sp, {r0 - lr}^            @ Calling r0 - lr
    mov    r0, r0
    ldr    lr, [sp, #S_PC]            @ Get PC
    add    sp, sp, #S_FRAME_SIZE
    subs    pc, lr, #4            @ return & move spsr_svc into cpsr
    .endm

    .macro get_bad_stack
    ldr    r13, _armboot_start        @ setup our mode stack
    sub    r13, r13, #(CONFIG_STACKSIZE)
    sub    r13, r13, #(CONFIG_SYS_MALLOC_LEN)
    sub    r13, r13, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack

    str    lr, [r13]            @ save caller lr / spsr
    mrs    lr, spsr
    str     lr, [r13, #4]

    mov    r13, #MODE_SVC            @ prepare SVC-Mode
    @ msr    spsr_c, r13
    msr    spsr, r13
    mov    lr, pc
    movs    pc, lr
    .endm

    .macro get_irq_stack            @ setup IRQ stack
    ldr    sp, IRQ_STACK_START
    .endm

    .macro get_fiq_stack            @ setup FIQ stack
    ldr    sp, FIQ_STACK_START
    .endm

/*
 * exception handlers
 */
    .align  5
undefined_instruction:
    get_bad_stack
    bad_save_user_regs
    bl    do_undefined_instruction

    .align    5
software_interrupt:
    get_bad_stack
    bad_save_user_regs
    bl    do_software_interrupt

    .align    5
prefetch_abort:
    get_bad_stack
    bad_save_user_regs
    bl    do_prefetch_abort

    .align    5
data_abort:
    get_bad_stack
    bad_save_user_regs
    bl    do_data_abort

    .align    5
not_used:
    get_bad_stack
    bad_save_user_regs
    bl    do_not_used

#ifdef CONFIG_USE_IRQ

    .align    5
irq:
    get_irq_stack
    irq_save_user_regs
    bl    do_irq
    irq_restore_user_regs

    .align    5
fiq:
    get_fiq_stack
    /* someone ought to write a more effiction fiq_save_user_regs */
    irq_save_user_regs
    bl    do_fiq
    irq_restore_user_regs

#else

    .align    5
irq:
    get_bad_stack
    bad_save_user_regs
    bl    do_irq

    .align    5
fiq:
    get_bad_stack
    bad_save_user_regs
    bl    do_fiq

#endif

3、board.c