Chinaunix首页 | 论坛 | 博客
  • 博客访问: 1354694
  • 博文数量: 239
  • 博客积分: 5909
  • 博客等级: 大校
  • 技术积分: 2715
  • 用 户 组: 普通用户
  • 注册时间: 2010-07-24 20:19
文章分类

全部博文(239)

文章存档

2014年(4)

2013年(22)

2012年(140)

2011年(14)

2010年(59)

我的朋友

分类: Oracle

2012-11-01 12:19:59


点击(此处)折叠或打开

  1. -- -----------------------------------------------------------------------------------

  2. -- Author : Tom Kyte

  3. -- Description : Displays free and unused space for the specified object.

  4. -- Call Syntax : EXEC Show_Space('Tablename');

  5. -- Requirements : SET SERVEROUTPUT ON

  6. -- Last Modified: June 22, 2010

  7. -- This enhance version has all the fixes for ASSM, LMT, partitions etc (Oracle version 10gr2 +)

  8. -- -----------------------------------------------------------------------------------

  9. set define off

  10. create or replace procedure show_space

  11. ( p_segname in varchar2,

  12.  p_owner in varchar2 default user,

  13.  p_type in varchar2 default 'TABLE',

  14.  p_partition in varchar2 default NULL )

  15. -- this procedure uses authid current user so it can query DBA_*

  16. -- views using privileges from a ROLE and so it can be installed

  17. -- once per database, instead of once per user that wanted to use it

  18. authid current_user

  19. as

  20.     l_free_blks number;

  21.     l_total_blocks number;

  22.     l_total_bytes number;

  23.     l_unused_blocks number;

  24.     l_unused_bytes number;

  25.     l_LastUsedExtFileId number;

  26.     l_LastUsedExtBlockId number;

  27.     l_LAST_USED_BLOCK number;

  28.     l_segment_space_mgmt varchar2(255);

  29.     l_unformatted_blocks number;

  30.     l_unformatted_bytes number;

  31.     l_fs1_blocks number; l_fs1_bytes number;

  32.     l_fs2_blocks number; l_fs2_bytes number;

  33.     l_fs3_blocks number; l_fs3_bytes number;

  34.     l_fs4_blocks number; l_fs4_bytes number;

  35.     l_full_blocks number; l_full_bytes number;

  36.     -- inline procedure to print out numbers nicely formatted

  37.     -- with a simple label

  38.     procedure p( p_label in varchar2, p_num in number )

  39.     is

  40.     begin

  41.        dbms_output.put_line( rpad(p_label,40,'.') ||

  42.                              to_char(p_num,'999,999,999,999') );

  43.     end;

  44. begin

  45.   -- this query is executed dynamically in order to allow this procedure

  46.   -- to be created by a user who has access to DBA_SEGMENTS/TABLESPACES

  47.   -- via a role as is customary.

  48.   -- NOTE: at runtime, the invoker MUST have access to these two

  49.   -- views!

  50.   -- this query determines if the object is a ASSM object or not

  51.   begin

  52.      execute immediate

  53.          'select ts.segment_space_management

  54.             from dba_segments seg, dba_tablespaces ts

  55.            where seg.segment_name = :p_segname

  56.              and (:p_partition is null or

  57.                  seg.partition_name = :p_partition)

  58.              and seg.owner = :p_owner

  59.              and seg.segment_type = :p_type

  60.              and seg.tablespace_name = ts.tablespace_name'

  61.             into l_segment_space_mgmt

  62.            using p_segname, p_partition, p_partition, p_owner, p_type;

  63.   exception

  64.       when too_many_rows then

  65.          dbms_output.put_line

  66.          ( 'This must be a partitioned table, use p_partition => ');

  67.          return;

  68.   end;

  69.   -- if the object is in an ASSM tablespace, we must use this API

  70.   -- call to get space information, else we use the FREE_BLOCKS

  71.   -- API for the user managed segments

  72.   if l_segment_space_mgmt = 'AUTO'

  73.   then

  74.     dbms_space.space_usage

  75.     ( p_owner, p_segname, p_type, l_unformatted_blocks,

  76.       l_unformatted_bytes, l_fs1_blocks, l_fs1_bytes,

  77.       l_fs2_blocks, l_fs2_bytes, l_fs3_blocks, l_fs3_bytes,

  78.       l_fs4_blocks, l_fs4_bytes, l_full_blocks, l_full_bytes, p_partition);

  79.     p( 'Unformatted Blocks ', l_unformatted_blocks );

  80.     p( 'FS1 Blocks (0-25) ', l_fs1_blocks );

  81.     p( 'FS2 Blocks (25-50) ', l_fs2_blocks );

  82.     p( 'FS3 Blocks (50-75) ', l_fs3_blocks );

  83.     p( 'FS4 Blocks (75-100)', l_fs4_blocks );

  84.     p( 'Full Blocks ', l_full_blocks );

  85.  else

  86.     dbms_space.free_blocks(

  87.       segment_owner => p_owner,

  88.       segment_name => p_segname,

  89.       segment_type => p_type,

  90.       freelist_group_id => 0,

  91.       free_blks => l_free_blks);

  92.     p( 'Free Blocks', l_free_blks );

  93.  end if;

  94.  -- and then the unused space API call to get the rest of the

  95.  -- information

  96.  dbms_space.unused_space

  97.  ( segment_owner => p_owner,

  98.     segment_name => p_segname,

  99.     segment_type => p_type,

  100.     partition_name => p_partition,

  101.     total_blocks => l_total_blocks,

  102.     total_bytes => l_total_bytes,

  103.     unused_blocks => l_unused_blocks,

  104.     unused_bytes => l_unused_bytes,

  105.     LAST_USED_EXTENT_FILE_ID => l_LastUsedExtFileId,

  106.     LAST_USED_EXTENT_BLOCK_ID => l_LastUsedExtBlockId,

  107.     LAST_USED_BLOCK => l_LAST_USED_BLOCK );

  108.     p( 'Total Blocks', l_total_blocks );

  109.     p( 'Total Bytes', l_total_bytes );

  110.     p( 'Total MBytes', trunc(l_total_bytes/1024/1024) );

  111.     p( 'Unused Blocks', l_unused_blocks );

  112.     p( 'Unused Bytes', l_unused_bytes );

  113.     p( 'Last Used Ext FileId', l_LastUsedExtFileId );

  114.     p( 'Last Used Ext BlockId', l_LastUsedExtBlockId );

  115.     p( 'Last Used Block', l_LAST_USED_BLOCK );

  116. end;

  117. /

  118. set define on

            When the table is in the same schema.

S             SET SERVEROUTPUT ON

   exec show_space ('EMP99')


             Example: When the table is in the different schema.

             SET SERVEROUTPUT ON

exec show_space ('EMP33' , 'MOID');

转自:
阅读(2135) | 评论(0) | 转发(0) |
给主人留下些什么吧!~~