u-boot-1.3.4源码分析(2)---start.S

 

#include

#include

 

#if defined(CONFIG_OMAP1610)

#include <./configs/omap1510.h>

#elif defined(CONFIG_OMAP730)

#include <./configs/omap730.h>

#endif

 

/*

 *************************************************************************

 *

 * Jump vector table as in table 3.1 in [1]

 *

 *************************************************************************

 */

 

 

.globl _start   @ 全局变量,_start是GNU汇编的默认入口标签

_start:       

       b     reset @复位向量，直接跳转到reset，并且不返回.以下的为向量表

       ldr   pc, _undefined_instruction

       ldr   pc, _software_interrupt

       ldr   pc, _prefetch_abort

       ldr   pc, _data_abort

       ldr   pc, _not_used

       ldr   pc, _irq

       ldr   pc, _fiq

 

_undefined_instruction:

       .word undefined_instruction @在_undefined_instruction标号处放置一个word型的值

_software_interrupt:

       .word software_interrupt

_prefetch_abort:

       .word prefetch_abort

_data_abort:

       .word data_abort

_not_used:

       .word not_used

_irq:

       .word irq

_fiq:

       .word fiq

 

       .balignl 16,0xdeadbeef @ 在以当前地址开始，在地址为16的倍数的位置的前面填入四个字节内容为0xdeadbeef;.balignl的最后一个字母l代表4字节对齐，因此地址就是16*4=64，而前面已经占了15*4=60个字节，故在地址60处开始填充0xdeadbeef

/*

 *************************************************************************

 *

 * Startup Code (reset vector)开始代码(复位向量)

 *

 * do important init only if we don't start from memory!

 * setup Memory and board specific bits prior to relocation.

 * relocate armboot to ram

 * setup stack

 *如果还没有从内存启动做一些重要的初始化，启动内存和重映射需要的板子上具体的位。重映射armboot到RAM，并初始化建立好栈

 *************************************************************************

 */

_TEXT_BASE:

       .word      TEXT_BASE   @ 本例中TEXT_BASE 的值为0x23f00000，用的是at91sam9263，SDRAM的地址是0x20000000—0x2fffffff,实际用的是64M的SDRAM。

 

.globl _armboot_start  @ 定义全局变量

_armboot_start:

       .word _start     @ 在标号_armboot_start处放置标号_start，这里_start为0，由u-boot.lds决定的

 

/*

 * These are defined in the board-specific linker script.

 */

.globl _bss_start      @ 声明_bss_start

_bss_start:

       .word __bss_start @ 在标号_bss_start 处放置标号__bss_start，这里的__bss_start也是由u-boot.lds决定的，值暂时未知

 

.globl _bss_end

_bss_end:

       .word _end    @ 在标号_bss_end处放置标号_end，这里的_end也是由u-boot.lds决定的，值暂时未知

 

 

#ifdef CONFIG_USE_IRQ 

/* IRQ stack memory (calculated at run-time) */

.globl IRQ_STACK_START

IRQ_STACK_START:

       .word      0x0badc0de @在IRQ_STACK_START处插入0x0badc0de

 

/* FIQ stack memory (calculated at run-time) */

.globl FIQ_STACK_START

FIQ_STACK_START:

       .word 0x0badc0de  @ 在FIQ_STACK_START处插入0x0badc0de

 

#endif

 

/*

 * the actual reset code 真正的复位代码

 */

reset:

       /*

        * set the cpu to SVC32 mode设置CPU到SVC32模式

        */

       mrs  r0,cpsr

       bic   r0,r0,#0x1f

       orr   r0,r0,#0xd3

       msr  cpsr,r0

 

       /*

        * we do sys-critical inits only at reboot,

        * not when booting from ram!

        */

#ifndef CONFIG_SKIP_LOWLEVEL_INIT

       bl    cpu_init_crit

/****************************************************

 如果没有定义CONFIG_SKIP_LOWLEVEL_INIT，则跳转到cpu_init_crit。本例中已经定义了CONFIG_SKIP_LOWLEVEL_INIT。这里顺便看看其代码，红色部分，不属于start.S

#ifndef CONFIG_SKIP_LOWLEVEL_INIT

.globl lowlevel_init

lowlevel_init:

        @ Clocks/SDRAM initialization is handled by at91bootstrap, no need to do it here...    

       mov pc, lr

       .ltorg

#endif @ CONFIG_SKIP_LOWLEVEL_INIT

@在at91sam系列芯片中，at91bootstrap已经初始化了时钟，SDRAM，因此这里不再需要初始化。直接返回

*************************************************/

#endif

 

#ifndef CONFIG_SKIP_RELOCATE_UBOOT 

@ 本例中at91sam系列芯片已经定义了CONFIG_SKIP_RELOCATE_UBOOT，在at91bootstrap就已经把程序从flash复制到ram里了，因此不需要再有这个重定位的过程，如三星的2410,2440就需要这个重定位过程。不过这里也分析下

relocate:                       /* relocate U-Boot to RAM       */

       adr   r0, _start        /* r0 <- current position of code*/ @得到当前代码的地址信息，已经拷贝到SDRAM里面了，所以 r0 = _start =  0x23f00000

       ldr   r1, _TEXT_BASE         /* test if we run from flash or RAM  */ @ r1 =  0x23f00000

       cmp     r0, r1                  /* don't reloc during debug         */

       beq     stack_setup

 

       ldr   r2, _armboot_start

       ldr   r3, _bss_start

       sub  r2, r3, r2        /* r2 <- size of armboot  */ @ 计算armboot的大小

       add  r2, r0, r2        /* r2 <- source end address */ @ 计算源代码结束地址

 

copy_loop:      @ 拷贝flash代码到RAM

       ldmia      r0!, {r3-r10}         /* copy from source address [r0]    */

       stmia       r1!, {r3-r10}         /* copy to   target address [r1]    */

       cmp r0, r2                    /* until source end addreee [r2]    */

       ble   copy_loop

#endif     /* CONFIG_SKIP_RELOCATE_UBOOT */

 

       /* Set up the stack  * / @ 建立堆栈

stack_setup:

       ldr   r0, _TEXT_BASE         /* upper 128 KiB: relocated uboot   */

       sub  r0, r0, #CFG_MALLOC_LEN      @ 向下内存分配，为malloc预留分配空间

       sub  r0, r0, #CFG_GBL_DATA_SIZE  @   预留初始化的数据的空间                      

#ifdef CONFIG_USE_IRQ  @ 如果定义了中断则还需要向下预留中断空间，本例中没有定义

       sub  r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)

#endif

       sub  sp, r0, #12             /* leave 3 words for abort-stack    */@ 预留3个字给溢出堆栈

@ 下面这段代码主要是为了初始化bss段为0

clear_bss:

       ldr   r0, _bss_start         /* find start of bss segment        */

       ldr   r1, _bss_end          /* stop here                        */

       mov r2, #0x00000000           /* clear                            */

 

clbss_l:str       r2, [r0]           /* clear loop...                    */

       add  r0, r0, #4

       cmp r0, r1

       ble   clbss_l

 

       bl coloured_LED_init @初始化led相关

       bl red_LED_on @红灯亮

 

       ldr   pc, _start_armboot @进入start_armboot

 

_start_armboot:

       .word start_armboot

 

至此，可以看下u-boot在SDRAM的内存分布图，地址从高往低，结合本例实际，相应地址都写上去了

bss段(0x23f2f900---0x23f44618)

u-boot程序(包括.text,.data等) (0x23f00000---0x23f2f900)

预留的堆(本例中预留的是512k)(0x23e80000---0x23efffff)

预留的全局变量结构体gd(本例中是128字节) (0x23e7ff80---0x237fffff)

预留的中断irq,fiq的栈(本例中没有预留)

预留的溢出栈(本例中是3个字) (0x23e7ff74---0x23e7ff7f)

用户栈区