keil startup 学习

在KEIL中,汇编是从ORG 000H开始启动,那么它在C51中是如何启动MAIN()函数的呢?实际上是C51中有一个启启动程序STARTUP.A51,它总是和C程序一起编译和链接的.

启动文件STARTUP.A51中包含目标板启动代码，可在每个project中加入这个文件，只要复位，则该文件立即执行，其功能包括：

z 定义内部RAM大小、外部RAM大小、可重入堆栈位置

z 清除内部、外部或者以此页为单元的外部存储器

z 按存储模式初使化重入堆栈及堆栈指针

z 初始化8051硬件堆栈指针

z 向main( )函数交权

开发人员可修改以下数据从而对系统初始化

常数名 意义

IDATALEN                  待清内部RAM长度

XDATA START           指定待清外部RAM起始地址

XDATALEN                 待清外部RAM长度

IBPSTACK                  是否小模式重入堆栈指针需初始化标志，1为需要。缺省为0

IBPSTACKTOP           指定小模式重入堆栈顶部地址

XBPSTACK                是否大模式重入堆栈指针需初始化标志，缺省为0

XBPSTACKTOP         指定大模式重入堆栈顶部地址

PBPSTACK                是否Compact重入堆栈指针，需初始化标志，缺省为0

PBPSTACKTOP         指定Compact模式重入堆栈顶部地址

PPAGEENABLE         P2初始化允许开关

PPAGE                      指定P2值

PDATASTART          待清外部RAM页首址

经常可能需要修改的地方:(红色)

XDATASTART EQU 0H ;                     the absolute start-address of XDATA memory

XDATALEN EQU 0H ;                          the length of XDATA memory in bytes.

XBPSTACK EQU 0 ;                            set to 1 if large reentrant is used.

XBPSTACKTOP EQU 0FFFFH+1;      set top of stack to highest location+1.

PPAGEENABLE EQU 0 ;                     set to 1 if pdata object are used.

PPAGE EQU 0 ;                                  define PPAGE number.

详解(转)

$NOMOD51;Ax51宏汇编器控制命令：告诉汇编器不使用预定义的寄存器名，因为汇编器内部定义了51的寄存器名，但在实际使用时会用51的扩展芯片例如52之类的，如果包含了52的头文件就会出现重复定义所以要先声明一下不适用汇编器内部定义的寄存器名

;------------------------------------------------------------------------------
; STARTUP.A51: 用户上电初始化程序
;------------------------------------------------------------------------------
;
; 用户定义需上电初始化的内存空间
;
; 使用以下EQU命令可定义在CPU复位时需用0进行初始化的内存空间
;
; ; IDATA 存储器的空间的绝对起始地址总是0.
IDATALEN EQU 80H ; 需用0进行初始化的IDATA存储器空间的字节数
;
XDATASTART EQU 0H ; XDATA存储器空间的绝对起始地址
XDATALEN EQU 0H ; 需用0进行初始化的XDATA存储器的空间字节数.
;
PDATASTART EQU 0H ; PDATA存储器的空间的绝对起始地址
PDATALEN EQU 0H ; 需用0进行初始化的PDATA存储器的空间字节数.
;
; 注意: IDATA 存储器的空间在物理上包括了8051单片机的DATA和BIT存储器空间.
; 听说至少要保证与C51编译器运行库有关的存储器的空间进行0初始化不知是否
;------------------------------------------------------------------------------
;
; 再入函数模拟初始化
;
; 以下用EQU指令定义了再入函数模拟堆栈指针的初始化
;
; 使用SMALL存储器模式时再入函数的堆栈空间.
IBPSTACK EQU 0 ; 使用SMALL存储器模式再入函数时将其设置成1.
IBPSTACKTOP EQU 0FFH+1 ; 将堆栈顶设置为最高地址+1.
;
; 使用LARGE存储器模式时再入函数的堆栈空间.
XBPSTACK EQU 0 ; 使用LARGE存储器模式再入函数时将其设置成1.
XBPSTACKTOP EQU 0FFFFH+1; 将堆栈顶设置为最高地址+1.
;
; 使用COMPACT存储器模式时再入函数的堆栈空间.
PBPSTACK EQU 0 ; 使用COMPACT存储器模式再入函数时将其设置成1.
PBPSTACKTOP EQU 0FFFFH+1; 将堆栈顶设置为最高地址+1.
;
;------------------------------------------------------------------------------
;
; 使用COMPACT存储器模式时64K字节XDATA存储器空间的分页定义
;
; 以下用EQU指令定义PDATA类型变量在XDATA存储器空间的页地址
; 使用EQU指令定义PFAGE时必须与L51连接定位器PDATA指令的控制参数一致
;
PPAGEENABLE EQU 0 ; 使用PDATA类型变量时将其设置成1.
PPAGE EQU 0 ; 定义页号.
;
;------------------------------------------------------------------------------
NAME ?C_STARTUP ; 模块名为?C_STAUTUP
?C_C51STARTUP SEGMENT CODE ; 代码
?STACK SEGMENT IDATA ; 堆栈
RSEG ?STACK ; 堆栈

DS 1
EXTRN CODE (?C_START) ; 程序开始地址
PUBLIC ?C_STARTUP
CSEG AT 0x8000 ; 定义用户程序的起始地址,用MON51仿真器时可能有用
?C_STARTUP: LJMP STARTUP1
RSEG ?C_C51STARTUP
STARTUP1:
;
; 初始化串口
MOV SCON,#40H
MOV TMOD,#20H
MOV TH1,#0fdH
SETB TR1
CLR TI

; 单片机上电IDATA内存清零如果不需要上电清零IDATA 可以注销IF到IFEDN之间的话句
; 或者修改IDTALEN的长度为了具有掉电保护功能不知IDTALEN多长为好
IF IDATALEN <> 0
MOV R0,#IDATALEN - 1
CLR A
IDATALOOP: MOV @R0,A
DJNZ R0,IDATALOOP
ENDIF
;
; 单片机上电XDATA内存清零如果不需要上电清零XDATA 可以注销IF到IFEDN之间的话句
; 或者修改XDATALEN的长度
IF XDATALEN <> 0
MOV DPTR,#XDATASTART
MOV R7,#LOW (XDATALEN)
IF (LOW (XDATALEN)) <> 0
MOV R6,#(HIGH (XDATALEN)) +1
ELSE
MOV R6,#HIGH (XDATALEN)
ENDIF
CLR A
XDATALOOP: MOVX @DPTR,A
INC DPTR
DJNZ R7,XDATALOOP
DJNZ R6,XDATALOOP
ENDIF
;
; 送PDATA存储器页面高位地址
IF PPAGEENABLE <> 0
MOV P2,#PPAGE
ENDIF
;
; 单片机上电PDATA内存清零如果不需要上电清零XDATA 可以注销IF到IFEDN之间的话句
; 或者修改PDATALEN的长度
IF PDATALEN <> 0
MOV R0,#PDATASTART
MOV R7,#LOW (PDATALEN)

CLR A
PDATALOOP: MOVX @R0,A
INC R0
DJNZ R7,PDATALOOP
ENDIF
;
; 设置使用SMALL存储器模式时再入函数的堆栈空间.
IF IBPSTACK <> 0
EXTRN DATA (?C_IBP)
MOV ?C_IBP,#LOW IBPSTACKTOP
ENDIF
;
; 设置使用LARGE存储器模式时再入函数的堆栈空间.
IF XBPSTACK <> 0
EXTRN DATA (?C_XBP)
MOV ?C_XBP,#HIGH XBPSTACKTOP
MOV ?C_XBP+1,#LOW XBPSTACKTOP
ENDIF
;
; 设置使用COMPACT存储器模式时再入函数的堆栈空间.
IF PBPSTACK <> 0
EXTRN DATA (?C_PBP)
MOV ?C_PBP,#LOW PBPSTACKTOP
ENDIF
;
; 设置堆栈的起始地址
MOV SP,#?STACK-1 ; 例如MOV SP,#4FH
;
; This code is required if you use L51_BANK.A51 with Banking Mode 4
; 如果你的程序使用了Mode 4 程序分组技术请启动下面的程序,不会吧你的程序超过64K 利害
; EXTRN CODE (?B_SWITCH0)
; CALL ?B_SWITCH0 ; init bank mechanism to code bank 0
; 程序从第一组bank 0 块开始执行
; 跳转到用户程序MAIN函数
LJMP ?C_START
END

 

====

http://blog.csdn.net/tianjueyiyi/article/details/5518475