转载的文章，自己稍微整理了一下。
一、adr和ldr的区别
两个都是伪指令：adr是小范围的地址读取伪指令，ldr是大范围的读取地址伪指令。
可实际上adr是将基于PC相对偏移的地址值或基于寄存器相对地址值读取的伪指令，而ldr用于加载32位立即数或一个地址到指定的寄存器中。如果在程序中想加载某个函数或者某个在链接时指定的地址时请使用adr，例如在lds中需要重定位的地址。而当加载32位的立即数或外部地址时请用ldr。
举例说明：
AREA test,CODE,READONLY
ENTRY
ldr r0,_start
adr r0,_start
ldr r0,=_start
nop
_start
nop
END
这段代码并无实际意义，只是为了方便说明。我们反汇编一下看看：
4: ldr r0,_start
0x00000000 E59F0008 LDR R0,[PC,#0x0008]
5: adr r0,_start
0x00000004 E28F0004 ADD R0,PC,#0x00000004
6: ldr r0,=_start
0x00000008 E59F0004 LDR R0,[PC,#0x0004]
7: nop
8:
9:
10: _start
0x0000000C E1A00000 NOP
11: nop
ldr r0, _start ;; 从内存地址_start 的地方把值读入。执行这个后，r0 = 0xe1a00000
adr r0, _start ;; 取得_start的地址到r0，但是请看反编译的结果，它是与位置无关的。其实取得的是相对的位置。
ldr r0, =_start ;; 这个是取得标号_start的绝对地址。这个绝对地址是在链接的时候确定的。看上去这只是一个指令，但是它要占用2个32位的空间，一条是指令，另一条
;; 是_start的数据（因为在编译的时候不能确定_start的值，这个地址要根据链接文件确定，所以只有在链接的时候，才能确定），而且也不能用mov指令来给r0赋
;; 一个32位的常量，所以需要多出一个空间存放。_start的真正数据，在这里就是0x0000000c。
因此可以看出，这个是绝对的寻址，不管这段代码在什么地方运行，它的结果都是r0 =0x0000000c。
二、ldr和adr在使用标号表达式作为操作数的区别
ARM汇编有ldr指令以及ldr、adr伪指令，他门都可以将标号表达式作为操作数，下面通过分析一段代码以及对应的反汇编结果来说明它们的区别。
ldr r0, _start
adr r0, _start
ldr r0, =_start
_start:
b _start
下面是反汇编的结果：
0x00000000: e59f0004 ldr r0, [pc, #4] ; 0xc
0x00000004: e28f0000 add r0, pc, #0 ; 0x0
0x00000008: e59f0000 ldr r0, [pc, #0] ; 0x10
0x0000000c: eafffffe b 0xc
0x00000010: 3000000c andcc r0, r0, ip ;注这条指令是不在上面指令中的任何一条
1．ldr r0, _start ：读取指定地址中的值
ldr在此是一条指令，把内存地址_start位置中的值读入r0。（_start为指针之意，读取指针的值）
在这里_start是一个标号（是一个相对程序的表达式），汇编程序计算相对于PC的偏移量，并生成相对于PC的前索引指令：ldr r0, [pc, #4]。执行指令后，r0 = 0xeafffffe。
可以在和_start标号的相对位置不变的情况下移动（也就是说整段代码从flash中拷贝到ram中依然可以正常运行）。
2．adr r0, _start ：将指定地址赋到r0中
ADR是小范围的地址读取伪指令。ADR指令将基于PC相对偏移的地址值读取到寄存器中。在汇编编译源程序时，ADR伪指令被编译器替换成一条合适的指令。通常，编译器用一条
ADD指令或SUB指令来实现该ADR伪指令的功能，若不能用一条指令实现，则产生错误，编译失败。
r0的值为（（标号_start 的地址与此指令的距离差）+（此指令的地址））。在此例中被汇编成：add r0, pc, #0。该代码可以在和标号相对位置不变的情况下移动（也就是说整段代码从flash中拷贝到ram中依然可以正常运行）；
假如这段代码在 0x30000000 运行，那么 adr r0, _start 得到 r0 = 0x3000000c；如果在地址 0 运行，就是 0x0000000c 了。
通过这一点可以判断程序在什么地方运行。U-boot中那段relocate代码就是通过adr实现判断当前程序是在RAM中还是flash中。
3．ldr r0, =_start ：将指定标号的值赋给r0
ldr在此是一条伪指令，_start（即：label-expr）是一个相对程序的或外部的表达式。汇编程序将相对程序的标号表达式
label-expr 的值放在一个文字池中，并生成一个相对程序的 LDR 指令来从文字池中装载该值，在此例中生成的指令为：ldr r0,
[pc, #0]，对应文字池中的地址以及值为：0x00000010: 3000000c。如果 label-expr
是一个外部表达式，或者未包含于当前段内，则汇编程序在目标文件中放置一个链接程序重定位命令。链接程序在链接时生成地址。
因此取得的是标号 _start 的绝对地址，这个绝对地址（运行地址）是在连接的时候确定的。它要占用 2 个 32bit
的空间，一条是指令，另一条是文字池中存放_start 的绝对地址。因此可以看出，不管这段代码将来在什么地方运行，它的结果都是 r0 =
0x3000000c。由于ldr r0,
=_start取得的是_start的绝对地址，这句代码可以在_start标号的绝对位置不变的情况下移动；如果使用寄存器pc在程序中可以实现绝对转
移。（1.绝对地址；2.标号对应的值）
举例：
GPFCON EQU 0x56000050
ldr r0,=GPFCON
GPFCON ：标号
0x56000050 ：标号的值
ldr的确是个复杂的指令，现总结一下:
首先要判断我们用的是ldr arm指令还是伪指令。 当我们用的是arm指令时，它的作用不是向寄存器里加载立即数，而是将某个地址里的内容加载到寄存器。而伪指令ldr的作用就是向寄存器里加载立即数。
（1） ldr伪指令
ldr伪指令的格式是 ldr Rn, =expr
其中，expr是要加载到Rn中的内容，一般可以是立即数或者label。
如果expr可以用8bit数据向右移偶数位得到，那么这条伪指令就被编译器翻译成mov指令。具体的移位情况可以去查阅资料。反之如果立即数很大，超过了12bit的表示范畴，那么就不能用一条mov指令了，毕竟arm指令最大只有32bit的空间可用（RISC的arm所有的指令长度是一致的，效率
较高，当然我们并不关心16bit的thumb指令）。如果不能用一条32bit的指令乘下来，那么就只能另辟蹊径了，新开一段缓冲，将立即数expr放
到里面，然后将其地址（暂时标记为addr）拿来使用：
ldr Rn, addr
xxx (xxx就是expr)
xxx
由于编译器一般来说新安排的存储这个立即数expr的缓冲的位置是在相应代码的附近（这个应该可以控制，好像是使用.ltorg伪指令）。我们从addr地址加载数据到Rn不就可以了。
（2）ldr arm 指令
就是将一个地址的内容加载到寄存器。不能用mov，因为arm里的mov只是在寄存器之间传输数据，不支持在寄出器和memory之间传递数据。因此就
出现了ldr/str指令。如ldr Rn,
addr，注意这里的addr的值也是有限制的。这个label应该距离当前指令的距离不超过4k。因为我们知道label在具体使用的时候应该是被翻译
成了相对偏移，如果这个label长度不超过12bit，那么就不应超过4k,我们可以这样做：
ldr pc, _start_armboot
_start_armboot: .word arm_startboot
这样label _start_armboot就在指令下方，因此肯定是合法的。
