Perl函数的hash参数与多态性(polymorphism)

函数的使我们可以用一个统一的接口来处理不同个数或类型的数据输入。很多语言支持这一概念，多是通过多态性原型的定义来实现的。而Perl可以让我们通过hash参数来实现函数的多态性，从而使函数在调用上更为灵活，且很大程度上降低了开发成本。这一能力是其他语言所不具备的。这是如何实现的呢？

我们知道，perl的hash可以视为一个大小为偶数的array。且在这一前提下的array可以与hash相互赋值。

%hash = @array;
@array = %hash;

我们可以通过这一特性使函数的参数结构为hash，使函数可以通过hash来调用参数。

下面举个小例子。一个函数greet()，它可以用多种语言打招呼。注意 my %param = @_; 即是array赋值予hash的操作。

sub greet
{
    my %param = @_;
    my $name = $param{name} ||= '';
    my $lang = $param{lang} ||= 'en';

    my %hi =
    (
        en => 'hi',
        fr => 'bonjour',
        ge => 'hallo',
        it => 'ciao',
        sp => 'hola',
    );

    if ( defined $hi{$lang} )
    {
        printf "%s %s\n", $hi{$lang}, $name;
    }
    else
    {
        print "don't know how to greet in this language\n";
    }
}

这样在调用greet()函数时我们可以在其参数的个数、默认值及输入顺序上随心所欲。对于没有定义的参数，函数会忽略不计，正常运行。

greet(); # hi
greet( name => 'tom' ); # hi tom
greet( lang => 'ge' );  # hallo
greet( name => 'dick', lang => 'it' );  # ciao dick
greet( lang => 'fr', name => 'harry' ); # bonjour harry
greet( junk => "doesn't matter" ); # hi

而具有hash参数的函数的优势不仅局限于此。假设我们为greet()增加了一个功能，调用时通过参数'greet'选择选择问候或道别。

sub greet
{
    my %param = @_;
    my $name = $param{name} ||= '';
    my $lang = $param{lang} ||= 'en';
    my $greet = $param{greet} ||= 'hi';

    my %hi =
    (
        en => 'hi',
        fr => 'bonjour',
        ge => 'hallo',
        it => 'ciao',
        sp => 'hola',
    );

    my %bye =
    (
        en => 'bye',
        fr => 'au revoir',
        ge => 'auf wiedersehen',
        it => 'arrivederci',
        sp => 'adios',
    );

    $greet = $greet eq 'hi' ? \%hi : \%bye;

    if ( defined $greet->{$lang} )
    {
        printf "%s %s\n", $greet->{$lang}, $name;
    }
    else
    {
        print "don't know how to greet in this language\n";
    }
}

由于参数'greet'的默认值是‘hi'，过去的调用方式完全不受影响。即增加了下述新功能的同时，上面调用greet()函数的代码也不需要改写。也就是说此函数在调用上具备自然的向后兼容性！

greet(); # hi
greet( name => 'tom' ); # hi tom
greet( lang => 'ge' );  # hallo
greet( name => 'dick', lang => 'it' );  # ciao dick
greet( lang => 'fr', name => 'harry' ); # bonjour harry
greet( junk => "doesn't matter" ); # hi

greet( greet => 'bye' ); # bye
greet( name => 'tom', greet => 'hi' ); # hi tom
greet( greet => 'bye', lang => 'ge' ); # auf wiedersehen
greet( name => 'dick', greet => 'bye',  lang => 'it' ); # arrivederci dick
greet( lang => 'fr', name => 'harry', greet => 'hi' ); # bonjour harry