在网上看了不少有关u-boot的文章,有的讲得也比较详细，但我按照上面的步骤移植到我的2410开发板总是有点小问题,所以我决定从头开始分析u-boot-1.1.4的源码,希望能对u-boot有个深入的了解,最后移植到我的开发板上.这里需要有点汇编和C基础,我在2410上写过最小启动代码,这个相信问题不大. 下面就从代码的入口地址u-boot-1.1.4\cpu\arm920t\start.s处开始分析:
.globl _start
_start: b reset
ldr pc, _undefined_instruction
ldr pc, _software_interrupt
ldr pc, _prefetch_abort
ldr pc, _data_abort
ldr pc, _not_used
ldr pc, _irq
ldr pc, _fiq
_undefined_instruction: .word undefined_instruction
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort: .word data_abort
_not_used: .word not_used
_irq: .word irq
_fiq: .word fiq
.balignl 16,0xdeadbeef
注:.globl相当ADS中的GLOBAL,.word相当于ADS中的DCD,指分配一个字的内存单元,其值为undefined_instruction等,.balignl应该是相当于ADS中的ALIGN(The ALIGN directive aligns the current location to a specified boundary by padding with zeroes.),意思是通过填充0来使当前位置满足一定的格式. 然后程序跳到reset处开始执行:
reset:
mrs r0,cpsr
bic r0,r0,#0x1f
orr r0,r0,#0xd3 /*屏蔽IRQ中断,FIQ中断,进入管理模式*/
msr cpsr,r0
#if defined(CONFIG_S3C2400)
# define pWTCON 0x15300000
# define INTMSK 0x14400008
# define CLKDIVN 0x14800014
#elif defined(CONFIG_S3C2410)
# define pWTCON 0x53000000 /*定义相关寄存器地址,因为这里没用到get 2410addr.inc,所以要自己定义*/
# define INTMSK 0x4A000008
# define INTSUBMSK 0x4A00001C
# define CLKDIVN 0x4C000014
#endif
#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
ldr r0, =pWTCON /*关闭看门狗*/
mov r1, #0x0
str r1, [r0]
mov r1, #0xffffffff /*屏蔽所有中断*/
ldr r0, =INTMSK
str r1, [r0]
# if defined(CONFIG_S3C2410)
ldr r1, =0x3ff /*屏蔽所有子中断*/
ldr r0, =INTSUBMSK
str r1, [r0]
# endif
ldr r0, =CLKDIVN /*设置FCLK:HCLK:PCLK = 1:2:4 */
mov r1, #3
str r1, [r0]
#endif /* CONFIG_S3C2400 || CONFIG_S3C2410 */
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
bl cpu_init_crit
#endif
下面就跳到cpu_init-crit,代码如下
cpu_init_crit:
mov r0, #0
mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */
设置cache,mmu等相关控制寄存器,其定义在S3C2410X USER'S MANUAL 1.2中546页可以查到,其中bit13为V bit:Base location of exception registers,0=Low addresses=0x0000 0000,1=High addresses=0xFFFF 0000,B bit为Big-endian/little-endian选择,bit1为Alignment fault enable,bit12为I bit,Instruction cache enable.
mrc p15, 0, r0, c1, c0, 0
bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)
bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)
orr r0, r0, #0x00000002 @ set bit 2 (A) Align
orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache
mcr p15, 0, r0, c1, c0, 0
然后保存PC地址,跳到lowlevel_init去初始化存储器控制寄存器,这里的lr为进入cpu_init_crit之前的PC地址,需要保存,等下用来返回.
mov ip, lr
bl lowlevel_init
mov lr, ip
mov pc, lr
接着进入到lowlevel_init,这里执行一个循环,相当于循环13次,把一个预先定义的一个表的值赋给从BWSCON开始的13个连续的寄存器.这些寄存器定义了bank1--bank7的控制设置,包括初始化sdram等,代码如下:
lowlevel_init:
ldr r0, =SMRDATA /*这里的ldr为直接地址跳转，是非位置无关代码,所以这里的SMRDATA为连接时地址,即在0x33f80000以上*/
ldr r1, _TEXT_BASE /*在u-boot-1.1.4\board\smdk2410\congfig.mk中定义了TEXT_BASE = 0x33F80000*/
sub r0, r0, r1 /*实际上前面的ldr指令如果用adr指令代码，这行可以不用*/
ldr r1, =BWSCON /* Bus Width Status Controller */
add r2, r0, #13*4
0:
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne 0b
/* everything is fine now */
mov pc, lr
.ltorg
/* the literal pools origin */
SMRDATA:
.word (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
.word ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))
.word ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))
.word ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))
.word ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))
.word ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))
.word ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))
.word ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))
.word ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))
.word ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
.word 0x32 /*这里有些参数是不准的，要根据实际板子的参数设置,虽然有时按这个设置也能正常工作*/
.word 0x30
.word 0x30
这里执行完以后,程序返回到cpu_init_crit的下一行开始执行,代码如下:
#ifndef CONFIG_SKIP_RELOCATE_UBOOT
relocate: /* relocate U-Boot to RAM */
adr r0, _start /*_start为当前代码的起始地址,即为rom的起始地址0*/
ldr r1, _TEXT_BASE /*_TEXT_BASE为代码段的连接起始地址*/
cmp r0, r1 /*如果两者相等，则为已经在ram中运行，不需要再拷贝*/
beq stack_setup
ldr r2, _armboot_start /*_armboot_start的定义是_armboot_start: .word _start,意思是说这个值在运行期间是不变的,而_start则运行在rom时与运行在ram时是不同的*/
ldr r3, _bss_start /*下面这里有一点点复杂,不过我可能已经看过N次,这里就不分析了*/
sub r2, r3, r2 /* r2 <- size of armboot */
add r2, r0, r2 /* r2 <- source end address */
copy_loop:
ldmia r0!, {r3-r10} /* copy from source address [r0] */
stmia r1!, {r3-r10} /* copy to target address [r1] */
cmp r0, r2 /* until source end addreee [r2] */
ble copy_loop
#endif /* CONFIG_SKIP_RELOCATE_UBOOT */
接下来进行堆栈初始化:
stack_setup:
ldr r0, _TEXT_BASE
sub r0, r0, #CFG_MALLOC_LEN /* malloc area */
sub r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo */
#ifdef CONFIG_USE_IRQ
sub r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
sub sp, r0, #12 /* leave 3 words for abort-stack */
clear_bss: /*将从_bss_start到_bss_end的bss段清0*/
ldr r0, _bss_start
ldr r1, _bss_end
mov r2, #0x00000000
clbss_l:str r2, [r0]
add r0, r0, #4
cmp r0, r1
ble clbss_l
越来越复杂,一开始尤其是搞不清u-boot在ram中的内存分布, 从这里看大概是这样:
_TEXT_BASE 0x33f80000
malloc area 0x33f80000-CFG_MALLOC_LEN
bdinfo 0x33f80000-CFG_MALLOC_LEN-CFG_GBL_DATA_SIZE
stack 0x33f80000-CFG_MALLOC_LEN-CFG_GBL_DATA_SIZE-CONFIG_STACKSIZE_IRQ-CONFIG_STACKSIZE_FIQ-abort-stack
到这里,汇编部分的启动代码就结束了,通过执行下面这条长跳转指令跳转到ram中执行C语言部分代码,ldr伪指令是位置相关的，即跳到连接时的地址.
ldr pc, _start_armboot
_start_armboot: .word start_armboot
