QJo.. Retrieve Journal APIs (PanelGroup,command)

QJo.. Retrieve Journal APIs (PanelGroup,command)

 

.*-----------------------------------------------------------------------**
.*
.*  Compile options:
.*
.*    CrtPnlGrp PnlGrp( CBX126H )
.*              SrcFile( QPNLSRC )
.*              SrcMbr( *PNLGRP )
.*
.*-----------------------------------------------------------------------**
:PNLGRP.
:IMPORT  NAME=DLTJRNRCV  PNLGRP=QHJOCMD.
:HELP NAME='MNGJRNRCV'.Manage Journal Receivers - Help
:P.
The Manage Journal Receivers (MNGJRNRCV) command is used to count or
delete the journal receivers matching the specified selection criteria.
:P.
:NT.
Currently attached receivers are not included in the processing
performed by this command.
:ENT.
:P.
:HP2.Restrictions&COLON.:EHP2.  *OBJOPR and some data authority other
than *EXECUTE is required to the specified journal and it's journal
receivers to retrieve the information.  Proper object authority is
required to delete a journal receiver.
:EHELP.
:HELP NAME='MNGJRNRCV/JRN'.Journal (JRN) - Help
:XH3.Journal (JRN)
:P.
Specifies the journal whose journal receivers are to be either counted
or deleted.
:P.
This is a required parameter.
:P.
:XH3.Library
:P.
The name of the journal can be qualified by one of the following
possible library values:
:P.
:PARML.
:PT.:PK DEF.*LIBL:EPK.
:PD.
All libraries in the job's library list are searched until the first
match is found.
:PT.:PK.*CURLIB:EPK.
:PD.
The current library for the job is searched.  If no library is
specified as the current library for the job, QGPL is used.
:PT.:PV.library-name:EPV.
:PD.
Specify the name of the library to be searched.
:EPARML.
:EHELP.
:HELP NAME='MNGJRNRCV/SAVDATE'.Journal receiver saved before (SAVDATE) - Help
:XH3.Journal receiver saved before (SAVDATE)
:P.
Specifies the earliest save date and time at which, or before which,
the journal receiver must have been saved in order to be selected.
Journal receivers saved after the specified date and time are not
included.  The date and time value are evaluated in conjunction,
meaning that journal receivers saved on the date specified will be
included, if the specified time criteria is met.
:P.
:NT.
The save date and time is only checked against journal receivers that
have a status of SAVED.  Journal receivers that were not previously
saved will therefore possibly still be included by the selection
process if all other selection criteria are met.  Specify
STATUS(*SAVED) if you want to ensure that only saved journal receivers
are selected.
:ENT.
:P.
The possible values are:
:P.
:PARML.
:PT.:PK DEF.*NOCHK:EPK.
:PD.
The journal receiver save date and time is not considered when the
specified selection criteria are evaluated.
:EPARML.
:XH3.Save date
:P.
The possible values are:
:P.
:PARML.
:PT.:PK.*CURRENT:EPK.
:PD.
The current date is used to evaluate the journal receiver save date.
:PT.:PV.save-date:EPV.
:PD.
Specify a date to use for journal receiver save date evaluation.
:EPARML.
:XH3.Save time
:P.
The possible values are:
:P.
:PARML.
:PT.:PK DEF.*CURRENT:EPK.
:PD.
The current time is used to select the journal receivers.
:PT.:PK.*BEGIN:EPK.
:PD.
The beginning of the day is used to select the journal receivers.
Journal receivers saved on the date specified in the save date
parameter will not be selected.
:PT.:PV.save-time:EPV.
:PD.
Specify a time to use for journal receiver selection.
:EPARML.
:EHELP.
:HELP NAME='MNGJRNRCV/DAYS'.Journal receiver retain days (DAYS) - Help
:XH3.Journal receiver retain days (DAYS)
:P.
Specifies the number of days to keep journal receivers online, after
they have been detached.  This criteria is evaluated independently of
the journal receiver save status.
:P.
The possible values are:
:P.
:PARML.
:PT.:PK DEF.*NONE:EPK.
:PD.
The journal receiver detach date is not evaluated during the selection
process.
:PT.:PV.journal-receiver-retain-days:EPV.
:PD.
Specify the minimum number of days to keep journal receivers online,
after they have been detached.
:EPARML.
:EHELP.
:HELP NAME='MNGJRNRCV/RETAIN'.Journal receivers to retain (RETAIN) - Help
:XH3.Journal receivers to retain (RETAIN)
:P.
Specifies the minimum number of journal receivers to keep online.  The
journal receivers are counted from the currently attached receiver and
backwards.
:P.
The possible values are:
:P.
:PARML.
:PT.:PK DEF.*NONE:EPK.
:PD.
The relative number of the journal receiver is not considered during
the selection process.
:PT.:PV.journal-receivers-to-retain:EPV.
:PD.
Specify the minimum number of journal receivers to keep online,
deleting the oldest receivers first.
:EPARML.
:EHELP.
:HELP NAME='MNGJRNRCV/STATUS'.Journal receiver status (STATUS) - Help
:XH3.Journal receiver status (STATUS)
:P.
Specifies the current journal receiver status that qualifies a journal
receiver to be selected.
:P.
The possible values are:
:P.
:PARML.
:PT.:PK DEF.*SAVED:EPK.
:PD.
Only journal receivers having a status of SAVED are selected.
:PT.:PK.*ONLINE:EPK.
:PD.
Only journal receivers having a status of ONLINE are selected.
:PT.:PK.*PARTIAL:EPK.
:PD.
Only journal receivers having a status of PARTIAL are selected.
:PT.:PK.*NONATTACH:EPK.
:PD.
Journal receivers having any status other than ATTACHED are selected.
:EPARML.
:EHELP.
:HELP NAME='MNGJRNRCV/OPTION'.Journal receiver option (OPTION) - Help
:XH3.Journal receiver option (OPTION)
:P.
Specifies what type of processing the selected journal receivers will
be subject to.
:P.
The possible values are:
:P.
:PARML.
:PT.:PK DEF.*VERIFY:EPK.
:PD.
The total number of journal receivers selected will be returned in the
completion message.  No further processing will occur.
:PT.:PK.*DELETE:EPK.
:PD.
The selected journal receivers will be deleted using the Delete Journal
Receiver (DLTJRNRCV) command.  All restrictions applying to the
:LINK PERFORM='DSPHELP DLTJRNRCV'.
DLTJRNRCV
:ELINK.
command are enforced during this process.  If the journal receiver
processing completes successfully, the total number of deleted journal
receivers will be returned in the completion message.
:EPARML.
:EHELP.
:HELP NAME='MNGJRNRCV/FORCE'.Force receiver deletion (FORCE) - Help
:XH3.Force receiver deletion (FORCE)
:P.
Specifies whether additional checking should not be done before a
journal receiver is deleted.
:P.
The possible values are:
:P.
:PARML.
:PT.:PK DEF.*NO:EPK.
:PD.
Additional checking is done prior to the deletion of a journal receiver,
and inquiry messages will, if necessary, be presented to the user.
:PT.:PK.*YES:EPK.
:PD.
Do not send inquiry messages.  Inquiry message CPA7025 is not presented
to the user, even if this receiver has not been fully saved (for
example, a save after the receiver was detached).
:P.
Also, inquiry message CPA705E is not presented to the user even
if the receiver is attached to a remote journal.  The delete
operation continues.
:EPARML.
:EHELP.
:EPNLGRP.


Command
/*-------------------------------------------------------------------*/
/*                                                                   */
/*  Compile options:                                                 */
/*                                                                   */
/*    CrtCmd Cmd( MNGJRNRCV )                                        */
/*           Pgm( CBX126 )                                           */
/*           SrcMbr( CBX126X )                                       */
/*           VldCkr( CBX126V )                                       */
/*           HlpPnlGrp( CBX126H )                                    */
/*           HlpId( *CMD )                                           */
/*                                                                   */
/*-------------------------------------------------------------------*/
             Cmd        Prompt( 'Manage Journal Receivers' )

             Parm       JRN           Q0001                          +
                        Min( 1 )                                     +
                        Prompt( 'Journal' )

             Parm       SAVDATE       E0001                          +
                        Dft( *NOCHK )                                +
                        SngVal(( *NOCHK 000000 ))                    +
                        Prompt( 'Journal receiver saved before' )

             Parm       DAYS          *Int2                          +
                        Range( 1  999 )                              +
                        Dft( *NONE )                                 +
                        SpcVal(( *NONE  -1 ))                        +
                        Prompt( 'Journal receiver retain days' )

             Parm       RETAIN        *Int2                          +
                        Range( 1  999 )                              +
                        Dft( *NONE )                                 +
                        SpcVal(( *NONE  -1 ))                        +
                        Prompt( 'Journal receivers to retain' )

             Parm       STATUS        *Char    3                     +
                        Rstd( *YES )                                 +
                        Dft( *SAVED )                                +
                        SpcVal(( *SAVED     SAV )                    +
                               ( *ONLINE    ONL )                    +
                               ( *PARTIAL   PTL )                    +
                               ( *NONATTACH NAT ))                   +
                        Prompt( 'Journal receiver status' )

             Parm       OPTION        *Char    3                     +
                        Rstd( *YES )                                 +
                        Dft( *VERIFY )                               +
                        SpcVal(( *VERIFY  VFY )                      +
                               ( *DELETE  DLT ))                     +
                        Prompt( 'Journal receiver option' )

             Parm       FORCE         *Char    3                     +
                        Rstd( *YES )                                 +
                        Dft( *NO )                                   +
                        SpcVal(( *NO   NO  )                         +
                               ( *YES  YES ))                        +
                        PmtCtl( PMTDLTRCV )                          +
                        Prompt( 'Force receiver deletion' )


Q0001:      Qual                   *Name                            +
                        Expr( *YES )

             Qual                   *Name                            +
                        Dft( *LIBL )                                 +
                        SpcVal(( *LIBL ) ( *CURLIB ))                +
                        Expr( *YES )                                 +
                        Prompt( 'Library' )

E0001:      Elem                     *Date                          +
                        SpcVal(( *CURRENT 000001 ))                  +
                        Expr( *YES )                                 +
                        Prompt( 'Save date' )

             Elem                     *Time                          +
                        SpcVal(( *BEGIN   000000 )                   +
                               ( *CURRENT 000001 ))                  +
                        Dft( *CURRENT )                              +
                        Expr( *YES )                                 +
                        Prompt( 'Save time' )


PmtDltRcv:  PmtCtl     Ctl( OPTION )                                +
                        Cond(( *EQ DLT ))

             Dep        Ctl( &OPTION *EQ 'VFY' )                     +
                        Parm(( FORCE ))                              +
                        NbrTrue( *EQ 0 )