spool file编辑命令

DDS(SPLFDB)

A          R SPLFDBR              
A            REC          220O

编译的时用一下命令：

CRTPF FILE(YOURLIB/SPLFDB) SRCFILE(YOURLIB/QDDSSRC) SRCMBR(SPLFDB) MBR(*NONE）

    

CMD(EDTS):

             CMD        PROMPT('スプールファイル編集コマンド')
             PARM       KWD(FILE) TYPE(*CHAR) LEN(10) MIN(1) +
                          PROMPT('スプールファイル名')
             PARM       KWD(MBR) TYPE(*CHAR) LEN(10) MIN(1) +
                          PROMPT('メンバー')
             PARM       KWD(JOB) TYPE(*CHAR) LEN(10) RSTD(*YES) +
                          DFT(*) VALUES('名前' *) +
                          PROMPT('ジョブ名')
             PARM       KWD(USR) TYPE(*CHAR) LEN(10) RSTD(*YES) +
                          VALUES('名前') PROMPT('　ユーザー')
             PARM       KWD(NBR) TYPE(*CHAR) LEN(6) RSTD(*NO) +
                          RANGE(000000 999999) PROMPT('　番号')

CL(EDTSPLF):

/********************************************************************/
/*   プログラムＩＤ :  EDTSPLF                                    */
/*   更新履歴                                                     */
/*      ID  更新日付  更新者        更新内容                  */
/*     #01  1994/XX/XX  XXXXXXXXXXXXX   XXXXXXXXXXXXXXXXXXXXXXXX    */
/*                                                                  */
/********************************************************************/
             PGM        PARM(&FILE &MBR &JOB &USR &NBR)

             DCL        VAR(&FILE) TYPE(*CHAR) LEN(10)
             DCL        VAR(&JOB) TYPE(*CHAR) LEN(10)
             DCL        VAR(&USR) TYPE(*CHAR) LEN(10)
             DCL        VAR(&NBR) TYPE(*CHAR) LEN(6)
             DCL        VAR(&MBR) TYPE(*CHAR) LEN(10)
             DCL        VAR(&BLANK) TYPE(*CHAR) LEN(10)
             IF         COND(&FILE *EQ &BLANK) THEN(GOTO CMDLBL(END))

             IF         COND(&JOB *EQ '*') THEN(DO)
             RTVJOBA    JOB(&JOB) USER(&USR) NBR(&NBR)
             ENDDO

             CHKOBJ     OBJ(AHPSLIB/SPLFDB) OBJTYPE(*FILE) MBR(&MBR)
             MONMSG     MSGID(CPF9815 CPF0001 CPF9801) EXEC(DO)
             ADDPFM     FILE(AHPSLIB/SPLFDB) MBR(&MBR)
             ENDDO

             CPYSPLF    FILE(&FILE) TOFILE(SPLFDB) +
                          JOB(&NBR/&USR/&JOB) SPLNBR(*LAST) +
                          TOMBR(&MBR) CTLCHAR(*FCFC)
             OVRDBF     FILE(SPLFDB) TOFILE(*LIBL/SPLFDB) MBR(&MBR)
             CALL       PGM(EDTSPLFR)
             CPYF       FROMFILE(SPLFDB) TOFILE(SPLSRC) +
                          FROMMBR(&MBR) TOMBR(*FROMMBR) +
                          MBROPT(*REPLACE) FMTOPT(*CVTSRC)

             STRSEU     SRCFILE(*LIBL/SPLSRC) SRCMBR(&MBR)

             CPYF       FROMFILE(SPLSRC) TOFILE(SPLFDB) +
                          FROMMBR(&MBR) TOMBR(*FROMMBR) +
                          MBROPT(*REPLACE) FMTOPT(*CVTSRC)

             OVRPRTF    FILE(QPRINT) TOFILE(QPRINT) DEV(*JOB) +
                          DEVTYPE(*SCS) PAGESIZE(66 132) LPI(6) +
                          CPI(10) OVRFLW(65) CTLCHAR(*FCFC) HOLD(*YES)

             CPYF       FROMFILE(SPLFDB) TOFILE(QPRINT) FROMMBR(&MBR)

             DLTOVR     FILE(QPRINT)
END:
             ENDPGM

RPG(EDTSPLFR)

     FSPLFDB  UF  E           K        DISK
     I            DS
     I                                        1 220 WREC
     I                                        1   1 WCHR
     I                                        2   2 WBLK
     I                                        3 220 WRE2
     C                     READ SPLFDB                   30
     C           *IN30     DOWEQ'0'
     C                     MOVELREC       WREC
     C           WCHR      CAT  WRE2      REC
     C                     UPDATSPLFDBR
     C                     READ SPLFDB                   30
     C                     ENDDO
     C                     MOVEL'1'       *INLR
     C                     RETRN
     C*