Create and manage LOB segments

LOB字段有：CLOB, NCLOB, BLOB，现在ORACLE已经不支持LONG字段了。
 
一张包含lob字段的表：
 
CREATE TABLE lob_test
(id       NUMBER(10)
,name     varchar2(20)
,text     CLOB
,context  BLOB
)
LOB (text)
STORE AS
text_clob
(TABLESPACE ldytbs
ENABLE STORAGE IN ROW
CHUNK 8192
PCTVERSION 10
CACHE
)
LOB (context)
STORE AS
context_blob
(TABLESPACE users
disable STORAGE IN ROW
CHUNK 16384
NOCACHE
NOLOGGING
RETENTION
);
 
STORAGE IN ROW子句：
默认是"ENABLE STORAGE IN ROW"，表示当lob数据小于4000byte时(actual maximum in-line LOB is 3964 bytes)将lob数据和其他字段，一起存储在表段里面；当lob数据大于4000byte的时候，将lob数据存储在lob data segment中，仅仅在表段里面存储指向Lob Index的Lob Locator。
当指定"DISABLE STOREGE IN ROW"的时候，不管LOB 数据大小，都将lob数据存储在lob data segment中，仅仅在表段里面存储指向Lob Index的Lob Locator。
 
CHUNK
lob数据存储在LOB data segment的Chunk里面，CHUNK大小必须是数据库block_size的整数倍
Oracle为每条非空lob 记录分配至少一个Chunk,且该Chunk为该条lob 记录专用，不能被其他的LOB记录共享使用。所以CHUNK的大小需要考虑适合lob字段存储内容的大小，设置得太大，浪费空间，设置太小，chunk的数量太多，引发过多的IO。
 
PCTVERSION和RETENTION
这2个参数与lob数据的一致读有关
当LOB段被更新的时候，Oracle会分配额外的新Chunk保留更新的数据，而不是在old image chunk上直接修改，回滚和一致读的时候就可以使用到old image chunk。
PCTVERSION设置了一个百分比，当lob字段被更新时不会覆盖原有的空间，只有当超过这个百分比时才会。
RETENTION设置了与UNDO_RETENTION相同的值，增长了lob旧数据的保留时间。
手动管理UNDO表空间的数据库中，默认使用PCTVERSION 10，自动管理UNDO表空间的数据库中，默认使用RETENTION，2个参数不能同时使用。
 
CACHE/NOCACHE
该选项只针对Out Row Lob 段有影响。IN ROW LOB会随着Data Block而被缓存到DB Buffer Cache中。lob index segment同in row lob一样，会被缓存到buffer cache中。
 
LOGGNG/NOLOGGING
该参数只有在NOCACHE环境下且对OUT ROW LOB才有效(updates to in-line LOBS are still logged as normal).
如果OUT ROW LOB设置为NOCACHE NOLOGGING ，则对LOB DATA SEGMENT做dml操作将不产生redo logs.
当对LOB进行批量操作的时候，如用SQL*LOADER批量装载LOB则可以使用NOLOGGING加快操作。
 
 
BLOB字段存放的是二进制的内容。如果用BLOB字段存放文件，例如word文档，图片等，需要存入或读取，可以采用以下这种方式：
 
建立一张包含blob字段的表，并且建立目录。
create table bfile_tab (id number,fname BFILE,bcontext BLOB);
create or replace directory dir1 as 'E:\oracle\dir1';
create or replace directory dir2 as 'E:\oracle\dir2';
 
将文件写入blob字段：
declare
   a_blob  BLOB;
   a_bfile BFILE := BFILENAME('DIR1','blob字段测试.docx');
 begin
   insert into bfile_tab values (1,a_bfile,empty_blob())
   returning fname,bcontext into a_bfile,a_blob;
   dbms_lob.fileopen(a_bfile);
   dbms_lob.loadfromfile(a_blob, a_bfile, dbms_lob.getlength(a_bfile));
   dbms_lob.fileclose(a_bfile);
   commit;
 end;
/
 
用以下这种方法可以获取blob字段的长度：
select dbms_lob.getlength(bcontext) from bfile_tab;
 
将blob字段内容写到操作系统上：
declare
l_file UTL_FILE.FILE_TYPE;
l_buffer RAW(32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER := 1;
l_blob BLOB;
l_blob_len INTEGER;
BEGIN
  SELECT bcontext INTO l_blob from bfile_tab WHERE id=1;
  l_blob_len := DBMS_LOB.GETLENGTH(l_blob);
  l_file := UTL_FILE.FOPEN('DIR2','blob字段测试.docx','wb', 32767);
  WHILE l_pos < l_blob_len LOOP
  DBMS_LOB.READ (l_blob, l_amount, l_pos, l_buffer);
  UTL_FILE.PUT_RAW(l_file, l_buffer, TRUE);
  l_pos := l_pos+l_amount;
  END LOOP;
  UTL_FILE.FCLOSE(l_file);
END;
/