;=========================================
; NAME: 2410INIT.S
; DESC: C start up codes
; Configure memory, ISR ,stacks
; Initialize C-variables
; HISTORY:
; 2002.02.25:kwtark: ver 0.0
; 2002.03.20:purnnamu: Add some functions for testing STOP,POWER_OFF mode
; 2002.04.10:SJS:sub interrupt disable 0x3ff -> 0x7ff
;=========================================
;GET类似于C语言的include，
;option.inc文件内定义了一些全局变量，
;memcfg.inc文件内定义了关于内存bank的符号和数字常量，
;2440addr.inc文件内定义了用于汇编的s3c2440寄存器变量和地址
GET option.s ; 相当于inclue， 包含汇编文件
GET memcfg.s
GET 2410addr.s
;SDRAM自刷新位，把寄存器REFRESH的第22位处置1
BIT_SELFREFRESH EQU (1<<22)
;CPSR中的低5位定义了处理器的七种工作模式，为以后切换模式时使用
;Pre-defined constants
USERMODE EQU 0x10 ; 预定义一下各种工作模式
FIQMODE EQU 0x11
IRQMODE EQU 0x12
SVCMODE EQU 0x13
ABORTMODE EQU 0x17
UNDEFMODE EQU 0x1b
MODEMASK EQU 0x1f
NOINT EQU 0xc0 ;CPSR中的I位和F位置1，表示禁止任何中断
;The location of stacks
;定义了7种处理器模式下的栈的起始地址，其中用户模式和系统模式共有一个栈空间
;定义了一下堆栈的地址我只用的开发板SDRAM中堆栈的地址范围是0x33ff4800~0x33ff7fff
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~
;ARM有两种工作状态16位的Thumb和32位的Arm，编译器有相对应的16位和32位两种编译方式。16位环境使用tasm.exe编译。[|]相当于C语言中的IF ELSE ENDIF
;Check if tasm.exe(armasm -16 1.0) is used.
GBLL THUMBCODE ; 声明一个全局逻辑变量
[ {CONFIG} = 16 ; if CONFIG == 16
THUMBCODE SETL {TRUE} ; SETL伪操作给一个全局或局部变量赋值,THUMBCODE = TRUE
CODE32 ; CODE32告诉我们下面是32位的arm指令, 指示编译器为ARM指令
| ; else
THUMBCODE SETL {FALSE} ; THUMBCODE = FALSE
]
;/*******************************************************************
;下面是一个宏，用来实现子程序返回的。也就是将LR(子程序链接寄存器)的内容放入PC中。
;如果是THUMBCODE为真，那么bx lr。也就是跳转到lr所指向的位置执行。bx可以用来进行工作状态的切换。
; 宏定义，在后面出现MOV_PC_LR时，这个宏会被自动展开
; 该宏的作用是跳出子程序，返回被调用处
;*******************************************************************/
MACRO
MOV_PC_LR
[ THUMBCODE
bx lr
|
mov pc,lr
]
MEND
; 该宏定义的作用是有条件地（当Z=1时）跳出子程序，返回被调用处
MACRO
MOVEQ_PC_LR
[ THUMBCODE
bxeq lr
|
moveq pc,lr
]
MEND
;/*******************************************************************
;这个宏用来把HandlerLabel这个地址标号和HandleLabel这个地址标号绑定在一起。
;注意前面比后面多了一个r。在后面可以看到这样的指令 b HandlerUndef ；
;这是硬件自动产生的中断向量表，也是第一级中断向量表。比如产生了一个ENT0中断，
;如果在矢量模式下，首先是跳转b HandlerIRQ，然后就是这个宏，进入HandleIRQ，
;可是到底是那个中断呢，在HandleIRQ这个位置，硬件会自动产生跳转到中断处理程序的指令，
;也就是说是哪个中断源由硬件自己判断，并将跳转指令自动送过来。如果是非矢量模式，
;首先跳转到b b HandlerIRQ，然后宏展开，跳转到HandleIRQ的位置，HandleIRQ里存放的是IsrIRQ，
;IsrIRQ用于找到是哪一个中断源，并定位它在中断向量表中的位置。
;这个中断向量表在SDRAM的0x33ffff00 ~ 0x33ffffff，共256个字节，一个中断向量占4个字节，
;即一个字，所以这个位置可以存放64个中断源。2440只能有60个中断源。这个位置也是SDRAM最后的地址。我的SDRAM是64M，从0x30000000~0x34000000。
;*******************************************************************/
;还要了解下ARM的堆栈：arm堆栈的组织结构是 满栈降 (fd)的形式，满栈即sp是要停留在最后一个进栈元素，
;降：就是堆栈的增长方向是从高地址向低地址发展。arm对于堆栈的操作一般采用 LDMFD（pop）和STMFD （push) 两个命令。
;该宏定义是把中断服务程序的首地址装载到pc中
;在后面当遇到HandlerXXX HANDLER HandleXXX时，该宏被展开
;注意：HANDLER前的符号HandlerXXX比其后的符号HandleXXX多了一个r
;HandlerXXX为ARM体系中统一定义的几种异常中断
;HandleXXX为每个ARM处理器各自定义的中断，见该文件最后部分的中断向量表
MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
;ATPCS规定数据栈为FD类型
;即栈指针指向栈顶元素，数据栈向内存地址减小的方向增长
;该语句是使栈地址减小4个字节，以留出空间装载中断服务函数首地址
sub sp,sp,#4 ;decrement sp(to store jump address)减少sp(用于存放转跳地址)
;由于要利用r0寄存器来传递数据，所以要保存r0数据，使其入栈
stmfd sp!,{r0} ;PUSH the work register to stack(lr does't push because it return to original address)把工作寄存器压入栈(lr does not push because it return to original address)
; 把HandleXXX的地址装到r0
ldr r0,=$HandleLabel;load the address of HandleXXX to r0 将HandleXXX的址址放入r0
; 装载中断服务函数的起始地址
ldr r0,[r0] ;load the contents(service routine start address) of HandleXXX 把HandleXXX所指向的内容(也就是中断程序的入口)放入r0
; 中断函数首地址入栈
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack 把中断服务程序(ISR)压入栈
;将事先保存的r0数据和中断函数首地址出栈
;并使系统跳转到相应的中断处理函数
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR) 用出栈的方式恢复r0的原值和为pc设定新值(也就完成了到ISR的转跳)
MEND
;这些符号是ADS生成的，是根据我们填的RO，RW，ZI生成的。IMPORT伪操作是导入别的文件生命的变量
;导入连接器事先定义好的运行域中三个段变量
;ARM的可执行映像文件由RO、RW、ZI三个段组成
;RO为代码段，RW为已初始化的全局变量，ZI为未初始化的全局变量
IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)
IMPORT |Image$$RW$$Base| ; Base of RAM to initialise
IMPORT |Image$$ZI$$Base| ; Base and limit of area
IMPORT |Image$$ZI$$Limit| ; to zero initialise
; 导入Main，它为C语言程序入口函数
IMPORT Main ; The main entry of mon program
;定义代码段，名为Init
AREA Init,CODE,READONLY
ENTRY
;1)The code, which converts to Big-endian, should be in little endian code.
;2)The following little endian code will be compiled in Big-Endian mode.
; The code byte order should be changed as the memory bus width.
;3)The pseudo instruction,DCD can't be used here because the linker generates error.
;/*******************************************************************
;是否进行大小端切换。ASSERT断言错误伪操作，如果表达式为假就报错，这里如果未定义ENDIAN_CHANGE就报错，
;如果ENDIAN_CHANGE为true，如果未定义ENTRY_BUS_WIDTH，就报错。根据不同的总线宽度32，16，8进行大小段的切换。
;andeq r14,r7,r0,lsl #20 ，streq r0,[r0,-r10,ror #1] ，与b ChangeBigEndian的作用相同。
;*******************************************************************/
;在0x0处的异常中断是复位异常中断，是上电后执行的第一条指令
;变量ENDIAN_CHANGE用于标记是否要从小端模式改变为大端模式，因为编译器初始模式是小端模式，如果要用大端模式，就要事先把该变量设置为TRUE，否则为FLASE
;变量ENTRY_BUS_WIDTH用于设置总线的宽度，因为用16位和8位宽度来表示32位数据时，在大端模式下，数据的含义是不同的
;由于要考虑到大端和小端模式，以及总线的宽度，因此该处看似较复杂，其实只是一条跳转指令：当为大端模式时，跳转到ChangeBigEndian函数处，否则跳转到ResetHandler函数处
ASSERT :DEF:ENDIAN_CHANGE ; 判断是否定义了ENDIAN_CHANGE,如果没有定义，则报告该处错误信息
[ ENDIAN_CHANGE ; if ENDIAN_CHANGE ==TRUE
ASSERT :DEF:ENTRY_BUS_WIDTH ; 判断是否定义了ENTRY_BUS_WIDTH,如果没有定义，则报告该处错误信息
[ ENTRY_BUS_WIDTH=32 ; if ENTRY_BUS_WIDTH ==32
;跳转到ChangeBigEndian（ChangeBigEndian在0x24），因此该条指令的机器码为0xea000007
;所以该语句与在该处（即0x0处）直接放入0xea000007数据（即DCD 0xea000007）作用相同
b ChangeBigEndian ;DCD 0xea000007
]
[ ENTRY_BUS_WIDTH=16
;在小端模式下，用16位或8位数据总线宽度表示32位数据，与用32位总线宽度表示32位数据，格式完全一致。但在大端模式下，格式就会发生变化
;在复位时，系统默认的是小端模式，所以就要人为地改变数据格式，使得用16位大端数据表示的32位数据也能被小端模式的系统识别
;该语句的目的也是跳转到ChangeBigEndian，即机器码也应该是0xea000007，但为了让小端模式系统识别，就要把机器码的顺序做一下调整，改为0x0007ea00，
;那么我们就可以用DCD 0x0007ea00把机器码装载进去了，但由于该处不能使用DCD伪指令，因此我们就要用一条真实的指令来代替DCD 0x0007ea00，
;即该指令编译后的机器码也为0x0007ea00，而andeq r14,r7,r0,lsl #20就是一条编译后机器码为0x0007ea00的指令，所以我们在该处写上该条指令
andeq r14,r7,r0,lsl #20 ;DCD 0x0007ea00
]
[ ENTRY_BUS_WIDTH=8
;该语句的分析与上一段代码的分析相似
;streq r0,[r0,-r10,ror #1]编译后的机器码为0x070000ea
streq r0,[r0,-r10,ror #1] ;DCD 0x070000ea
]
|
b ResetHandler ; 设成FALSE的话就来到这了,转跳到复位程序入口
;这段是复位程序，先进行大小段切换，然后进入复位异常处理程序
]
;这段时异常中断向量表
b HandlerUndef ;handler for Undefined mode ; 转跳到Undefined mode程序入口
b HandlerSWI ;handler for SWI interrupt ; 转跳到SWI 中断程序入口
b HandlerPabort ;handler for PAbort ; 转跳到PAbort(指令异常)程序入口
b HandlerDabort ;handler for DAbort ; 转跳到DAbort(数据异常)程序入口
b . ; reserved 保留，跳转到自身地址处，即进入死循环
b HandlerIRQ ;handler for IRQ interrupt ; 转跳到IRQ 中断程序入口
b HandlerFIQ ;handler for FIQ interrupt ; 转跳到FIQ 中断程序入口
;电源管理 EnterPWDN在后面进行了实现，主要是进入IDLE模式和SLEEP模式
;@0x20
;跳转到EnterPWDN，处理电源管理的其他非正常模式，在C语言程序段中被调用
;该处地址为0x20，至于为什么要在该处执行，我认为可能是该处离异常中断向量表最近吧
b EnterPWDN
;从小端切换到大端的实现过程,由0x0跳转至此，目的是把小端模式改为大端模式，即把CP15中的寄存器C1中的第7位置1
ChangeBigEndian
;@0x24
[ ENTRY_BUS_WIDTH=32 ; if ENTRY_BUS_WIDTH == 32
;执行mrc p15,0,r0,c1,c0,0，得到CP15中的寄存器C1，放入r0中
;由于mrc p15,0,r0,c1,c0,0的机器码为0xee110f10
;因此DCD 0xee110f10的意思就是mrc p15,0,r0,c1,c0,0。下同
DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
;执行orr r0,r0,#0x80，置r0中的第7位为1，表示选择大端模式
DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian
;执行mcr p15,0,r0,c1,c0,0，把r0写入CP15中的寄存器C1
DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
]
[ ENTRY_BUS_WIDTH=16
;由于此时系统还不能识别16位或8位大端模式下表示的32为数据
;因此还需人为地进行数据调整，即把0xee110f10变为0x0f10ee11
;然后用DCD指令存入该数据。下同
DCD 0x0f10ee11
DCD 0x0080e380
DCD 0x0f10ee01
]
[ ENTRY_BUS_WIDTH=8
DCD 0x100f11ee
DCD 0x800080e3
DCD 0x100f01ee
]
; 相当于NOP指令，作用是等待从小端模式向大端模式切换
; 此后系统就能够自动识别出不同总线宽度下的大端模式，因此以后就无需再人为调整指令了
DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
b ResetHandler
;Function for entering power down mode
; 1. SDRAM should be in self-refresh mode.
; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.
; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.
; 4. The I-cache may have to be turned on.
; 5. The location of the following code may have not to be changed.
;void EnterPWDN(int CLKCON);
;/*******************************************************************
;进入电源管理部分，ATPCS定义了｛R0～R3｝作为参数传递和结果返回，超过4个放堆栈里。编程时尽可能4个之内的参数。所以这里R0是EnterPWDN的参数，r0=CLKCON。
;*******************************************************************/
;掉电模式函数
;在C语言中定义为：#define EnterPWDN(clkcon) ((void (*)(int))0x20)(clkcon)
;void EnterPWDN(int clkcon);
EnterPWDN
mov r2,r0 ;r2=rCLKCON r0为该函数输入参数clkcon
tst r0,#0x8 ;POWER_OFF mode? 判断clkcon中的第3位，是否要切换到SLEEP模式
bne ENTER_POWER_OFF ; 切换到SLEEP模式
ENTER_STOP ; IDLE模式
ldr r0,=REFRESH ; 进入IDLE模式前要设置SDRAM的自刷新，否则数据丢失了
ldr r3,[r0] ;r3=rREFRESH
mov r1, r3
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh
mov r1,#16 ;wait until self-refresh is issued. may not be needed.
0 subs r1,r1,#1
bne %B0
ldr r0,=CLKCON ;enter STOP mode. 进入IDLE模式
str r2,[r0] ; 置第2位，进入IDLE模式
mov r1,#32
0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.
bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off
; Entering POWER_OFF mode, only the reset by wake-up is available.
; 从IDLE模式下被唤醒，系统从该处继续执行
; 取消SDRAM自刷新方式
ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
str r3,[r0] ; 这里的r3是设置了自刷新之前的值，改变的是r1，所以可以用r3直 接赋值
MOV_PC_LR ; 返回，该语句为一个宏定义
ENTER_POWER_OFF ; SLEEP模式
;NOTE.
;1) rGSTATUS3 should have the return address after wake-up from POWER_OFF mode.
ldr r0,=REFRESH ; 进入睡眠模式也要自刷新
ldr r1,[r0] ;r1=rREFRESH
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh
mov r1,#16 ;Wait until self-refresh is issued,which may not be needed.
0 subs r1,r1,#1
bne %B0
; 在进入SLEEP模式之前，配置必要的时钟和OFFREFRESH
ldr r1,=MISCCR
ldr r0,[r1]
orr r0,r0,#(7<<17) ;Make sure that SCLK0:SCLK->0, SCLK1:SCLK->0, SCKE=L during boot-up
str r0,[r1]
ldr r0,=CLKCON
str r2,[r0] ; 置第3位，进入SLEEP模式
b . ;CPU will die here.
WAKEUP_POWER_OFF ; 从SLEEP模式下被唤醒函数
;Release SCLKn after wake-up from the POWER_OFF mode.设置时钟和OFFREFRESH
ldr r1,=MISCCR
ldr r0,[r1]
bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:L->H
str r0,[r1]
;/*******************************************************************
;设置内存控制寄存器，在SMRDATA中已经设定好，BWSCON总线宽度和等待状态寄存器，地址0x48000000，是13内存控制寄存器的起始地址。
;*******************************************************************/
;Set memory control registers
ldr r0,=SMRDATA
ldr r1,=BWSCON ;BWSCON Address
add r2, r0, #52 ;End address of SMRDATA r2是这13个寄存器结束的地
0
ldr r3, [r0], #4 ; 通过r3作为中介，把以r0为基址的内容向r1为基址的地方拷贝
str r3, [r1], #4
cmp r2, r0 ;如果没有结束继续拷贝
bne %B0
mov r1,#256
0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.
bne %B0
;GSTATUS3存放着想要从SLEEP模式唤醒后的执行地址
ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after POWER_OFF wake-up
ldr r0,[r1]
mov pc,r0
LTORG
; 将HandlerLabel与HandleLabel进行关联，所谓的“加载程序”
; 当系统进入异常中断后，由存放在0x0~0x1C处的中断向量地址中的跳转指令，跳转到此处相应的位置，并由事先定义好的宏定义再次跳转到相应的中断服务程序中
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort
;/*******************************************************************
;下面这段代码用于非矢量中断。INTOFFSET中断偏移寄存器。中断偏移寄存器显示了哪个IRQ中断模式的请求在INTPND寄存器中。
;该位可以通过清除SRCPND和INTPND寄存器被自动清除。 在汇编中INTOFFSET等寄存器的名字是指寄存器的地址，
;比如INTOFFSET是INTOFFSET这个寄存器的地址，所以ldr r9 = INTOFFSET，在C语言中，INTOFFSET是INTOFFSET这个寄存器的内容。
;*******************************************************************/
;下面这段代码是用于处理非向量中断，即由软件程序来判断到底发生了哪种中断，然后跳转到相应地中断服务程序中
;具体地说就是，当发生中断时，会置INTOFFSET寄存器相应的位为1，然后通过查表（见该程序末端部分的中断向量表），找到相对应的中断入口地址
;观察中断向量表，会发现它与INTOFFSET寄存器中的中断源正好相对应，即向量表的顺序与INTOFFSET寄存器中的中断源的由小到大的顺序一致，
;因此我们可以用基址加变址的方式很容易找到相对应的中断入口地址。其中基址为向量表的首个中断源地址，变址为INTOFFSET寄存器的值乘以4（因为系统是用4个字节单元来存放一个中断向量）
IsrIRQ
sub sp,sp,#4 ;reserved for PC 首先在栈中留出一个字的位置
stmfd sp!,{r8-r9} ;由于要用到r8，r9所以先压栈，保存
ldr r9,=INTOFFSET ; 把INTOFFSET寄存器的地址放入r9中
ldr r9,[r9] ; 把r9的内容放入r9寄存器中
ldr r8,=HandleEINT0 ; 得到中断向量表的基地址
add r8,r8,r9,lsl #2 ; 用基址加变址的方式得到中断向量表的地址
ldr r8,[r8] ; 把中断处理程序的入口地址放入r8
str r8,[sp,#8] ; 将r8压入栈中
ldmfd sp!,{r8-r9,pc} ; 使r8,r9和入口地址出栈，并跳转到中断服务程序中
;/*******************************************************************
;这个是程序的入口，主要进行了关闭看门狗，屏蔽所有中断，设置时钟，设置内存控制，
;检查启动方式，如果是Nandflash，进行代码的搬运。如果是Norflash，将代码复制到RO指定的位置。初始化各个模式下的堆栈。
;*******************************************************************/
;=======
; ENTRY
;=======
;系统上电或复位后，由0x0处的跳转指令，跳转到该处开始真正执行系统的初始化工作
ResetHandler
ldr r0,=WTCON ;watch dog disable 在系统初始化过程中，不需要看门狗，因此关闭看门狗功能
ldr r1,=0x0 ; WTCON的第0位是复位信号输出允许位
str r1,[r0]
;同样，此时也不应该响应任何中断，因此屏蔽所有中断，以及子中断
ldr r0,=INTMSK
ldr r1,=0xffffffff ;all interrupt disable 屏蔽所有的中断
str r1,[r0]
ldr r0,=INTSUBMSK ; 屏蔽所有的子中断
ldr r1,=0x7ff ;all sub interrupt disable, 2002/04/10
str r1,[r0]
;led显示
;由于启动文件是无法仿真的，因此为了判断该文件中语句的正确与否，往往在需要观察的地方加上一段点亮LED的程序，这样就可以知道程序是否已经执行到此处
;下面方括号内的程序就是点亮LED的小程序
[ {FALSE}
; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
; Led_Display
ldr r0,=GPFCON
ldr r1,=0x5500
str r1,[r0]
ldr r0,=GPFDAT
ldr r1,=0x10
str r1,[r0]
]
;/**********************************************************************************
;设置系统时钟，主要设置PLL锁定时间和UPLL（USB时钟）和MPLL的主频。S3C2440A的时钟控制逻辑有两个PLL，
;一个是UPLL，一个是MPLL。MPLL可以产生FCLK（for CPU），HCLK(for AHB bus),PCLK(for APB bus)。
;**********************************************************************************/
;下列程序是用于设置系统时钟频率
;设置PLL的锁定时间常数，以得到一定时间的延时
;To reduce PLL lock time, adjust the LOCKTIME register.
ldr r0,=LOCKTIME
ldr r1,=0xffffff ; 复位后 LOCKTIME 是0xffffffff, 复位后经过LOCKTIME时间后，FCLK才稳定
str r1,[r0]
[ PLL_ON_START
;Configure MPLL 设置系统的三个时钟频率FCLK、HCLK、PCLK
ldr r0,=MPLLCON
ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin=12MHz,Fout=50MHz
str r1,[r0]
]
;Check if the boot is caused by the wake-up from POWER_OFF mode.
ldr r1,=GSTATUS2
ldr r0,[r1]
tst r0,#0x2
;In case of the wake-up from POWER_OFF mode, go to POWER_OFF_WAKEUP handler.
bne WAKEUP_POWER_OFF
EXPORT StartPointAfterPowerOffWakeUp
StartPointAfterPowerOffWakeUp
;Set memory control registers
ldr r0,=SMRDATA
ldr r1,=BWSCON ;BWSCON Address
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0
;Initialize stacks
bl InitStacks
; Setup IRQ handler
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]
;Copy and paste RW data/zero initialized data
ldr r0, =|Image$$RO$$Limit| ; Get pointer to ROM data 得到RW数据源的起始地址
ldr r1, =|Image$$RW$$Base| ; and RAM copy ;RW区在RAM里的执行区起始地址
ldr r3, =|Image$$ZI$$Base| ; ZI区在RAM里面的起始地址
;Zero init base => top of initialised data
cmp r0, r1 ; Check that they are different ;比较它们是否相等
beq %F2
1
cmp r1, r3 ; Copy init data
ldrcc r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4
strcc r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4
bcc %B1
2
ldr r1, =|Image$$ZI$$Limit| ; Top of zero init segment
mov r2, #0
3
cmp r3, r1 ; Zero init
strcc r2, [r3], #4
bcc %B3
[ :LNOT:THUMBCODE
bl Main ;Don't use main() because ......
b .
]
[ THUMBCODE ;for start-up code for Thumb mode
orr lr,pc,#1
bx lr
CODE16
bl Main ;Don't use main() because ......
b .
CODE32
]
;function initializing stacks
InitStacks ; 初始化堆栈函数
;Don't use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'
;/*******************************************************************
;修改状态寄存器一般是通过“读取－修改－写回”，先将cpsr中的内容取出，放入r0中，
;通过orr操作进行置位，然后通过指令msr写回到cpsr，这样就进行了工作状态的切换，
;栈的地址前面已经声明过了，所以这里直接赋值就可以。 系统复位后进入的是SVC模式，
;而且各种模式下的lr不同，因此要想从该函数内返回，要首先切换到SVC模式，再使用lr，这样可以返回了，
;mov pc,lr 。
;因为ARM有7种执行状态，每一种状态的堆栈指针寄存器（SP）都是独立的。因此，对程序中需要用到的每一种模式都要给SP定义一个堆栈地址。
;方法是改变状态寄存器内的状态位，使处理器切换到不同的状态，让后给SP赋值。注意：不要切换到User模式进行User模式的堆栈设置，
;因为进入User模式后就不能再操作CPSR回到别的模式了，可能会对接下去的程序执行造成影响
;*******************************************************************/
;改变CPSR中M控制位，切换到相应的处理器模式下
;为各自模式下的SP赋值
mrs r0,cpsr
bic r0,r0,#MODEMASK
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1 ;UndefMode
ldr sp,=UndefStack
orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1 ;AbortMode
ldr sp,=AbortStack
orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1 ;IRQMode
ldr sp,=IRQStack
orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1 ;FIQMode
ldr sp,=FIQStack
bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1 ;SVCMode
ldr sp,=SVCStack
;USER mode has not be initialized.
;系统模式和用户模式共用一个栈空间，因此不用再重复设置用户模式堆栈
;系统复位后进入的是SVC模式，而且各种模式下的lr不同，因此要想从该函数内返回，要首先切换到SVC模式，再使用lr，这样可以正确返回了
mov pc,lr
;The LR register won't be valid if the current mode is not SVC mode.
; 定义一个数据缓冲池
LTORG
;连续13个内存控制寄存器的定义空间
SMRDATA DATA
; Memory configuration should be optimized for best performance
; The following parameter is not optimized.
; Memory access cycle parameter strategy
; 1) The memory settings is safe parameters even at HCLK=75Mhz.
; 2) SDRAM refresh period is for HCLK=75Mhz.
;/*******************************************************************
;这个是SMRDATA区域的13个寄存器的值，下面的一些符号在Memcfg.inc中定义。用于初始化各个bank。
;Memory control
;BWSCON EQU 0x48000000 ;Bus width & wait status
;BANKCON0 EQU 0x48000004 ;Boot ROM control
;BANKCON1 EQU 0x48000008 ;BANK1 control
;BANKCON2 EQU 0x4800000c ;BANK2 control
;BANKCON3 EQU 0x48000010 ;BANK3 control
;BANKCON4 EQU 0x48000014 ;BANK4 control
;BANKCON5 EQU 0x48000018 ;BANK5 control
;BANKCON6 EQU 0x4800001c ;BANK6 control
;BANKCON7 EQU 0x48000020 ;BANK7 control
;REFRESH EQU 0x48000024 ;DRAM/SDRAM refresh
;BANKSIZE EQU 0x48000028 ;Flexible Bank Size
;MRSRB6 EQU 0x4800002c ;Mode register set for SDRAM Bank6
;MRSRB7 EQU 0x48000030 ;Mode register set for SDRAM Bank7
;*******************************************************************/
DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
DCD 0x32 ;SCLK power saving mode, BANKSIZE 128M/128M
DCD 0x30 ;MRSR6 CL=3clk
DCD 0x30 ;MRSR7
; DCD 0x20 ;MRSR6 CL=2clk
; DCD 0x20 ;MRSR7
;/*******************************************************************
;运行域定义，比如|Image$$ZI$$Base|是ZI区在RAM中的起始地址，|Image$$ZI$$Limit|是ZI区在RAM中的结束地址。
;在CodeWarrior的设置中，RW Base选项保留为空，RO属性的输出段，RW属性的输出段以及ZI属性的输出段都包含在一个域中，
;这些可以在从List.txt文件中看出，3者定义的地址是顺序相连的，它们之间的相对位置不用重新加载已经是正确的了。
;所以直接把这三个段整体拷贝到SDRAM中就可以运行，而不需要再按照各段的值进行加载。如果RW设置某一固定值，这时就需要3个段值进行加载了。
;*******************************************************************/
ALIGN
;二级中断向量表，软件实现的
AREA RamData, DATA, READWRITE
^ _ISR_STARTADDRESS
HandleReset # 4
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4
;Don't use the label 'IntVectorTable',
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
HandleEINT0 # 4
HandleEINT1 # 4
HandleEINT2 # 4
HandleEINT3 # 4
HandleEINT4_7 # 4
HandleEINT8_23 # 4
HandleRSV6 # 4
HandleBATFLT # 4
HandleTICK # 4
HandleWDT # 4
HandleTIMER0 # 4
HandleTIMER1 # 4
HandleTIMER2 # 4
HandleTIMER3 # 4
HandleTIMER4 # 4
HandleUART2 # 4
HandleLCD # 4
HandleDMA0 # 4
HandleDMA1 # 4
HandleDMA2 # 4
HandleDMA3 # 4
HandleMMC # 4
HandleSPI0 # 4
HandleUART1 # 4
HandleRSV24 # 4
HandleUSBD # 4
HandleUSBH # 4
HandleIIC # 4
HandleUART0 # 4
HandleSPI1 # 4
HandleRTC # 4
HandleADC # 4
END
