呵呵，要再次感谢赵博的书给我的启发，现在想什么就可以自己去实践，这种感觉真好。这两天我实践了一个中文显示问题，终于成功，贴出来与大家共享。
通过实践，大概了解图形模式下的工作方式，和汉字支持的基本实现方法。我的工作是让系统启动后在屏幕上显示“汉字操作系统”五个汉字
说明：这里只介绍使用点阵字库。
准备工作：
1、首先必须创建相应的点阵信息
我们来创建一个16×16的两个汉字的点阵，其实很简单，你在纸上画一个行列
各有16个格子的方块出来，然后按其大小，在里面写一个字，比如”成“，建
议你写得粗一点，这时你会发现有些格子中被字的笔画穿过，有的仍是空格
子，现在你把没有笔画穿过的记为0，有笔画的记为1，从第一行开始，将这个
16×16的“点阵”的信息记下来，由于每行有16个位，所以需要2个字节来记录一
行，共16行，所以共需2×16=32个字节来保存一个字的“点阵”.
比如：汉-->00000h,04008h,037fch,01008h,08208h,06208h,02210h,00910h
01120h,020A0h,0E040h,020A0h,02110h,02208h,0240Eh,00804h
当然我这个“点阵”是从别的字库里载取出来的，但上面的方法绝对是可行的
点阵本质上就是这样生成的。
2、编写一个显示一个像素的子程序
面临的任务：在图形模式下，在屏幕上打印一个像素点
分析：
所需的变量：初始的左上角的坐标值x0,y0
默认参数： 默认分辨率为640×480×16色模式
（因为这是VGA标准BIOS支持的模式）
默认颜色为黑底黄字
实现：（参考了《VGA实用编程技术》罗健军 清华大学出版社 1995）
;功能：
; 在指定的屏幕位置用指定的颜色画一个点
;入口参数：
; bx = x0 象素在屏幕上的X坐标
; ax = y0 象素在屏幕上的Y坐标
; cl = color 象素的颜色值
writePix proc
linelen = 80 ;640*480*16色模式下一条扫描线占用的字节数
;=Width/8
;计算象素点的位置
push es
push bp
push dx
push ax
push di
push cx
push bx
mov bp,sp
mov cl,3
shr bx,cl ;X0/8
mov cx,linelen
mul cx
add ax,bx ;至此ax中为像素点的偏移，dx为页号
mov di,ax
;设置映象屏蔽寄存器
mov dx,sequen_ctl
mov al,2
out dx,al
inc dx
mov al,0fh ;四个位面全部充许写
out dx,al
;选择写方式2
mov dx,graphi_ctl
mov al,5
out dx,al
inc dx
mov al,2
out dx,al
;计算屏蔽码,并设置位屏蔽寄存器
dec dx
mov al,8
out dx,al
mov cx,[bp] ;取出X坐标
and cl,7
mov al,80h
shr al,cl
inc dx
out dx,al
;写数据
mov ax,vgaseg ;ES段指向显存地址0a000h
mov es,ax
mov ax,[bp+2] ;取颜色值
mov ah,es:[di] ;读一次使屏蔽寄存器有效
mov es:[di],al ;写入显示存储器
pop bx
pop cx
pop di
pop ax
pop dx
pop bp
pop es
ret
writePix endp
3、编写一个输出一个汉字图形字符的子程序，有了2的基础这一步显得比较容易，实现
如下：
;在图形模式下显示一个汉字
;输入参数：
; BX=x0 初始左上角X坐标
; AX=y0 初始左上角Y坐标
; CX=color 其实只是cl表示颜色
; ds:si=buff 字符点阵信息首地址
;返回值：无
DispZhC proc
push si
push bp
push ax
push bx
push cx
push dx
mov bp,sp
xor dx,dx ;dx 当前行
jmp a1
Disp:
inc si
inc si ;指向下一个字
inc dx ;行记数加一
a1:
cmp dx,16 ;当前行为0-15，因为是16*16点阵
je Done
xor cx,cx ;cx 当前列初始化
mov bx,word ptr [si] ;读入一行的点阵信息，一行两个字节表示
DispL:
cmp cx,16
je Disp ;换行
or cx,cx ;清零CF
shl bx,1
jc DispP ;如果当前位是1，显示一个点
inc cx
jmp DispL
DispP:
push ax
push bx
push cx
mov ax,[bp+6]
add ax,dx
mov bx,[bp+4]
add bx,cx
mov cx,[bp+2] ;颜色值在cl中
call writePix
pop cx
inc cx
pop bx
pop ax
jmp DispL
Done:
pop dx
pop cx
pop bx
pop ax
pop bp
pop si
ret
DispZhC endp
4、编写一个输出一个字符串的子程序
面临的任务：你已经拥有显示一个字符的子程序，现在要对它连续调用，完整
地显示缓冲区中的全部汉字点阵。
分析：
所需的变量：整个字符串初始的左上角坐标x0,y0
字符串长度
在显示每个字符时传递给子程序的左上角坐标x1,y1
默认参数： 默认为16点阵
默认字间距为5个像素
程序主要结构：
一个单重循环，按字符串长度进行循环。
我的实现：
;在图形模式下显示指定长度的字符串
;输入参数：
; ds:si 字符串点阵缓冲区的首地址
; ax=y0 字符串第一个字符左上角的Y坐标
; bx=x0 字符串第一个字符左上角的X坐标
; ch=n
; cl=color
;返回值：无
DefDis = 5 ;每两个符号间的默认间距为5个像素
CharWidth = 16 ;默认为16点阵，这也是每个字符的像素宽度
DispZhS proc
push bp
push ax
push bx
push ds
push si
push cx
push dx
mov bp,sp
xor dx,dx
jmp s1
nextChar: ;指向下一个要输出的字符
add si,32
add bx,DefDis+CharWidth
s1:
cmp dh,ch ;是否已经输出了指定个数的字符
je Dones
call DispZhc
inc dh
jmp nextChar
Dones:
pop dx
pop cx
pop si
pop ds
pop bx
pop ax
pop bp
ret
DispZhS endp
5、标准VGA进入图形模式的方法
;进入640×480×16色模式
;setmode:
;对640*480*16和320*论200*256是标准VGA模式，在各种VGA上都分别为12h和13h
mov ax, 12h
int 10h
作者: wildcatgsk
时间: 2004-11-8 16:01
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
[这个贴子最后由wildcatgsk在 2004/11/16 11:34am 第 2 次编辑]
这是这个主题的贴图
关于中文支持的几点想法：
1、“字符集”只是面向用户的对问题的高层次的抽象。
当你把中文文档保存在软盘上带回家时，上面存放着的是“字符集”中编码的集合，它们以一种成为标准的方式定义着唯一的一个现实世界存在的汉字。但另一方面，这些编码本身并不说明任何其它关于这个汉字的信息，比如发音？偏旁？等等，当你在另外一台机器上查看这个文档时，必需有一个“显示层”处在人和计算机之间，而这个显示层如何实现并不重要，唯一重要的是它也必需知道编码与汉字的对应关系，当它读到一个处于某个“字符集”的编码时，它就通过自身维护着的一个代码转换表将标准的编码转换成自己的字形信息码，这是一个查表的过程，之后它根据查找到的信息“绘制”出一个特定的汉字。
2、这就意味着重要的是标准，而不是实现，当你要在一个英文平台上显示汉字时，唯一困难的是确定一个相互不冲突的标准字符集，至于要显示出什么形状根本不是问题。
3、为了确保兼容和跨平台，从软件的角度说最好自带字库，通过这个实例清楚了如何做到自带字库，事实上因为这里实现的程序是以字而不是象通常那样以字节为单位读字形信息，造成通常点阵字库中的编码无法直接拿来用，那样字的两边恰好颠倒，必须对每两个字节交换一次才能被它正确显示出来。但是不难通过修改DispZhC中的代码实现通用。
4、要实现矢量字形原理是一样的，但是需要较多的数学方法，这就知道了理论的用途。想想为什么一些计算机大师最初的动力竟是因为酷爱游戏。
作者: kevie
时间: 2004-11-9 11:16
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
[这个贴子最后由kevie在 2004/11/09 01:54pm 第 6 次编辑]
请问我用ml＋tlink5编译链接后大小为1,024 字节（其中有512字节的dos头信息，去掉后就只有启动扇区的信息了），怎么把他放到虚拟软驱（1。4M）里面的？即除开第一扇区的512字节外，其它空间怎么处理呢？谢谢
还有一问，testVGA。asm里面只有“汉”字的点阵信息，怎么运行的时候会出现”汉字操作系统"?是不是其它的点阵忘记给了？
作者: lmarsin
时间: 2004-11-13 20:08
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
请问哪有VGA编程技术方面的电子书？
作者: powerlly
时间: 2004-11-14 12:57
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
正在学习当中
希望自己学完以后也能像版主一样自己动手写写
作者: lmarsin
时间: 2004-11-14 20:10
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
以上实在实模式下，不知道在保护模式下怎么实现使VGA进入图形模式？
作者: wildcatgsk
时间: 2004-11-15 12:39
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
下面引用由kevie在 2004/11/09 11:16am 发表的内容：
请问我用ml＋tlink5编译链接后大小为1,024 字节（其中有512字节的dos头信息，去掉后就只有启动扇区的信息了），怎么把他放到虚拟软驱（1。4M）里面的？即除开第一扇区的512字节外，其它空间怎么处理呢？谢谢
还 ...
tlink5一般来说也是生成DOS的EXE文件,也就是前512个字节是支持信息,而不是代码,只有后512个字节才是真正可运行的代码.放到虚拟软驱中可以这样做.
首先创建一个虚拟软驱的文件,用UltraEdit以进制模式打开,再打开你编译得到的这个文件,同样以16进制打开,拷贝后512个字节,拷到虚拟软驱文件最头部就可以在Bochs中使用了.要注意的是偏移1feh和1ffh必须是55AA.
至于只有一个字,只是做为演示,因为是从UCDOS的16点阵字库中提取出来的.并对每两个字节做了一次交换得到可用的点阵后直接在UltraEdit中编辑进去的.
作者: wildcatgsk
时间: 2004-11-15 12:52
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
下面引用由lmarsin在 2004/11/14 08:10pm 发表的内容：
以上实在实模式下，不知道在保护模式下怎么实现使VGA进入图形模式？
进入图形模式,只是指显示器、显卡的工作状态,本质上说这些设备中也存在相应的硬件
控制设备的运行。要进入图形模式只是通过使用I/O指令（in、 out）设置相关控制器即
可，与处在实模式还是安全模式无关，只要相应的BIOS调用仍然存在，仍然可以被程序调
用，就可以通过调用BIOS进入图形模式。
更进一步说，BIOS调用本身也是一个子程序，只是它固化在硬件中，并被自动装入内存
中，所有的BIOS例程本身也是一段代码，也就是说，它也是在操作设备提供的接口，如果程
序员能够知道相应设备的接口信息，比如有哪些寄存器、操作端口是什么、操作时序如何？
等等。那就完全可以自己编程完成所有的功能。这一切与保护模式还是实模式无关，只是在
保护模式下如果代码的级别不够的话，有些特权指令无法执行而已， 而且相关的寻址方式
等发生了变化。比如在保护模式下一般的应用程序未必可以操作硬件的端口。
作者: kevie
时间: 2004-11-15 13:44
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
请问：除开第一扇区的512字节外，其它空间怎么处理呢？ 用你的源代码编译后生成的1024byte<<1.44M,那其它空间怎么处理呢？让它全为零？ 我用二进制编辑工具打开你给的img文件，看到在第1扇区外的空间也有数据的。是不是得到这个img文件的源代码比你放到网上的要大？即可以全部显示“汉字操作系统”的代码。 我这里用你的代码试验得出的“汉”字比较模糊，看不清楚。不知道怎么回事情 谢谢你的回复
作者: wildcatgsk
时间: 2004-11-15 17:01
标题: 从最底层实现汉字输出，一个中文启动界面的实现方法
下面引用由kevie在 2004/11/15 01:44pm 发表的内容： 请问：除开第一扇区的512字节外，其它空间怎么处理呢？ 用你的源代码编译后生成的1024byte<<1.44M,那其它空间怎么处理呢？让它全为零？ 我用二进制编辑工具打开你给的img文件，看到在第1扇区 ...
生成的代码是1K,前512个字节是DOS使用的信息,后512个字节是有用的,只要拷贝这些数据到a.img文件中去就可以了,我的img文件因为是做很多试验都用它后面的数据没有清掉.完全不影响结果.至于比较模糊就不清楚了,可能是我抄的点阵信息有点问题?
(39.92 KB)