mx.events.PropertyChangeEvent

1.简介
       继承关系：PropertyChangeEvent
       如果对象的属性值发生变化，可以派发PropertyChangeEvent事件来表示。
       Flex 数据绑定机制也使用此事件。
       例子请参考《PropertyChangeEvent事件》

2.常见属性和方法
2.1 属性PROPERTY_CHANGE
PROPERTY_CHANGE : String = "propertyChange"
[静态] PropertyChangeEvent.PROPERTY_CHANGE 常量可为 PropertyChange 事件定义事件对象的 type 属性的值。

2.2 属性kind
指定更改的类型。String类型
可能的值为 PropertyChangeEventKind.UPDATE、PropertyChangeEventKind.DELETE 和 null

2.3 属性newValue
更改后的属性的值。Object类型

2.4 属性oldValue
更改前的属性的值。Object类型

2.5 属性property
需要更改的属性。Object类型

2.6 属性source
发生更改属性的对象。Object类型

2.7 属性currentTarget
用于定义处理该事件的事件侦听器的 Object。Object类型
例如，如果您使用myButton.addEventListener() 注册某个事件侦听器，则 myButton 为 currentTarget 的值。

2.8 属性target
事件目标。Object类型
派发事件的 Object；它不一定是侦听该事件的 Object。使用 currentTarget 属性始终可以访问侦听事件的 Object。


3.源代码

package mx.events
{

import flash.events.Event;
import mx.events.PropertyChangeEventKind;

public class PropertyChangeEvent extends Event
{
    include "../core/Version.as";

    //类属性
    public static const PROPERTY_CHANGE:String = "propertyChange";

      //类方法

    public static function createUpdateEvent(
                                    source:Object,
                                    property:Object,
                                    oldValue:Object,
                                    newValue:Object):PropertyChangeEvent
    {
        var event:PropertyChangeEvent =
            new PropertyChangeEvent(PROPERTY_CHANGE);

        event.kind = PropertyChangeEventKind.UPDATE;
        event.oldValue = oldValue;
        event.newValue = newValue;
        event.source = source;
        event.property = property;

        return event;
    }

    //  构造函数
    public function PropertyChangeEvent(type:String, bubbles:Boolean = false,
                                        cancelable:Boolean = false,
                                        kind:String = null,
                                        property:Object = null,
                                        oldValue:Object = null,
                                        newValue:Object = null,
                                        source:Object = null)
    {
        super(type, bubbles, cancelable);

        this.kind = kind;
        this.property = property;
        this.oldValue = oldValue;
        this.newValue = newValue;
        this.source = source;
    }

    //  属性kind
    public var kind:String;


    // 属性newValue
    public var newValue:Object;


    // 属性 oldValue
    public var oldValue:Object;


    //  属性property
    public var property:Object;

    //  属性source
    public var source:Object;

    //方法clone，继承自Event
     /**
     *  @private
     */
    override public function clone():Event
    {
        return new PropertyChangeEvent(type, bubbles, cancelable, kind,
                                       property, oldValue, newValue, source);
    }
}

}

参考文献
1.类参考.
2.源代码.