分类： LINUX
2008-08-27 09:27:28
附上我的理解：
> 使用BIOS中断获取有关内存、硬盘等参数，保存在原来bootsect模块驻扎的地方
> 屏蔽中断
> 将system模块移动到0x0000:0x0000处，BIOS向量表被覆盖(因为程序运行至此，之后再也无需用到BIOS中断了)
> 加载中断描述符表和全局描述符表
> 开启A20地址线
> 对可编程中断控制器8259A进行重新编程，建立硬件中断与向量号的对应关系
> PE置位，控制权交给system模块
#
# setup.s (C) 1991 Linus Torvalds
#
# setup.s is responsible for getting the system data from the BIOS,
# and putting them into the appropriate places in system memory.
# both setup.s and system has been loaded by the bootblock.
#
# This code asks the bios for memory/disk/other parameters, and
# puts them in a "safe" place: 0x90000-0x901FF, ie where the
# boot-block used to be. It is then up to the protected mode
# system to read them from there before the area is overwritten
# for buffer-blocks.
#
# NOTE! These had better be the same as in bootsect.s#
INITSEG = 0x9000 # we move boot here - out of the way
SYSSEG = 0x1000 # system loaded at 0x10000 (65536).
SETUPSEG = 0x9020 # this is the current segment
.globl start
.text
.code16
start:
# ok, the read went well so we get current cursor position and save it for
# posterity.
movw $INITSEG,%ax # this is done in bootsect already, but...
movw %ax,%ds
movb $0x03,%ah # read cursor pos
xorb %bh,%bh
int $0x10 # save it in known place, con_init fetches
movw %dx,0 # it from 0x90000.
# Get memory size (extended mem, kB)
movb $0x88,%ah
int $0x15
movw %ax,2
# Get video-card data:
movb $0x0f,%ah
int $0x10
movw %bx,4 # bh = display page
movw %ax,6 # al = video mode, ah = window width
# check for EGA/VGA and some config parameters
movb $0x12,%ah
movb $0x10,%bl
int $0x10
movw %ax,8
movw %bx,10
movw %cx,12
# Get hd0 data
movw $0x0000,%ax
mov %ax,%ds
lds 0x41*4,%si
movw $INITSEG,%ax
movw %ax,%es
movw $0x0080,%di
movw $0x10,%cx
rep
movsb
# Get hd1 data
mov $0x0000,%ax
mov %ax,%ds
lds 0x46*4,%si
mov $INITSEG,%ax
mov %ax,%es
mov $0x0090,%di
mov $0x10,%cx
rep
movsb
# Check that there IS a hd1 :-)
movw $0x01500,%ax
movb $0x81,%dl
int $0x13
jc no_disk1
cmpb $3,%ah
je is_disk1
no_disk1:
movw $INITSEG,%ax
movw %ax,%es
movw $0x0090,%di
movw $0x10,%cx
movw $0x00,%ax
rep
stosb
is_disk1:
# now we want to move to protected mode ...
cli # no interrupts allowed #
# first we move the system to it's rightful place
movw $0x0000,%ax
cld # 'direction'=0, movs moves forward
do_move:
movw %ax,%es # destination segment
addw $0x1000,%ax
cmpw $0x9000,%ax
jz end_move
movw %ax,%ds # source segment
subw %di,%di
subw %si,%si
movw $0x8000,%cx
rep
movsw
jmp do_move
# then we load the segment descriptors
end_move:
movw $SETUPSEG,%ax # right, forgot this at first. didn't work :-)
movw %ax,%ds
lidt idt_48 # load idt with 0,0
lgdt gdt_48 # load gdt with whatever appropriate
# that was painless, now we enable A20
call empty_8042
movb $0xD1,%al # command write
outb %al,$0x64
call empty_8042
movb $0xDF,%al # A20 on
outb %al,$0x60
call empty_8042
# well, that went ok, I hope. Now we have to reprogram the interrupts :-(
# we put them right after the intel-reserved hardware interrupts, at
# int 0x20-0x2F. There they won't mess up anything. Sadly IBM really
# messed this up with the original PC, and they haven't been able to
# rectify it afterwards. Thus the bios puts interrupts at 0x08-0x0f,
# which is used for the internal hardware interrupts as well. We just
# have to reprogram the 8259's, and it isn't fun.
movb $0x11,%al # initialization sequence
outb %al,$0x20 # send it to 8259A-1
.word 0x00eb,0x00eb # jmp $+2, jmp $+2
outb %al,$0xA0 # and to 8259A-2
.word 0x00eb,0x00eb
movb $0x20,%al # start of hardware int's (0x20)
outb %al,$0x21
.word 0x00eb,0x00eb
movb $0x28,%al # start of hardware int's 2 (0x28)
outb %al,$0xA1
.word 0x00eb,0x00eb
movb $0x04,%al # 8259-1 is master
outb %al,$0x21
.word 0x00eb,0x00eb
movb $0x02,%al # 8259-2 is slave
outb %al,$0xA1
.word 0x00eb,0x00eb
movb $0x01,%al # 8086 mode for both
outb %al,$0x21
.word 0x00eb,0x00eb
outb %al,$0xA1
.word 0x00eb,0x00eb
movb $0xFF,%al # mask off all interrupts for now
outb %al,$0x21
.word 0x00eb,0x00eb
outb %al,$0xA1
# well, that certainly wasn't fun :-(. Hopefully it works, and we don't
# need no steenking BIOS anyway (except for the initial loading :-).
# The BIOS-routine wants lots of unnecessary data, and it's less
# "interesting" anyway. This is how REAL programmers do it.
#
# Well, now's the time to actually move into protected mode. To make
# things as simple as possible, we do no register set-up or anything,
# we let the gnu-compiled 32-bit programs do that. We just jump to
# absolute address 0x00000, in 32-bit protected mode.
movw $0x0001,%ax # protected mode (PE) bit
lmsw %ax # This is it#
ljmp $8,$0 # jmp offset 0 of segment 8 (cs)
# This routine checks that the keyboard command queue is empty
# No timeout is used - if this hangs there is something wrong with
# the machine, and we probably couldn't proceed anyway.
empty_8042:
.word 0x00eb,0x00eb
inb $0x64,%al # 8042 status port
test $2,%al # is input buffer full?
jnz empty_8042 # yes - loop
ret
gdt:
.word 0,0,0,0 # dummy
.word 0x07FF # 8Mb - limit=2047 (2048*4096=8Mb)
.word 0x0000 # base address=0
.word 0x9A00 # code read/exec
.word 0x00C0 # granularity=4096, 386
.word 0x07FF # 8Mb - limit=2047 (2048*4096=8Mb)
.word 0x0000 # base address=0
.word 0x9200 # data read/write
.word 0x00C0 # granularity=4096, 386
idt_48:
.word 0 # idt limit=0
.word 0,0 # idt base=0L
gdt_48:
.word 0x800 # gdt limit=2048, 256 GDT entries
.word 512+gdt,0x9 # gdt base = 0X9xxxx
