Chinaunix首页 | 论坛 | 博客

Junn9527

首页　| 　博文目录　| 　关于我

Junn9527

  • 博客访问： 2981582
  • 博文数量： 412
  • 博客积分： 3010
  • 博客等级： 中校
  • 技术积分： 7374
  • 用 户 组： 普通用户
  • 注册时间： 2009-04-25 15:15
个人简介

学习是一种信仰。

文章分类

全部博文（412）

文章存档

2014年（108）

2013年（250）

2010年（11）

2009年（43）

我的朋友
最近访客
推荐博文
相关博文
PL/SQL程序设计（五）

分类： Oracle

2013-10-28 19:04:01

第五章    异常错误处理

    一个优秀的程序都应该能够正确处理各种出错情况，并尽可能从错误中恢复。ORACLE 提供异常情况(EXCEPTION)和异常处理(EXCEPTION HANDLER)来实现错误处理。

§5.1 异常处理概念

异常情况处理(EXCEPTION)是用来处理正常执行过程中未预料的事件,程序块的异常处理预定义的错误和自定义错误,由于PL/SQL程序块一旦产生异常而没有指出如何处理时,程序就会自动终止整个程序运行.

 

有三种类型的异常错误：

1． 预定义 ( Predefined )错误

ORACLE预定义的异常情况大约有24个。对这种异常情况的处理，无需在程序中定义，由ORACLE自动将其引发。

2． 非预定义 ( Predefined )错误

即其他标准的ORACLE错误。对这种异常情况的处理，需要用户在程序中定义，然后由ORACLE自动将其引发。

3． 用户定义(User_define) 错误

程序执行过程中，出现编程人员认为的非正常情况。对这种异常情况的处理，需要用户在程序中定义，然后显式地在程序中将其引发。

 

异常处理部分一般放在 PL/SQL 程序体的后半部,结构为:

 

EXCEPTION

   WHEN first_exception THEN 

   WHEN second_exception THEN 

   WHEN OTHERS THEN 

END;

异常处理可以按任意次序排列,但 OTHERS 必须放在最后.

 

§5.1.1预定义的异常处理

 

预定义说明的部分 ORACLE 异常错误

错误号

异常错误信息名称

说明

ORA-0001

Dup_val_on_index

试图破坏一个唯一性限制

ORA-0051

Timeout-on-resource

在等待资源时发生超时

ORA-0061

Transaction-backed-out

由于发生死锁事务被撤消

ORA-1001

Invalid-CURSOR

试图使用一个无效的游标

ORA-1012

Not-logged-on

没有连接到ORACLE

ORA-1017

Login-denied

无效的用户名/口令

ORA-1403

No_data_found

SELECT INTO没有找到数据

ORA-1422

Too_many_rows

SELECT INTO 返回多行

ORA-1476

Zero-divide

试图被零除

ORA-1722

Invalid-NUMBER

转换一个数字失败

ORA-6500

Storage-error

内存不够引发的内部错误

ORA-6501

Program-error

内部错误

ORA-6502

Value-error

转换或截断错误

ORA-6504

Rowtype-mismatch

宿主游标变量与 PL/SQL变量有不兼容行类型

ORA-6511

CURSOR-already-OPEN

试图打开一个已存在的游标

ORA-6530

Access-INTO-null

试图为null 对象的属性赋值

ORA-6531

Collection-is-null

试图将Exists 以外的集合( collection)方法应用于一个null pl/sql 表上或varray上

ORA-6532

Subscript-outside-limit

对嵌套或varray索引得引用超出声明范围以外

ORA-6533

Subscript-beyond-count

对嵌套或varray 索引得引用大于集合中元素的个数.

   

对这种异常情况的处理，只需在PL/SQL块的异常处理部分，直接引用相应的异常情况名，并对其完成相应的异常错误处理即可。

 

例1：更新指定员工工资，如工资小于1500，则加100；

 

DECLARE

   v_empno emp.empno%TYPE :=&empno;

   v_sal    emp.sal%TYPE;

BEGIN

   SELECT sal INTO v_sal FROM emp WHERE empno=v_empno;

   IF v_sal<=1500 THEN

        UPDATE emp SET sal=sal+100 WHERE empno=v_empno;

        DBMS_OUTPUT.PUT_LINE('编码为'||v_empno||'员工工资已更新!');    

   ELSE

DBMS_OUTPUT.PUT_LINE('编码为'||v_empno||'员工工资已经超过规定值!');

   END IF;

EXCEPTION

   WHEN NO_DATA_FOUND THEN 

      DBMS_OUTPUT.PUT_LINE('数据库中没有编码为'||v_empno||'的员工');

   WHEN TOO_MANY_ROWS THEN

      DBMS_OUTPUT.PUT_LINE('程序运行错误!请使用游标');

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||’---‘||SQLERRM);

END;

 

§5.1.2非预定义的异常处理

      

对于这类异常情况的处理，首先必须对非定义的ORACLE错误进行定义。步骤如下：

1.      在PL/SQL 块的定义部分定义异常情况：

<异常情况>  EXCEPTION;

 

2.      将其定义好的异常情况，与标准的ORACLE错误联系起来，使用EXCEPTION_INIT语句：

PRAGMA EXCEPTION_INIT(<异常情况>, <错误代码>)；

 

3.      在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

 

例2：删除指定部门的记录信息，以确保该部门没有员工。

 

INSERT INTO dept VALUES(50, ‘FINANCE’, ‘CHICAGO’);

 

DECLARE

   v_deptno dept.deptno%TYPE :=&deptno;

   deptno_remaining EXCEPTION;

   PRAGMA EXCEPTION_INIT(deptno_remaining, -2292);

   /* -2292 是违反一致性约束的错误代码 */

BEGIN

   DELETE FROM dept WHERE deptno=v_deptno;

EXCEPTION

   WHEN deptno_remaining THEN

      DBMS_OUTPUT.PUT_LINE('违反数据完整性约束!');

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||’---‘||SQLERRM);

END;

 

§5.1.3用户自定义的异常处理

当与一个异常错误相关的错误出现时，就会隐含触发该异常错误。用户定义的异常错误是通过显式使用 RAISE 语句来触发。当引发一个异常错误时，控制就转向到 EXCEPTION块异常错误部分，执行错误处理代码。

 

       对于这类异常情况的处理，步骤如下：

1． 在PL/SQL 块的定义部分定义异常情况：

<异常情况>  EXCEPTION;

 

2． RAISE <异常情况>；

 

3． 在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

 

例3：更新指定员工工资，增加100；

 

DECLARE

   v_empno emp.empno%TYPE :=&empno;

   no_result  EXCEPTION;

BEGIN

   UPDATE emp SET sal=sal+100 WHERE empno=v_empno;

   IF SQL%NOTFOUND THEN

      RAISE no_result;

   END IF;

EXCEPTION

   WHEN no_result THEN

      DBMS_OUTPUT.PUT_LINE('你的数据更新语句失败了!');

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||’---‘||SQLERRM);

END;

 

§5.1.4  用户定义的异常处理

 

调用DBMS_STANDARD(ORACLE提供的包)包所定义的RAISE_APPLICATION_ERROR过程，可以重新定义异常错误消息，它为应用程序提供了一种与ORACLE交互的方法。

 

RAISE_APPLICATION_ERROR 的语法如下：

RAISE_APPLICATION_ERROR(error_number,error_message,[keep_errors] ) ;

 

这里的error_number 是从 –20,000 到 –20,999 之间的参数，

    error_message 是相应的提示信息(< 2048 字节)，

keep_errors 为可选，如果keep_errors =TRUE ,则新错误将被添加到已经引发的错误列表中。如果keep_errors=FALSE(缺省),则新错误将替换当前的错误列表。

 

例4：创建一个函数get_salary, 该函数检索指定部门的工资总和，其中定义了-20991和-20992号错误，分别处理参数为空和非法部门代码两种错误：

 

CREATE TABLE errlog(

       Errcode NUMBER,

       Errtext CHAR(40));

 

CREATE OR REPLACE FUNCTION get_salary (p_deptno NUMBER)

       RETURN NUMBER AS

       V_sal NUMBER;

BEGIN

       IF p_deptno IS NULL THEN

              RAISE_APPLICATION_ERROR(-20991, ’部门代码为空’);

       ELSIF p_deptno<0 THEN

              RAISE_APPLICATION_ERROR(-20992, ’无效的部门代码’);

       ELSE

              SELECT SUM(sal) INTO v_sal FROM EMP WHERE deptno=p_deptno;

              RETURN V_sal;

       END IF;

END;

 

DECLARE

       V_salary NUMBER(7,2);

       V_sqlcode NUMBER;

       V_sqlerr VARCHAR2(512);

       Null_deptno EXCEPTION;

       Invalid_deptno EXCEPTION;

       PRAGMA EXCEPTION_INIT(null_deptno,-20991);

       PRAGMA EXCEPTION_INIT(invalid_deptno, -20992);

BEGIN

       V_salary :=get_salary(10);

       DBMS_OUTPUT.PUT_LINE(’10号部门工资：’||TO_CHAR(V_salary));

 

       BEGIN

              V_salary :=get_salary(-10);

       EXCEPTION

              WHEN invalid_deptno THEN

                     V_sqlcode :=SQLCODE;

                     V_sqlerr :=SQLERRM;

                     INSERT INTO errlog(errcode, errtext) VALUES(v_sqlcode, v_sqlerr);

                     COMMIT;

       END inner1;

 

       V_salary :=get_salary(20);

       DBMS_OUTPUT.PUT_LINE(’20号部门工资：’||TO_CHAR(V_salary));

 

       BEGIN

              V_salary :=get_salary(NULL);

       END inner2;

 

       V_salary :=get_salary(30);

       DBMS_OUTPUT.PUT_LINE(’30号部门工资：’||TO_CHAR(V_salary));

 

       EXCEPTION

              WHEN null_deptno THEN

                     V_sqlcode :=SQLCODE;

                     V_sqlerr :=SQLERRM;

                     INSERT INTO errlog(errcode, errtext) VALUES(v_sqlcode, v_sqlerr);

                     COMMIT;

              WHEN OTHERS THEN

                 DBMS_OUTPUT.PUT_LINE(SQLCODE||’---‘||SQLERRM);

END outer;

 

§5.2 异常错误传播

    由于异常错误可以在声明部分和执行部分以及异常错误部分出现，因而在不同部分引发的异常错误也不一样。

 

§5.2.1在执行部分引发异常错误

    当一个异常错误在执行部分引发时，有下列情况：

l  如果当前块对该异常错误设置了处理，则执行它并成功完成该块的执行，然后控制转给包含块。

l  如果没有对当前块异常错误设置定义处理器，则通过在包含块中引发它来传播异常错误。然后对该包含块执行步骤1)。

 

§5.2.2在声明部分引发异常错误

    如果在声明部分引起异常情况，即在声明部分出现错误，那么该错误就能影响到其它的块。比如在有如下的PL/SQL程序：

 

DECLARE

Abc number(3):=’abc’;

其它语句

BEGIN

其它语句

EXCEPTION

WHEN OTHERS THEN

其它语句

END;

 

例子中，由于Abc number(3)=’abc’; 出错，尽管在EXCEPTION中说明了WHEN OTHERS THEN语句，但WHEN OTHERS THEN也不会被执行。 但是如果在该错误语句块的外部有一个异常错误，则该错误能被抓住，如：

 

BEGIN

DECLARE

Abc number(3):=’abc’;

其它语句

   BEGIN

其它语句

   EXCEPTION

WHEN OTHERS THEN

其它语句

END;

EXCEPTION

WHEN OTHERS THEN

其它语句

END;

§5.3 异常错误处理编程

    在一般的应用处理中，建议程序人员要用异常处理，因为如果程序中不声明任何异常处理，则在程序运行出错时，程序就被终止，并且也不提示任何信息。下面是使用系统提供的异常来编程的例子。

§5.4  在 PL/SQL 中使用 SQLCODE, SQLERRM

    由于ORACLE 的错信息最大长度是512字节，为了得到完整的错误提示信息，我们可用 SQLERRM和 SUBSTR 函数一起得到错误提示信息。

 

SQLCODE 返回错误代码数字,

SQLERRM 返回错误信息.

 

如:  SQLCODE=-100  è SQLERRM=’no_data_found ‘

SQLCODE=0      è SQLERRM=’normal, successfual completion’

 

例5. 将ORACLE错误代码及其信息存入错误代码表

CREATE TABLE errors (errnum NUMBER(4), errmsg VARCHAR2(100));

 

DECLARE

   err_msg  VARCHAR2(100);

BEGIN

   /*  得到所有 ORACLE 错误信息  */

   FOR err_num IN -100 .. 0LOOP

      err_msg := SQLERRM(err_num);

      INSERT INTO errors VALUES(err_num, err_msg);

   ENDLOOP;

END;

 

DROP TABLE errors;

 

例6. 查询ORACLE错误代码；

BEGIN

   INSERT INTO emp(empno, ename, hiredate, deptno)

            VALUES(2222, ‘Jerry’, SYSDATE, 20);

   DBMS_OUTPUT.PUT_LINE('插入数据记录成功!');

   INSERT INTO emp(empno, ename, hiredate, deptno)

            VALUES(2222, ‘Jerry’, SYSDATE, 20);

   DBMS_OUTPUT.PUT_LINE('插入数据记录成功!');

EXCEPTION

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||’---‘||SQLERRM);

END;

 

例7. 利用ORACLE错误代码，编写异常错误处理代码；

DECLARE

   empno_remaining EXCEPTION;

   PRAGMA EXCEPTION_INIT(empno_remaining, -1);

   /* -1 是违反唯一约束条件的错误代码 */

BEGIN

   INSERT INTO emp(empno, ename, hiredate, deptno)

            VALUES(3333, ‘Jerry’, SYSDATE, 20);

   DBMS_OUTPUT.PUT_LINE('插入数据记录成功!');

   INSERT INTO emp(empno, ename, hiredate, deptno)

            VALUES(3333, ‘Jerry’, SYSDATE, 20);

   DBMS_OUTPUT.PUT_LINE('插入数据记录成功!');

EXCEPTION

   WHEN empno_remaining THEN

      DBMS_OUTPUT.PUT_LINE('违反数据完整性约束!');

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||’---‘||SQLERRM);

END;

 

 


阅读(876) | 评论(0) | 转发(0) |
0

上一篇：L/SQL程序设计（四）

下一篇：PL/SQL程序设计（六）

给主人留下些什么吧！~~
关于我们 | 关于IT168 | 联系方式 | 广告合作 | 法律声明 | 免费注册

Copyright 2001-2010 ChinaUnix.net All Rights Reserved 北京皓辰网域网络信息技术有限公司. 版权所有

感谢所有关心和支持过ChinaUnix的朋友们

16024965号-6