uboot_2013.07 crt0.S 流程分析

crt0.S.  此文件 把原有  Start.S 部分代码进行封装, 一般此文件无需修改. Start.S 中 最后一条执行代码 bl _main 语句跳到此处运行.

ENTRY(_main)

/*
 * Set up initial C runtime environment and call board_init_f(0).
 */

//为 board_init_f 调用 准备 GD 和 堆栈的存放空间(RAM空间)
#if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
    ldr    sp, =(CONFIG_SPL_STACK)
#else
    ldr    sp, =(CONFIG_SYS_INIT_SP_ADDR)   //设置调用c语言函数的堆栈并以八字节对齐.
/*
    #define CONFIG_SYS_INIT_SP_ADDR	(CONFIG_SYS_SDRAM_BASE=0x30000000 + 0x1000 - GENERATED_GBL_DATA_SIZE=160Bytes=sizeof(struct global_data)+16字节对齐)
    #define GD_SIZE 152 (sizeof(struct global_data))
*/
#endif
    bic    sp, sp, #7    /* 8-byte alignment for ABI compliance 8字节对齐 */
    sub    sp, #GD_SIZE    /* allocate one GD above SP */
    bic    sp, sp, #7    /* 8-byte alignment for ABI compliance */
    mov    r8, sp        /* GD is above SP */
    /* 此处 全局变量 gd 定义.
        arch/arm/include/asm/global_data.h:#define DECLARE_GLOBAL_DATA_PTR     register volatile gd_t *gd asm ("r8")
        即 gd 的地址是存在 r8寄存器的. 此时gd空间已经准备好, 可以交给 board_init_f 去初始化了.
    */
    mov    r0, #0
    bl    board_init_f   // 设置传递给board_init_f的参数 r0=0, 定义在 board.c, 硬件的初始化init_sequence数组, 设置 gd 信息.

#if ! defined(CONFIG_SPL_BUILD)

/*
 * Set up intermediate environment (new sp and gd) and call
 * relocate_code(addr_moni). Trick here is that we'll return
 * 'here' but relocated.
 */

    ldr    sp, [r8, #GD_START_ADDR_SP]    /* sp = gd->start_addr_sp */
    bic    sp, sp, #7    /* 8-byte alignment for ABI compliance */
    ldr    r8, [r8, #GD_BD]        /* r8 = gd->bd */
    sub    r8, r8, #GD_SIZE        /* new GD is below bd */

    adr    lr, here
    ldr    r0, [r8, #GD_RELOC_OFF]        /* r0 = gd->reloc_off */
    add    lr, lr, r0
    ldr    r0, [r8, #GD_RELOCADDR]        /* r0 = gd->relocaddr */
    b    relocate_code  // 定义在 arch/arm/lib/relocate.S
here:

/* Set up final (full) environment  清除bss段 */

    bl    c_runtime_cpu_setup    /* we still call old routine here */

    ldr    r0, =__bss_start    /* this is auto- */
    ldr    r1, =__bss_end        /* this is auto- */

    mov    r2, #0x00000000        /* prepare zero to clear BSS */
//循环清除bss段
clbss_l:cmp    r0, r1            /* while not at end of BSS */
    strlo    r2, [r0]        /* clear 32-bit BSS word */
    addlo    r0, r0, #4        /* move to next */
    blo    clbss_l

    /* call board_init_r(gd_t *id, ulong dest_addr) */
    mov    r0, r8            /* gd_t */
    ldr    r1, [r8, #GD_RELOCADDR]    /* dest_addr */
    /* call board_init_r */
    ldr    pc, =board_init_r    /* this is auto- board_init_r 正式进入第二阶段的初始化 * /

    /* we should not return here. */

#endif

ENDPROC(_main)

arch/arm/lib/relocate.S 大妈重定位启动的代码

ENTRY(relocate_code)  //比较当前位置和 __image_copy_start 位置 /* r0 = gd->relocaddr */
    ldr    r1, =__image_copy_start    /* r1 <- SRC &__image_copy_start */
    subs    r9, r0, r1        /* r9 <- relocation offset */
    beq    relocate_done        /* skip relocation */
    ldr    r2, =__image_copy_end    /* r2 <- SRC &__image_copy_end */

copy_loop:
    ldmia     {r10-r11}        /* copy from source address [r1] */
    stmia     {r10-r11}        /* copy to   target address [r0] */
    cmp    r1, r2            /* until source end address [r2] */
    blo    copy_loop

    /*
     * fix .rel.dyn relocations
     */
    ldr    r2, =__rel_dyn_start    /* r2 <- SRC &__rel_dyn_start */
    ldr    r3, =__rel_dyn_end    /* r3 <- SRC &__rel_dyn_end */
fixloop:
    ldmia     {r0-r1}        /* (r0,r1) <- (SRC location,fixup) */
    and    r1, r1, #0xff
    cmp    r1, #23            /* relative fixup? */
    bne    fixnext

    /* relative fix: increase location by offset */
    add    r0, r0, r9
    ldr    r1, [r0]
    add    r1, r1, r9
    str    r1, [r0]
fixnext:
    cmp    r2, r3
    blo    fixloop

relocate_done:
    /* ARMv4- don't know bx lr but the assembler fails to see that */
#ifdef __ARM_ARCH_4__
        mov pc, lr
#else
        bx        lr
#endif

ENDPROC(relocate_code)